0

問題を次の状況に抽象化しました。

更新したいアイテムAの数 ( ) を含むテーブル ( ) があります。Quantity次に、選択する必要があるテーブル ( )SLへの参照を含むテーブル ( A) があります。最後に、更新する必要があるテーブル ( B)

CREATE TABLE A
(
    Id int,
    Quantity int
)

CREATE TABLE SL
(
    Id int,
    A_Id int,
    S_Id int
)

CREATE TABLE B
(
    Id int,
    StatusValue int,
    A_Id int, 
    S_Id int NULL,
)

それでは、テスト目的でいくつかのデータを挿入しましょう。

INSERT INTO A Values (1, 4), (2, 2), (3, 3), (4, 4), (5, 2)

delete from B
declare @i int = 1;
declare @j int = 0;
declare @maxA int = 5;
declare @rows_to_insert int = 10;
while @i < @maxA
begin
    while @j < @rows_to_insert * @i
    begin
        INSERT INTO B VALUES (10+@j, 0, @i, null)
        set @j = @j + 1
    end
    set @i = @i + 1
end
select * from B

INSERT INTO SL Values (1, 1, 1), (2, 2, 1), (3 ,2, 1)

そして、問題に移ります。のレコードに関連する のレコードのTOP(数量)を更新したい。基本的にこれは私がやりたいことですが、SQLではサポートされていません:BSL

DECLARE @Sale_Id int = 1;
WITH AB (AId, AQuantity, SaleId)
AS
(
    SELECT A.Id, A.Quantity, SL.S_Id FROM A
        INNER JOIN SL on A.Id = SL.A_Id
        WHERE SL.S_Id = @Sale_Id
)
UPDATE TOP(AB.Quantity) B
    SET StatusValue = 1,
        S_Id = AB.SaleId
    FROM AB
    WHERE StatusValue = 0 -- Edited
                AND B.A_Id = AB.AId

エラーメッセージは

メッセージ 4104、レベル 16、状態 1、行 55 マルチパート識別子「AB.Quantity」をバインドできませんでした。

これを行うための私のオプションは何ですか？（常にありますが、Cursorそれは良いオプションですか？）

注:このデータには、SL に A_Id = 2 を参照するレコードが 2 回あるという面白い側面があります。これは、A_Id = 2 が更新された 4 つの B レコードが結果に必要であることを意味します。

4

2 に答える 2

1

これはうまくいくはずです

DECLARE @Sale_Id int = 1;
with tmp as (
  SELECT A.Id, A.Quantity, SL.S_Id SaleID, B.S_ID, b.id b_id, B.StatusValue,
         rn=dense_rank() over (partition by a.id order by b.id)
    FROM A
    JOIN SL on A.Id = SL.A_Id
    JOIN B ON B.A_Id = A.Id
   WHERE SL.S_Id = @Sale_Id
)
update tmp
   set S_ID = SaleID,
       StatusValue = 1
 where rn <= quantity;

ただし、A.id=2 が同じ SL.id=1 で 2 回販売されているというデータはおかしなことです。

SQL フィドル

于 2012-11-29T11:45:13.853 に答える
0

だから、Cursor私が行く必要がある方法のようです：

DECLARE @A_Id int, @Quantity int;
DECLARE ABCursor CURSOR LOCAL READ_ONLY FOR 
    SELECT A.Id, A.Quantity FROM A
        INNER JOIN SL on A.Id = SL.A_Id
        WHERE SL.S_Id = @Sale_Id
OPEN ABCursor
FETCH NEXT FROM ABCursor 
    INTO @A_Id, @Quantity
WHILE @@FETCH_STATUS = 0
BEGIN
    UPDATE TOP(@Quantity) B
        SET StatusValue = 1,
            S_Id = @Sale_Id
        WHERE StatusValue = 0
            AND B.A_Id = @A_Id
            AND S_Id is null
    FETCH NEXT FROM ABCursor 
        INTO @A_Id, @Quantity
END 
CLOSE ABCursor;
DEALLOCATE ABCursor;

ここで、カーソルの最適な定義を確認する必要があります。つまり、次のとおりです。LOCAL READ_ONLY

于 2012-12-05T10:49:02.403 に答える