0

xmlを並べ替えたい

私のxml形式は

<OTA_HotelAvailRS xmlns="http://www.opentravel.org/OTA" EchoToken="" SequenceNmbr="1" Target="Production" TimeStamp="2012-09-28T08:29:44Z" Version="1">
    <SummaryResponse>    
        <AdditionalDetails>    
           <AdditionalDetail Amount="212,20 EUR" Code="TotalPackagePrice" CurrencyCode="EUR" DecPart="20" IntPart="212" Type="PackageInformation"></AdditionalDetail>
          </AdditionalDetails>

    </SummaryResponse>
    <SummaryResponse>

       <AdditionalDetails>
          <AdditionalDetail Amount="212,20 EUR" Code="TotalPackagePrice" CurrencyCode="EUR" DecPart="20" IntPart="500" Type="PackageInformation"></AdditionalDetail>
        </AdditionalDetails>
    </SummaryResponse>
</OTA_HotelAvailRS>

私が使用しているXSLは

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" version="1.0" encoding="iso-8859-1" indent="yes"/>

<xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

<xsl:template match="OTA_HotelAvailRS">
  <xsl:copy>   
    <xsl:apply-templates select="SummaryResponse/AdditionalDetails">
       <xsl:sort select="AdditionalDetail/@IntPart" data-type="number" order="descending"/>
    </xsl:apply-templates>
    Value of :<xsl:value-of select="AdditionalDetail/@IntPart" />
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

AdditionalDetailのIntPart属性でソートしたい。

誰か助けてください

4

2 に答える 2

2

これは実際には並べ替えの問題ではなく、名前空間の問題です! 元の XML で、デフォルトの名前空間を指定しました

<OTA_HotelAvailRS xmlns="http://www.opentravel.org/OTA"

これは、XML のすべての要素がその名前空間内にあることを意味します。ただし、XSLT では、この名前空間を参照せず、名前空間にまったく含まれていない要素を探しています。

これを回避するには、任意の文字プレフィックスを使用して XSLT で名前空間を指定し、要素名にプレフィックスを付けて、その名前空間にある必要があることを示す必要があります。

このXSLTを試してください

<xsl:stylesheet 
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" 
     xmlns:a="http://www.opentravel.org/OTA">

   <xsl:output method="xml" version="1.0" encoding="iso-8859-1" indent="yes"/>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="a:OTA_HotelAvailRS">
      <xsl:copy>
         <xsl:apply-templates select="a:SummaryResponse/a:AdditionalDetails">
            <xsl:sort select="a:AdditionalDetail/@IntPart" data-type="number" order="descending"/>
         </xsl:apply-templates>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="a:AdditionalDetails">
     Value of : <xsl:value-of select="a:AdditionalDetail/@IntPart"/>
   </xsl:template>
</xsl:stylesheet>

要素の値を出力したいように見えたので、AdditionalDetailsに一致するテンプレートも追加したことに注意してください。

于 2012-10-29T13:58:45.570 に答える
1

SummaryResponse要素をソートしたいだけなら、このスタイルシートが機能します:

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:ota="http://www.opentravel.org/OTA">

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="ota:OTA_HotelAvailRS">
    <xsl:copy>
      <xsl:apply-templates select="ota:SummaryResponse">
        <xsl:sort select="ota:AdditionalDetails/ota:AdditionalDetail/@IntPart" data-type="number" order="descending"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>
于 2012-10-30T08:49:54.803 に答える