1

Windows SAS で sas ファイルの所有者に関する情報を見つける方法はありますか? 次のコードを試しましたが、コードの所有者に関する情報はありません。

data info;
   length infoname infoval $300;
   drop rc fid infonum i close;
   rc=filename('abc','C:\c-ae.sas');
   fid=fopen('abc');
   infonum=foptnum(fid);
   do i=1 to infonum;
      infoname=foptname(fid,i);
      infoval=finfo(fid,infoname);
      output;
   end;
   close=fclose(fid);
run;

コード/ファイルの所有者に関する情報を取得する方法はありますか?

4

1 に答える 1

1

SAS ファイル プロパティからファイル所有者を取得できるとは思えません。ただし、WindowsDIRコマンドを/Qスイッチと共に使用して、所有者を検出することができます。例えば：

filename x pipe 'dir /q c:\c-ae.sas';
data a;
   infile x firstobs=6 truncover;
   input @1 file_date yymmdd10.
        @13 file_time time8.
            file_size
            file_owner $22.
            file_name $32.;
   format file_date yymmdd10. file_time time8.; 
   output;
   stop;
run;
filename x clear;

スイッチはコマンド ヘッダーとトレーラの出力を抑制するはずですが、/B私のシステムではそうではありません。したがって、 を使用firstobs=6するとヘッダーがスキップされ、stopコマンドは残りの出力をスキップします。

これは実際には Windows ソリューションであり、実際には SAS ではないことに注意してください。Windows他の人が参加できる場合に備えて、タグを追加します。

于 2012-08-22T16:22:15.207 に答える