4

ユーザーにパスワードの入力を求めたい。VCLが実行されているメインスレッドとは別のスレッドでパスワードが必要になることがあるため、メインウィンドウにメッセージを送信してパスワードを要求しようとしました。次に、メインウィンドウがユーザーに尋ねます。

ユーザーに質問する方法：

procedure TMainForm.WMGetPassword(var Msg: TMessage);
var
  Password: String;
begin
  if QueryPassword(Password) then // function QueryPassword(out Password: String): boolean;
  begin
    Password := Password + #0; // Add #0-Terminator
    Move(Password[1], Msg.wParam, Length(Password) * sizeOf(Char)); // Copy the String in my buffer
    Msg.Result := 1;
  end
  else
  begin
    Msg.Result := 0;
  end;
end;

メインウィンドウに尋ねる方法：

var
  PasswordBuffer: PChar;
  Password: String;
begin
  PasswordBuffer := AllocMem(100 * sizeof(Char));
  PasswordResult := SendMessage(MainFormHWND, WM_GetPassword, Integer(PasswordBuffer), 0);
  Result := (PasswordResult <> -1);
  if not Result then
    Exit;

  SetString(Password, PasswordBuffer, 100);
  ShowMessage(Password);
end;

しかしPassword、PasswordBufferその後は空になります。私は何が間違っているのですか？

4

3 に答える 3

3

スレッドが同じプロセスにある限り (つまり、同じアドレス空間を共有する限り)、コードは機能するはずです。ただし、これは不必要に複雑であり、メモリ リークがあります (PasswordBuffer決して解放されません)。

スレッドで文字列変数を使用し、アドレスを内部の事前割り当てバッファにメイン スレッドに渡すことができます。

type
  TTestThread = class(TThread)
  private
    fHwnd: HWND;
  protected
    procedure Execute; override;
  public
    constructor Create(AWnd: HWND);
  end;

constructor TTestThread.Create(AWnd: HWND);
begin
  fHwnd := AWnd;
  inherited Create(False);
end;

procedure TTestThread.Execute;
const
  MAXLEN = 1024;
var
  s: string;
begin
  SetLength(s, MAXLEN);
  if SendMessage(fHwnd, WM_GETPASSWORD, MAXLEN, LPARAM(@s[1])) > 0 then begin
    s := PChar(s);
    // don't use VCL here
    Windows.MessageBox(0, PChar('password is "' + s + '"'), 'password',
      MB_ICONINFORMATION or MB_OK);
  end;
end;

メイン スレッドでは、パスワードはバッファー サイズに制限された長さのバッファーに入れられます。

procedure TForm1.WMGetPassword(var AMsg: TMessage);
var
  Pwd: string;
begin
  if InputQuery('Password Entry', 'Please enter the password:', Pwd)
    and (Pwd <> '')
  then begin
    StrPLCopy(PChar(AMsg.LParam), Pwd, AMsg.WParam);
    AMsg.Result := 1;
  end else
    AMsg.Result := -1;
end;
于 2012-08-14T10:33:02.697 に答える
3

Msg.wParam を 2 番目のパラメーターとして渡しているため、ポイントしようとしている場所ではなく、その場所に文字列を書き込んでいます。Msg.wParam、Msg.lParam、Msg.Result に保存されている値と、おそらくスタック上のその他の情報も上書きされます。

それ以外の：

Move(Password[1], Msg.wParam, Length(Password) * sizeOf(Char));

以下を使用する必要があります。

Move(Password[1], PChar(Msg.wParam)^, Length(Password) * sizeOf(Char));

または、ポインタを使用する場合は MoveMemory を使用します。

于 2012-08-14T10:30:15.657 に答える
2

@Danは正しく、@mghieはリークを発見しました。

ポインターを使用しない別の方法を次に示します。

type
  TMyMessage = class
    msg: string;
  end;

procedure TMainForm.WMGetPassword(var Msg: TMessage);
var
  SMessage: TMyMessage;
  Password: string;
begin
  if QueryPassword(Password) then 
  begin
    SMessage := TMyMessage(msg.WParam);
    SMessage.msg := Password;
    msg.Result := 1;
  end
  else
  begin
    Msg.Result := 0;
  end;
end;


var
  MyMsg: TMyMessage;
begin
  MyMsg := TMyMessage.Create('');
  try
    PasswordResult := SendMessage(FormHandleHWND,WM_GetPassword,WPARAM(MyMsg),0);
    Result := (PasswordResult <> -1);
    if Result
      then Password := MyMsg.msg;
  finally
    MyMsg.Free;
  end;
end;
于 2012-08-14T10:55:44.990 に答える