14

QuickCheck-2.5.1.1を使用してQAを行っています。私は2つの純粋関数gold :: a -> Float とをテストf :: a -> Floatしていaます。インスタンスは任意です。

goldこれが参考計算であり、私fが最適化しているバリエーションです。

これまで、クイックチェックを使用した私のテストのほとんどは、のようなテストを使用してき\a -> abs (gold a - f a) < 0.0001ました。

ただし、平均誤差と標準偏差を知ることは私の設計を導くのに役立つので、しきい値を確認しながら統計を収集したいと思います。

QuickCheckを使用してこのような統計を収集する方法はありますか？

具体例

私が探している種類のものの具体的な例を与えるために、平方根を近似するための次の2つの関数があると仮定します。

-- Heron's method
heron :: Float -> Float
heron x = heron' 5 1
    where
      heron' n est
          | n > 0 = heron' (n-1) $ (est + (x/est)) / 2
          | otherwise = est

-- Fifth order Maclaurin series expansion
maclaurin :: Float -> Float
maclaurin x = 1 + (1/2) * (x - 1) - (1/8)*(x - 1)^2
                + (1/16)*(x - 1)^3 - (5/128)*(x - 1)^4
                + (7/256)*(x - 1)^5

これのテストは次のようになります。

test = quickCheck
       $ forAll (choose (1,2))
       $ \x -> abs (heron x - maclaurin x) < 0.02

したがって、テストの副作用として知りたいのは、統計abs (heron x - maclaurin x)（平均や標準偏差など）です。

4

1 に答える 1

4

Chris Kuklewicz と Ingo からのコメントのおかげで、この例で必要な統計を収集する次のようになりました。

resultToWeightList :: Result -> [(Double,Int)]
resultToWeightList r = [ (read s, n) | (s,n) <- labels r]

weightListMuSigma :: [(Double,Int)] -> (Double,Double)
weightListMuSigma wlst = (mu,sigma)  
  where 
    (weightSum,weightSqrSum,entryCount) = foldl addEntry (0,0,0) wlst
    addEntry (s,s2,c) (v,w) = (s + (v * w'), s2 + (v**2 * w'), c + w)
      where w' = fromIntegral w
    entryCount' = fromIntegral entryCount
    mu = weightSum / entryCount'
    var = weightSqrSum / entryCount' - mu**2
    sigma = sqrt var

quietCheckResult :: Testable prop => prop -> IO Result
quietCheckResult p = quickCheckWithResult args p
  where args = stdArgs { chatty = False }

test :: IO ()
test = do { r <- quietCheckResult $ forAll (choose (1,2)) test'
          ; let wlst = resultToWeightList r
          ; let (mu,sigma) = weightListMuSigma wlst 
          ; putStrLn $ "Average: " ++ show mu
          ; putStrLn $ "Standard Deviation: " ++ show sigma
          }
   where
     test' x = collect err (err < 0.1)
       where err = abs $ heron x - maclaurin x
于 2013-03-14T16:33:50.770 に答える