3

この関数を使用して IE のバージョンを取得します。しかし、場合によっては、このキーが見つからず、0 が返されます。レジストリに依存しない別の方法はありますか?

function GetIEVersion: string;
var
   Reg: TRegistry;
   S: string;
   i : integer;
begin
   Reg := TRegistry.Create;
   with Reg do
      begin
         RootKey := HKEY_LOCAL_MACHINE;
         OpenKey('Software\Microsoft\Internet Explorer', False);
         if ValueExists('Version') then
          begin
            S := ReadString('Version');
          end
         else
         begin
            S := '0';
         CloseKey;
        end;
         Free;
      end;
    result := s;
end;
4

3 に答える 3

7

TRegistry.OpenKey()プロパティを使用してTRegistry.Access、キーを開くときに要求するアクセス許可を認識します。デフォルトでTRegistry.Accessは、 は に設定されてKEY_ALL_ACCESSおり、管理者のみに制限されています。TRegistry.OpenKeyReadOnly()代わりに使用してください。また、値が存在しない場合は空白の文字列ValueExists()を返すため、チェックを省略できます。ReadString()

これを試して：

function GetIEVersion: string; 
var 
  Reg: TRegistry; 
begin 
  Result := '';
  Reg := TRegistry.Create; 
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE; 
    if Reg.OpenKeyReadOnly('Software\Microsoft\Internet Explorer') then
    try
      Result := Reg.ReadString('Version'); 
    finally
      Reg.CloseKey; 
    end; 
  finally
    Reg.Free; 
  end;
  if Result = '' then
    Result := '0'; 
end;
于 2012-10-04T00:39:26.520 に答える
5

ファイルのバージョン情報を取得する方法を使用できます。まず、iexplore.exeパスを取得します。

function GetIEPath: string;
var
  Reg: TRegistry;
  Len: Integer;
begin
  Result := '';
  Reg := TRegistry.Create;

  with Reg do
  begin
    try
      RootKey := HKEY_CLASSES_ROOT;
      OpenKeyReadOnly('CLSID\{0002DF01-0000-0000-C000-000000000046}\LocalServer32');
      try
        Result := ReadString('');
      finally
        CloseKey;
        Len := Length(Result);

        if Len >= 2 then
        begin
          if(Result[Len] = '"') then
            Delete(Result, Len, 1);

          if(Result[1] = '"') then
            Delete(Result, 1, 1);
        end
        else
        begin
          Result := '';
        end;
      end;
    finally
      Free;
    end;
  end;
end;

{0002DF01-0000-0000-C000-000000000046}InternetExplorerのCLSIDです。のデフォルトのキー値LocalServer32はiexplore.exeパスです。

次に、Simon Grossenbacherが示すように、このリンクでいくつかのAPI呼び出しを使用して、ファイルのバージョン情報を取得します。彼の関数を変更すると、次のようになります。

function GetIEVersion: string;
var
  IEPath: string;
  VerInfoSize: DWORD;
  VerInfo: Pointer;
  VerValueSize: DWORD;
  VerValue: PVSFixedFileInfo;
  Dummy: DWORD;
begin
  Result := '0';

  IEPath := GetIEPath;
  if IEPath = '' then
    Exit;

  VerInfoSize := GetFileVersionInfoSize(PChar(IEPath), Dummy);
  if VerInfoSize = 0 then
    Exit;

  GetMem(VerInfo, VerInfoSize);
  GetFileVersionInfo(PChar(IEPath), 0, VerInfoSize, VerInfo);
  VerQueryValue(VerInfo, '\', Pointer(VerValue), VerValueSize);

  with VerValue^ do
  begin
    Result := IntToStr(dwFileVersionMS shr 16);
    Result := Result + '.' + IntToStr(dwFileVersionMS and $FFFF);
    Result := Result + '.' + IntToStr(dwFileVersionLS shr 16);
    Result := Result + '.' + IntToStr(dwFileVersionLS and $FFFF);
  end;
  FreeMem(VerInfo, VerInfoSize);
end;

次に、たとえば、これを使用します。

ShowMessage(GetIEVersion);
于 2012-10-04T01:02:05.730 に答える