5

最近関数を作成したのに、データベースの関数リストに追加された場合に、SQL Server が呼び出し時にエラーを返すのはなぜだろうか。

たとえば、次の関数の場合、次のようなエラーが発生します。

declare @cats nvarchar(1000)
set @cats = 'a|b|c|d|e'

SELECT dbo.fncSplit(@Cats, '|')

エラー：

列 "dbo"、ユーザー定義関数または集計 "dbo.fncSplit" が見つからないか、名前があいまいです。

サンプル関数:

CREATE FUNCTION [dbo].fncSplit
(    
    @RowData NVARCHAR(MAX),
    @Delimeter NVARCHAR(MAX)
)
RETURNS @RtnValue TABLE 
(
    ID INT IDENTITY(1,1),
    Data NVARCHAR(MAX)
) 
AS
BEGIN 
    DECLARE @Iterator INT
    SET @Iterator = 1

    DECLARE @FoundIndex INT
    SET @FoundIndex = CHARINDEX(@Delimeter,@RowData)

    WHILE (@FoundIndex>0)
    BEGIN
        INSERT INTO @RtnValue (data)
        SELECT 
            Data = LTRIM(RTRIM(SUBSTRING(@RowData, 1, @FoundIndex - 1)))

        SET @RowData = SUBSTRING(@RowData,
                @FoundIndex + DATALENGTH(@Delimeter) / 2,
                LEN(@RowData))

        SET @Iterator = @Iterator + 1
        SET @FoundIndex = CHARINDEX(@Delimeter, @RowData)
    END

    INSERT INTO @RtnValue (Data)
    SELECT Data = LTRIM(RTRIM(@RowData))

    RETURN
END

どんな提案や解決策も大歓迎です。

4

1 に答える 1

8

これはテーブル値関数です。構文は次のとおりです。

declare @cats nvarchar(1000)
set @cats = 'a|b|c|d|e'

SELECT * from dbo.fncSplit(@Cats, '|')
于 2013-04-09T09:22:19.120 に答える