vb6 - Basic4android と VB6 間の通信

Question

Androidで（basic4androidを使用して）ボタンを押す方法と、データを受け入れて応答するVB6プログラムを取得する方法について簡単な回答が欲しいです。Android と VB6 プログラムを実行しているコンピューターの両方が同じ WiFi に接続されています。

Erel は URL を教えてくれますが、何時間も読んでも、Android コードと VB6 コードの簡単な例が見つからないようです。

Answer 1

basic4androidはわかりませんが、コンピューター上の単純なVB6プロジェクトは次のようになります。

'1 form with :
'  1 textbox : name=Text1
'  1 winsock control : name=Winsock1

Option Explicit

Private Sub Form_Load()
  Text1.Move 0, 0, ScaleWidth, ScaleHeight 'position the textbox
  With Winsock1
    .LocalPort = 5001                      'set the port to listen on
    .Listen                                'start listening
  End With 'Winsock1
End Sub

Private Sub Winsock1_ConnectionRequest(ByVal requestID As Long)
  With Winsock1
    If .State <> sckClosed Then .Close     'close the port when not closed (you could also use another winsock control to accept the connection)
    .Accept requestID                      'accept the connection request
  End With 'Winsock1
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
  Dim strData As String
  Winsock1.GetData strData                 'get the data
  ProcessData strData                      'process the data
End Sub

Private Sub Winsock1_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
  MsgBox Description, vbCritical, "Error " & CStr(Number)
End Sub

Private Sub ProcessData(strData As String)
  Text1.SelText = strData                  'show the data
End Sub

いくつかの意見：

このプロジェクトは、リスニングwinsockコントロールを使用して接続を受け入れるため、その後は新しい接続要求をリッスンしなくなります。大量のデータを送信する場合は、おそらくデータをバッファリングし、完了したら処理する必要があります。