perl - 2 つの日付間の日数を計算する (モジュールを使用しない)

Question

私はこれをよく検索しましたが、すべてのソリューションが何らかのモジュールを使用しているようです。

yyyymmdd形式の日付が 2 つあります。モジュールを使用せずに、これらの日付間の日数を計算する簡単な方法を知りたいです。

例: 日付 1: 20130625 日付 2: 20130705

日数 = 10

PS: スクリプトを実行するサーバーの制限により、モジュールを使用できません。Perl バージョン - 5.8.4

Answer 1

sub yyyymmdd_to_rata_die {
    use integer;
    my ( $y, $m, $d ) = $_[0] =~ /\A([0-9]{4})([0-9]{2})([0-9]{2})\z/
        or return;

    my $adj;

    # make month in range 3..14 (treat Jan & Feb as months 13..14 of prev year)
    if ( $m <= 2 ) {
        $y -= ( $adj = ( 14 - $m ) / 12 );
        $m += 12 * $adj;
    }
    elsif ( $m > 14 ) {
        $y += ( $adj = ( $m - 3 ) / 12 );
        $m -= 12 * $adj;
    }

    # add: day of month, days of previous 0-11 month period that began w/March,
    # days of previous 0-399 year period that began w/March of a 400-multiple
    # year), days of any 400-year periods before that, and 306 days to adjust
    # from Mar 1, year 0-relative to Jan 1, year 1-relative (whew)

    $d += ( $m * 367 - 1094 ) / 12 + $y % 100 * 1461 / 4 + ( $y / 100 * 36524 + $y / 400 ) - 306;
}

print yyyymmdd_to_rata_die(20130705) - yyyymmdd_to_rata_die(20130625);