1

私は2枚持っています。シート1は次のように設定されます。

Keyword  Domain  Rank
  A        Z      1
  B        Z      2
  C        Z      3
  D        Y      10
  E        Y      15
  B        Y      20

シート2は次のように設定されています。

Keyword  (Domain Z)  (Domain Y)
  A           1          -
  B           2          20
  C           3          -
  D           -          10

シート2のキーワードをシート1のキーワードと比較し、正しいドメイン（その列のシート2で指定されている）に対応するランクを返す数式を作成しようとしています。評価に使用する数式を取得できません。これまでに2つの数式を使用しました。

=INDEX(Raw!$H$11:$H$322, MATCH(A3,IF(Raw!$D$11:$D$322=All!$B$2,Raw!$B$11:$B$322),0))

上記の式は、ある程度は機能します。問題は、見つかったキーワードの最初のインスタンスのドメインを単純にプルすることです。これは、シート2の列のドメインと常に一致するとは限りません。私が試した2番目の式：

=INDEX(Raw!$H$11:$H$322, MATCH(B3,MATCH($C$2,Raw!$D$11:$D$322,0)))
4

2 に答える 2

2

シート 2 テーブルに値を表示するには、次の式を使用します。

=SUMPRODUCT(--($A$2:$A$7=E2),--($B$2:$B$7=$F$1),$C$2:$C$7)

ここに画像の説明を入力

これは0一致しない場合に返されます-セルをフォーマットして0を表示するか、より長く/醜いものを使用できます。

=IF(SUMPRODUCT(--($A$2:$A$7=E2),--($B$2:$B$7=$G$1),$C$2:$C$7)<>0,SUMPRODUCT(--($A$2:$A$7=E2),--($B$2:$B$7=$G$1),$C$2:$C$7),"-")

2 番目のシートのデータに基づいて 1 番目のシートのランクを計算するには:

=VLOOKUP(A2,$F$2:$H$5,MATCH(B2,$G$1:$H$1,0)+1,FALSE)

サンプルの目的で、これはシート 2 のデータを F1:H5 に入れるだけです。 ここに画像の説明を入力

これにより、対応するキーワードが検索され、match を使用して正しい列が選択されます。列に と という名前を付けましたZが、含めるY必要がある場合は、それも実行Domainできます。E2 番目のテーブルに何も定義されていないため、これによりエラーが発生することに注意してください。その場合、次のように一致しないことを考慮して調整できます (Excel 2007 を想定)。

=IFERROR(VLOOKUP(A6,$F$2:$H$5,MATCH(B6,$G$1:$H$1,0)+1,FALSE),"Rank Not Found")

ここに画像の説明を入力

于 2012-10-02T01:00:05.950 に答える
0

行にキーワード、列にドメイン名を含むピボットテーブルを使用することもできます。それは仕事をし、より堅牢なソリューションになるようです。

于 2015-08-10T04:26:05.220 に答える