1

iTunes クエリ データから Excel ページを作成しようとしています。Angry Birds アプリのクエリの例は次のよう に なります。アルジェリア iTunes ... 150以上のストア

私の質問は、このクエリを実行して応答を解析する最も効率的な方法です。私はxmlhttpクエリの方法しか知りません。これを行うためのより良い方法として私に教えてください。VB-JSON、Json.net、CDataSet、fastJSON のドキュメントをいくつか読みましたが、これらのツールを試してみる方法がわかりません。JSON をプルする VBA コード例や、これらのフレームワークの使用法を初心者に説明する方法を持っている人はいますか? 

Dim innerHTML As Object
Dim myText As String
JsonCheck = ""
Set innerHTML = CreateObject("Microsoft.XMLHTTP")
With innerHTML
    .Open "GET", iTunesAPI_link, False
    .send
    myText = .responsetext
End With
Set innerHTML = Nothing
If InStr(myText, ":0") = 20 Then   'no results found
    result = "Down"
ElseIf InStr(myText, "Your request produced an error.") = 46 Then 'link error
    result = HTMLCheck(human iTunes link)
Else      'found the app
    result = call function which parses myText for desired fields
Endif
4

2 に答える 2

3

scriptcontrol を使用した基本的なアプローチは次のとおりです。

Sub Tester()

    Dim json As String
    Dim sc As Object
    Dim o

    Set sc = CreateObject("scriptcontrol")
    sc.Language = "JScript"

    json = HttpGet("https://itunes.apple.com/lookup?id=343200656&country=AL")

    'some json property names may be keywords in VBA, so replace with
    '  something similar....
    json = Replace(json, """description""", """description_r""")
    Debug.Print json

    sc.Eval "var obj=(" & json & ")" 'evaluate the json response
    'add some accessor functions
    sc.AddCode "function getResultCount(){return obj.resultCount;}"
    sc.AddCode "function getResult(i){return obj.results[i];}"

    Debug.Print sc.Run("getResultCount")

    Set o = sc.Run("getResult", 0)
    Debug.Print o.kind, o.features, o.description_r

End Sub

Function HttpGet(url As String) As String
    Dim oHTML As Object
    Set oHTML = CreateObject("Microsoft.XMLHTTP")
    With oHTML
        .Open "GET", url, False
        .send
        HttpGet = .responsetext
    End With
End Function

この質問に対する Codo の回答には、よく練られたアプローチがあります: Excel VBA: Parsed JSON Object Loop

于 2013-01-18T06:28:34.003 に答える
0

Salesforce の REST API のクエリで同様の問題が発生し、JSON の処理ScriptControlが管理不能になることがわかりました。JSON の解析と変換に次のライブラリを使用しましたが、完全に機能しました: https://code.google.com/p/vba-json/。

Dim JSON As New JSONLib
Dim Parsed As Object

Set Parsed = JSON.parse(jsonValue)
Debug.Print Parsed("resultCount")
Debug.Print Parsed("results")(0)

そのライブラリを使用して、次に役立つと思われる Web 要求を作成するための一般的な機能のいくつかをまとめました: https://github.com/timhall/Excel-REST

これらのライブラリを使用すると、コードは次のようになります。

Dim iTunesClient As New RestClient
iTunesClient.BaseUrl = "https://itunes.apple.com/"

Dim Request As New RestRequest
Request.Format = json
Request.Resource = "lookup"
Request.AddQuerystringParam "id", "343200656"
Request.AddQuerystringParam "country", "AL"

Dim Response As RestResponse
Set Response = iTunesClient.Execute(Request)

' => GET https://itunes.apple.com/lookup?id=343200656&country=AL

If Response.StatusCode = 200 Then
    ' Response.Data contains converted JSON Dictionary/Collection
    Debug.Print "Result Count: " & Response.Data("resultCount")
    Dim i As Integer
    For i = LBound(Response.Data("results")) To UBound(Response.Data("results"))
        Debug.Print "Result " & i & ": " & Response.Data("results")(i)
    Next i
Else
    Debug.Print "Error: " & Response.Content
End If
于 2014-04-03T13:43:43.837 に答える