0

だから私が欲しいのは次のとおりです。画面上で跳ね返るボールが1つあります。これはうまくいきます+ランダムな方向に左または右に蹴ることができます。私は box2d を初めて使用し、アプリに複数のボールが必要です。私はネット上の優れたチュートリアルに従いました。私は自分が作ったものをほとんど理解していますが、しばらくの間、ボール1からボディエンを含むすべてをコピーしようとしています。その直後に「2」なので、2つの同一のボールが跳ね返ります。スクリーン。しかし、成功はありません。

スプライトとそのオブジェクトを簡単に「複製」する簡単な方法はありますか?

これはコードです:)

#import "HelloWorldLayer.h"

@implementation HelloWorldLayer

+ (id)scene {

    CCScene *scene = [CCScene node];
    HelloWorldLayer *layer = [HelloWorldLayer node];
    [scene addChild:layer];
    return scene;

}

- (id)init {



    if ((self=[super init])) {

        CGSize winSize = [CCDirector sharedDirector].winSize;

        // Create sprite and add it to the layer
        _ball = [CCSprite spriteWithFile:@"ball.png" rect:CGRectMake(0, 0, 52, 52)];
        _ball.position = ccp(100, 300);
        [self addChild:_ball];

        // Create a world
        b2Vec2 gravity = b2Vec2(0.0f, -8.0f);
        _world = new b2World(gravity);

        // Create ball body and shape
        b2BodyDef ballBodyDef;
        ballBodyDef.type = b2_dynamicBody;
        ballBodyDef.position.Set(100/PTM_RATIO, 300/PTM_RATIO);
        ballBodyDef.userData = _ball;
        _body = _world->CreateBody(&ballBodyDef);

        b2CircleShape circle;
        circle.m_radius = 26.0/PTM_RATIO;

        b2FixtureDef ballShapeDef;
        ballShapeDef.shape = &circle;
        ballShapeDef.density = 1.0f;
        ballShapeDef.friction = 0.2f;
        ballShapeDef.restitution = 0.4f;
        _body->CreateFixture(&ballShapeDef);

        [self schedule:@selector(tick:)];

        // Create edges around the entire screen
        b2BodyDef groundBodyDef;
        groundBodyDef.position.Set(0,0);

        b2Body *groundBody = _world->CreateBody(&groundBodyDef);
        b2EdgeShape groundEdge;
        b2FixtureDef boxShapeDef;
        boxShapeDef.shape = &groundEdge;

        //WALL DEFINITIONS
        //floor wall
        groundEdge.Set(b2Vec2(0,0), b2Vec2(winSize.width/PTM_RATIO, 0));
        groundBody->CreateFixture(&boxShapeDef);
        //roof wall
        groundEdge.Set(b2Vec2(0,0), b2Vec2(0,winSize.height/PTM_RATIO));
        groundBody->CreateFixture(&boxShapeDef);
        //left wall
        groundEdge.Set(b2Vec2(0, winSize.height/PTM_RATIO),
                       b2Vec2(winSize.width/PTM_RATIO, winSize.height/PTM_RATIO));
        groundBody->CreateFixture(&boxShapeDef);
        //right wall
        groundEdge.Set(b2Vec2(winSize.width/PTM_RATIO, winSize.height/PTM_RATIO),
                       b2Vec2(winSize.width/PTM_RATIO, 0));
        groundBody->CreateFixture(&boxShapeDef);


         //Do the kick every 5 seconds
         //[self schedule:@selector(kick) interval:5.0];

        [self setTouchEnabled:YES];

    }
    return self;

}

- (void)tick:(ccTime) dt {

    _world->Step(dt, 10, 10);
    for(b2Body *b = _world->GetBodyList(); b; b=b->GetNext()) {
        if (b->GetUserData() != NULL) {
            CCSprite *ballData = (CCSprite *)b->GetUserData();
            ballData.position = ccp(b->GetPosition().x * PTM_RATIO,
                                    b->GetPosition().y * PTM_RATIO);
            ballData.rotation = -1 * CC_RADIANS_TO_DEGREES(b->GetAngle());
        }
    }

}

//do the kick every 5 seconds
/*- (void)kick {
    b2Vec2 force = b2Vec2(30, 30);
    _body->ApplyLinearImpulse(force,_body->GetPosition());
}*/

- (void)ccTouchesBegan:(UITouch *)touch withEvent:(UIEvent *)event {
    randomGetal = ((arc4random() % 20) - 10);
    b2Vec2 force = b2Vec2(randomGetal, 10);
    _body->ApplyLinearImpulse(force, _body->GetPosition());
}

- (void)dealloc {
    delete _world;
    _body = NULL;
    _world = NULL;
    [super dealloc];
}

@end
4

1 に答える 1

1

コードでは、単一のボールを作成しました。あなたがやりたいことは、物理シミュレーションで個別の b2Body を持つ複数のボールを作成することだと思います。

これを行うにはいくつかの方法がありますが、ここでは「ブルート フォース アプローチ」に固執します。

次のような静的関数を作成します。

static b2Body* CreateBall(b2World* world, CCNode* node, CCPoint position)
{
  // Create sprite and add it to the layer
    CCSprite* ballSprite = [CCSprite spriteWithFile:@"ball.png" rect:CGRectMake(0, 0, 52, 52)];
    ballSprite.position = ccp(position.x, position.y);
    [node addChild:ballSprite];

    // Create ball body and shape
    b2BodyDef ballBodyDef;
    ballBodyDef.type = b2_dynamicBody;
    ballBodyDef.position.Set(position.x/PTM_RATIO, position.y/PTM_RATIO);
    ballBodyDef.userData = ballSprite;
    b2Body* body = world->CreateBody(&ballBodyDef);

    b2CircleShape circle;
    circle.m_radius = 26.0/PTM_RATIO;

    b2FixtureDef ballShapeDef;
    ballShapeDef.shape = &circle;
    ballShapeDef.density = 1.0f;
    ballShapeDef.friction = 0.2f;
    ballShapeDef.restitution = 0.4f;
    body->CreateFixture(&ballShapeDef);

    return body;

}

注：これを入力しました。コンパイルしませんでした。少し微調整が必​​要かもしれません。

新しいボールを作成し、ボールを配置したいワールドと位置にパスするたびに、これを呼び出します。

これはあなたが必要としていたものでしたか？

私のサイトhttp://www.NonlinearIdeas.comには、Box2D を使用してグラフィックスなどを操作するより大きな例 (およびコード) があります。

于 2013-11-09T14:02:17.067 に答える