6

Groovy 1.8.6 と 2.0.0 の両方でこれに遭遇しました。

したがって、これらのシナリオはすべて期待どおりに機能します。

def ay = { one, two=[:] -> [one, two] }
def be = { one, two, three=[:] -> [one,two,three] }
def ayprime = ay.curry('PRIME')
def beprime = be.curry('PRIME')
def beprimer = be.curry('PRIME', 'PRIMER')

assert ay(1,2) == [1,2]
assert ay(1) == [1,[:]]
assert be(1,2,3) == [1,2,3]
assert be(1,2) == [1,2,[:]]

assert ayprime(1) == ['PRIME', 1]
assert ayprime() == ['PRIME', [:]]
assert beprime(1,2) == ['PRIME', 1, 2]
assert beprime(1) == ['PRIME', 1, [:]]
assert beprimer(1) == ['PRIME', 'PRIMER', 1]
assert beprimer() == ['PRIME', 'PRIMER', [:]]

これと同じように：

class Klass {
    static def smethod = { one, two=[:] -> [one, two] }
}
assert Klass.smethod(1,2) == [1, 2]
assert Klass.smethod(1) == [1, [:]]

これも期待どおりに機能します。

Klass.metaClass.static.aymethod << ay
assert Klass.aymethod(1) == [1, [:]]

アンカリー化されたクロージャへのデフォルト パラメータは、 への代入後も存続しKlassます。

ただし、これは失敗します。

Klass.metaClass.static.ayprimemethod << ayprime
assert Klass.ayprimemethod() == ['PRIME', [:]]

したがって：

assert Klass.ayprimemethod() == ['PRIME', [:]]
             |               |
             [PRIME, null]   false

同様に、これは失敗します:

Klass.metaClass.static.beprimermethod << beprimer
assert Klass.beprimermethod() == ['PRIME', 'PRIMER', [:]]

したがって：

assert Klass.beprimermethod() == ['PRIME', 'PRIMER', [:]]
         |                |
         |                false
         [PRIME, PRIMER, null]

カリー化されたクロージャーでは、デフォルトのパラメーター値は直接機能しますが、クロージャーが の静的メンバーとして割り当てられると失われKlassます。

これはバグのようです。この動作がどこにも文書化されているのを見つけることができませんでした。何か不足していますか？

4

1 に答える 1

0

問題がまだ気になる場合は、Groovy トランクで修正されるまで、これが回避策になると思います。ものをカレーするpythonの方法：

def ayprime = { x -> x ? ay('PRIME', x) : ay('PRIME') }
def beprime = be.curry('PRIME')
def beprimer = { x -> x ? be('PRIME', 'PRIMER', x) : be('PRIME', 'PRIMER') }
于 2012-09-01T18:51:12.170 に答える