1

次のコードを見てください。

<xsl:template match="tocline[@toclevel='2']">
    <xsl:copy>
        <xsl:copy-of select="@*"/>

        <xsl:for-each select="descendant::toctitle">
            <xsl:if test="position() = last()">
                <xsl:attribute name="last">
                    <xsl:value-of select="'true'"/>
                </xsl:attribute>
            </xsl:if>
        </xsl:for-each>

    <xsl:apply-templates />
    </xsl:copy>
</xsl:template>

このテンプレートは、属性を tocline 要素に適用します。さまざまなレベルに配置できるノードセットの最後の toctitle に属性を適用したいと考えています。

このサンプルでは:

        <tocline id="d1e11" toclevel="1">
            <toctitle>Section 1. Legislative Powers</toctitle>
            <tocline id="d1e40" toclevel="2">
                <toctitle>Separation of Powers and Checks and Balances</toctitle>
                <tocline id="d1e51" toclevel="3">
                    <toctitle>The Theory Elaborated and Implemented</toctitle>
                </tocline>
                <tocline id="d1e189" toclevel="3">
                    <toctitle>Judicial Enforcement</toctitle>
                </tocline>
            </tocline>
        </tocline>

これ欲しい：

        <tocline id="d1e11" toclevel="1">
            <toctitle>Section 1. Legislative Powers</toctitle>
            <tocline id="d1e40" toclevel="2">
                <toctitle>Separation of Powers and Checks and Balances</toctitle>
                <tocline id="d1e51" toclevel="3">
                    <toctitle>The Theory Elaborated and Implemented</toctitle>
                </tocline>
                <tocline id="d1e189" toclevel="3">
                    <toctitle last="true">Judicial Enforcement</toctitle>
                </tocline>
            </tocline>
        </tocline>

しかし、私はこれを取得します:

        <tocline id="d1e11" toclevel="1">
            <toctitle>Section 1. Legislative Powers</toctitle>
            <tocline id="d1e40" toclevel="2" last="true">
                <toctitle>Separation of Powers and Checks and Balances</toctitle>
                <tocline id="d1e51" toclevel="3">
                    <toctitle>The Theory Elaborated and Implemented</toctitle>
                </tocline>
                <tocline id="d1e189" toclevel="3">
                    <toctitle>Judicial Enforcement</toctitle>
                </tocline>
            </tocline>
        </tocline>
4

2 に答える 2

0

キーを追加したところ、思いついたのは次のとおりです。

<xsl:key name="l2id" match="tocline[@toclevel eq '2']" use="@id"/>

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="toctitle[. is (ancestor-or-self::tocline/key('l2id',@id)/descendant-or-self::toctitle[last()])]">
    <xsl:copy>
        <xsl:attribute name="last">
            <xsl:value-of select="'true'"/>
        </xsl:attribute>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
于 2013-01-18T13:28:40.843 に答える
0

この変換:

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
 "toctitle
    [. is (ancestor::tocline[@toclevel eq '2'][1]//toctitle)[last()]]">
    <toctitle last="true">
      <xsl:apply-templates select="@*|node()"/>
    </toctitle>
 </xsl:template>
</xsl:stylesheet>

提供された XML ドキュメントに適用した場合:

<tocline id="d1e11" toclevel="1">
    <toctitle>Section 1. Legislative Powers</toctitle>
    <tocline id="d1e40" toclevel="2">
        <toctitle>Separation of Powers and Checks and Balances</toctitle>
        <tocline id="d1e51" toclevel="3">
            <toctitle>The Theory Elaborated and Implemented</toctitle>
        </tocline>
        <tocline id="d1e189" toclevel="3">
            <toctitle>Judicial Enforcement</toctitle>
        </tocline>
    </tocline>
</tocline>

必要な正しい結果が生成されます。

<tocline id="d1e11" toclevel="1">
   <toctitle>Section 1. Legislative Powers</toctitle>
   <tocline id="d1e40" toclevel="2">
      <toctitle>Separation of Powers and Checks and Balances</toctitle>
      <tocline id="d1e51" toclevel="3">
         <toctitle>The Theory Elaborated and Implemented</toctitle>
      </tocline>
      <tocline id="d1e189" toclevel="3">
         <toctitle last="true">Judicial Enforcement</toctitle>
      </tocline>
   </tocline>
</tocline>
于 2013-01-18T00:12:16.427 に答える