16

ユーザーがソフトウェアを既にインストールしているかどうかを検出するにはどうすればよいですか。インストールしている場合は、古いバージョンを削除する可能性を提供する方法を教えてください。

私はそれをチェックするためにいくつかの行を書きました。今のところそれは正しいですか？これが正しい場合、インストールを続行するか、古いバージョンをアンインストールするかをユーザーに選択させるにはどうすればよいですか？

#define UNINSTKEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\setupname_is1"

var
  uninstallPath: string;

function InitializeSetup: Boolean;
begin
  if (RegQueryStringValue(HKLM,'{#UNINSTKEY}','UninstallString',uninstallPath)) and
     (uninstallPath <> '') and (fileexists(uninstallPath)) then
  begin
    Result :=
      (MsgBox(CustomMessage('NotVerifiedVersionFound'), mbConfirmation,
              MB_YESNO or MB_DEFBUTTON2) = IDYES);
  end;
  { ... }
end;
4

2 に答える 2

23

ここに最初に投稿された Craig McQueen のソリューションを使用できます: InnoSetup: 以前にインストールされたバージョンを自動的にアンインストールする方法? 

function GetUninstallString: string;
var
  sUnInstPath: string;
  sUnInstallString: String;
begin
  Result := '';
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{{A227028A-40D7-4695-8BA9-41DF6A3895C7}_is1'); { Your App GUID/ID }
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;

function IsUpgrade: Boolean;
begin
  Result := (GetUninstallString() <> '');
end;

function InitializeSetup: Boolean;
var
  V: Integer;
  iResultCode: Integer;
  sUnInstallString: string;
begin
  Result := True; { in case when no previous version is found }
  if RegValueExists(HKEY_LOCAL_MACHINE,'Software\Microsoft\Windows\CurrentVersion\Uninstall\{A227028A-40D7-4695-8BA9-41DF6A3895C7}_is1', 'UninstallString') then  { Your App GUID/ID }
  begin
    V := MsgBox(ExpandConstant('Hey! An old version of app was detected. Do you want to uninstall it?'), mbInformation, MB_YESNO); { Custom Message if App installed }
    if V = IDYES then
    begin
      sUnInstallString := GetUninstallString();
      sUnInstallString :=  RemoveQuotes(sUnInstallString);
      Exec(ExpandConstant(sUnInstallString), '', '', SW_SHOW, ewWaitUntilTerminated, iResultCode);
      Result := True; { if you want to proceed after uninstall }
      { Exit; //if you want to quit after uninstall }
    end
    else
      Result := False; { when older version present and not uninstalled }
  end;
end;
于 2012-07-31T11:59:46.477 に答える
1

興味のある方のために、私は Inno Setup 6 以降用の小さな DLL を作成しました。これは、アプリケーションがインストールされているかどうかを検出し、独自の基準に基づいて以前にインストールされたバージョンを自動的にアンインストールする機能を提供します。

https://github.com/Bill-Stewart/UninsIS

DLL を使用すると、ダウングレード時のみ、アップグレード時のみ、またはそのいずれかを自動的にアンインストールできます。

于 2021-03-30T02:09:39.940 に答える