1

私は TMachine クラスを持っています。それは TShape クラスです

unit MachineShape;


interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, extctrls,myDataModule,Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type

TMachine = class(TShape)
  private
    { Private declarations }
  public
    { Public declarations }
    procedure PlaceShape(sizeW,sizeH :integer; name, order,asset : string);
  end;
implementation



    Procedure TMachine.PlaceShape(sizeW,sizeH :integer; name, order,asset : string);
    begin
       self.width :=  sizeW;
       self.height := sizeH;
       self.top := 136;
       self.left := MyDataModule.fDB.LastX +2;//set left
       MyDataModule.fDB.lastx := left + sizeW;
    end;



end.

これに onmouseenter コードを追加するにはどうすればよいですか? そのため、実行時に形状が追加されると、独自のマウス入力コードが表示されます。このようなもの、私はこれがうまくいかないことを知っています..しかし、多分それは私が何をしようとしているのかをあなたに示すでしょう? したがって、TMachine を作成するときに、名前と番号をこのプロシージャに渡すと、送信した名前/番号で onmouseenter プロシージャが更新されます。 

Procedure TMachine.EditMouseEnter(name,number :string);
begin
   ....onmouseenter(Label2.Caption := name AND label3.caption := Number)...
end
4

1 に答える 1

5

OnMouseEnterイベントを追加します。

type
  TMachineEvent = procedure(Sender: TMachine) of object;

  TMachine = class(TShape)
  private
    FOnMouseEnter: TMachineEvent;
    ...
    procedure CMMouseEnter(var Message: TMessage); message CM_MOUSEENTER;
  protected
    procedure DoMouseEnter; virtual;
  published
    property OnMouseEnter: TMachineEvent read FOnMouseEnter write FOnMouseEnter;
    ...
  end;

implementation

{ TMachine }

procedure TMachine.CMMouseenter(var Message: TMessage);
begin
  DoMouseEnter;
  inherited;
end;

procedure TMachine.DoMouseEnter;
begin
  if Assigned(FOnMouseEnter) then
    FOnMouseEnter(Self);
end;

実行時にそのイベントを割り当てます。

procedure TForm1.CreateMachine;
var
  Machine: TMachine;
begin
  Machine := TMachine.Create(Self);
  Machine.SetBounds(...);
  Machine.OnMouseEnter := MachineMouseEnter;
  Machine.Parent := Self;
end;

procedure TForm1.MachineMouseEnter(Sender: TMachine);
begin
  Label2.Caption := Sender.Name;
  Label3.Caption := Sender.Number;
end;
于 2013-01-28T11:33:56.650 に答える