1

divisionノードに対する子の位置を取得するのに問題がありsectionます。ここに私のXMLファイルがあります: 

<document>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
</document>

そして、ここに私のXSLがあります: 

<xsl:template match="/">
   <xsl:for-each select="//section">
       <div class="section">
           <xsl:text>section </xsl:text>
           <xsl:value-of select="position ()"/>
           <xsl:apply-templates/>
       </div>
    </xsl:for-each>
</xsl:template>

<xsl:template match="division">
    <div class="division">
        <xsl:text>division </xsl:text>
        <xsl:value-of select='count(../preceding-sibling::section)+1' /><xsl:text>.</xsl:text>
        <xsl:value-of select="position ()"/>
        <xsl:apply-templates/>
    </div>
</xsl:template>

そして、位置が依存するこの種の出力が必要sectionです: 

section 1
division 1.1 
division 1.2
division 1.3
section 2
division 2.1
division 2.2
division 2.3

そして、これではありません：

section 1
division 1.2 
division 1.4
division 1.6
section 2
division 2.2
division 2.4
division 2.6

../section[position()]orのように思えます../ancestor/position()が違います… ありがとうございます！

4

1 に答える 1

2

の代わりにposition()、 を使用してみてくださいxsl:number。

例：

XML 入力

<document>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
    <section>
        <division>text of division</division>
        <division>text of division</division>
        <division>text of division</division>
    </section>
</document>

XSLT1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="text()"/>

    <xsl:template match="section|division">
        <xsl:value-of select="concat(name(),' ')"/>
        <xsl:number level="multiple" count="section|division"/>
        <xsl:text>&#xA;</xsl:text>
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

出力

section 1
division 1.1
division 1.2
division 1.3
section 2
division 2.1
division 2.2
division 2.3

編集: XSLT で行っていたことに近い別の例を次に示します。<p>（ただし、テキストをラップする要素を追加しました。

XSLT1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="text()"/>

    <xsl:template match="section|division">
        <div class="{name()}">
            <p>
                <xsl:value-of select="concat(name(),' ')"/>
                <xsl:number level="multiple" count="section|division"/>             
            </p>
            <xsl:apply-templates/>              
        </div>
    </xsl:template>

</xsl:stylesheet>

出力

<div class="section">
   <p>section 1</p>
   <div class="division">
      <p>division 1.1</p>
   </div>
   <div class="division">
      <p>division 1.2</p>
   </div>
   <div class="division">
      <p>division 1.3</p>
   </div>
</div>
<div class="section">
   <p>section 2</p>
   <div class="division">
      <p>division 2.1</p>
   </div>
   <div class="division">
      <p>division 2.2</p>
   </div>
   <div class="division">
      <p>division 2.3</p>
   </div>
</div>
于 2013-05-23T17:11:05.217 に答える