perl - Perl を使用してパスワードで保護された PPT ファイル

Question

Perl で以下の Microsoft プレゼンテーション オブジェクト プロパティを使用する方法を教えてください。

http://msdn.microsoft.com/en-us/library/office/bb251459(v=office.12).aspx

基本的に、Password プロパティを使用してプレゼンテーションを保護したいと考えています。

Answer 1

このスクリプトは、上記の @FtLie からのコメントに従って、 angiehopeの perlmonks の記事に基づいています。Office 2010 でこれをテストしました。スクリプトは、スクリプトと同じファイルに ppt_test.ppt というファイルを作成し、保存されたドキュメントにパスワード 'secret' を設定します。

use strict;
use warnings;
use v5.10;

use Try::Tiny;
use Data::Dumper;
use Carp;

use FindBin qw ($Bin);

use Win32::OLE qw( in CP_UTF8 );
Win32::OLE->Option( CP => CP_UTF8 );
$Win32::OLE::Warn = 3;
my $filename = "$Bin/ppt_test.ppt";
unlink $filename if (-e $filename);

print( "Starting Powerpoint Object\n" );
my $power = Win32::OLE->GetActiveObject('Powerpoint.Application') ||
    Win32::OLE->new('Powerpoint.Application', 'Quit');

my $ppt = $power->Presentations->Add();
# 12 = blank layout
my $slide = $ppt->Slides->Add(1,12);
# 1 = text in horizontal direction, the next two numbers describe the position
# and the last numbers the width and height of the box
my $new_textbox = $slide->Shapes->AddTextbox(1,30,30,600,200);
my $text_frame = $new_textbox->TextFrame;
my $text_range = $text_frame->TextRange;
$text_range->{Text} = "Please print \x{03B1},\x{03B2},\x{03B3}";

#   Now set the password
my $password = 'secret';
$ppt->{Password} = $password;

$ppt->SaveAs($filename);
$ppt->Close();