12

私はかなりばかげた質問をしています。XML 混合コンテンツ ノードが混同されないようにするにはどうすればよいですか? たとえば、これに似た XML 構造があります。

<root>
 <book>
  <title>Stuff</title>
  <description> This book is <i>great</i> if you need to know about stuff.
                I suggest <link ref="Things">this one</link> if you need to know
                about things. </description>
 </book>
 [other books]
</root>

このように見える最終的なコンテンツが必要です

<h1>List of books</h1>
<h2><a name="Stuff"/>Stuff</h2>
<p> This book is <i>great</i> if you need to know about stuff.
    I suggest <a href="#Things">this one</a> if you need to know
    about things. </p>

しかし、テキスト ノードの一部を抽出することはできません。常に全体を取得します。子孫軸を使用しています。私が間違っていることの手がかりはありますか？

これが私のxsltです：

<xsl:template match="description/*">
    <xsl:for-each select="following-sibling::*">
            <xsl:choose>
            <xsl:when test="name(.)='link'">
                <a href="{@ref}"><xsl:value-of select="."/></a>
            </xsl:when>
            <xsl:when test="name(.)='em'">
                <em><xsl:value-of select="."/></em>
            </xsl:when>
            <xsl:otherwise><p><xsl:value-of select="."/></p></xsl:otherwise>    
        </xsl:choose>
    </xsl:for-each>
  </xsl:template>

含まれている XML と結果の html は単なる例であることに注意してください。わかりやすくするために、含まれていないより大きな構造を扱う必要があります。

4

2 に答える 2

12

<xsl:apply-templates>あなたの友達です：

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="html" />

  <xsl:template match="root">
    <h1>List of books</h1>
    <xsl:apply-templates />
  </xsl:template>

  <!-- a <book> consists of its <title> and <description> -->
  <xsl:template match="book">
    <xsl:apply-templates select="title" />
    <xsl:apply-templates select="description" />
  </xsl:template>

  <!-- <title> is turned into a <h2> -->
  <xsl:template match="title">
    <h2>
      <a name="{.}"/>
      <xsl:value-of select="." />
    </h2>
  </xsl:template>

  <!-- <description> is turned into a <p> -->
  <xsl:template match="description">
    <p>
      <xsl:apply-templates />
    </p>
  </xsl:template>

  <!-- default rule: copy any node beneath <description> -->
  <xsl:template match="description//*">
    <xsl:copy>
      <xsl:copy-of select="@*" />
      <xsl:apply-templates />
    </xsl:copy>
  </xsl:template>

  <!-- override rule: <link> nodes get special treatment -->
  <xsl:template match="description//link">
    <a href="#{@ref}">
      <xsl:apply-templates />
    </a>
  </xsl:template>

  <!-- default rule: ignore any unspecific text node -->
  <xsl:template match="text()" />

  <!-- override rule: copy any text node beneath description -->
  <xsl:template match="description//text()">
    <xsl:copy-of select="." />
  </xsl:template>

</xsl:stylesheet>

入力 XML に対して次の出力が生成されます (注: 読みやすくするために tidy でパイプ処理しました。無関係な空白はプロセスで削除されました)。

<h1>List of books</h1>
<h2><a name="Stuff">Stuff</h2>
<p>This book is <i>great</i> if you need to know about stuff. I
suggest <a href="#Things">this one</a> if you need to know about
things.</p>
于 2009-10-06T12:59:47.903 に答える
0 
<root>
 <book>
  <title>Stuff</title>
  <description><![CDATA[
      This book is <i>great</i> if you need to know about stuff.
      I suggest <link ref="Things">this one</link> if you need to know
      about things.
  ]]></description>
 </book>
 [other books]
</root>
于 2009-10-06T12:28:29.813 に答える