1

FlashDevelopを使用してFlexでモバイルアプリを作成し、FlashCS6を使用してビジュアルアセットを作成しています。Flash CS6でシンボルを作成し、それをAC3としてSWCにエクスポートし、FlashDevelopプロジェクトにインポートしました。次に、次のようにクラスを作成しました。

package com 
{
import flash.display.Sprite;

  public class volmeter_class extends Sprite
  {
    private var design:volmeter;

    public function volmeter_class()
    {
        trace("I'm a MySymbol instance called", name);
        design = new volmeter();
        addChild(design);
    }     
  }  
}

アプリのページに作成した記号を表示しようとしています。これを行うには、どういうわけかMXMLにインポートすることが期待されていると思いますが、その方法がわかりません。誰かがこれを始める方法についていくつかのヒントを教えてもらえますか？

4

1 に答える 1

3

Flash Proでは、シンボルにASリンケージが指定されていることを確認してください。

フラッシュシンボル

プロジェクトのActionScriptビルドパスでFlashProから公開されたSWCを使用すると、ASLinkageによってシンボルをインスタンス化できます。または、公開されているFlashProのSWF​​からシンボルを埋め込むこともできます。

純粋なActionScriptの例：

package
{
    import flash.display.Sprite;

    public class AppExample extends Sprite
    {
        public function AppExample()
        {
            var exampleSymbol:ExampleSymbol = new ExampleSymbol();
            addChild(exampleSymbol);
        }
    }
}

Flex MXMLの例：

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               creationComplete="creationCompleteHandler(event)">

    <fx:Script>
        <![CDATA[
            import mx.events.FlexEvent;

            protected function creationCompleteHandler(event:FlexEvent):void
            {
                var exampleSymbol:ExampleSymbol = new ExampleSymbol();
                symbol.addChild(exampleSymbol);
            }
        ]]>
    </fx:Script>

    <s:SpriteVisualElement id="symbol" />

</s:Application>

もう1つのアプローチは、FlashProのSWF​​をリンクしてシンボルを埋め込むことです。

Flex MXML埋め込みの例：

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark">

    <fx:Script>
        <![CDATA[
            [Embed('assets/library.swf', symbol = 'ExampleSymbol')]
            [Bindable]
            public static var ExampleSymbolClass:Class;
        ]]>
    </fx:Script>

    <s:Image source="{ExampleSymbolClass}" />

</s:Application>
于 2013-02-17T05:31:32.437 に答える