0

薬の定義欄があります。[product name(PN)]定義を、[doseform(DF)]、[total dose(TD)]およびに分割したい[units]。例えば：

BENADRYL: MYLANTA 1:1 SOLUTION(Benadryl mylanta(PN),Sol(DF),1:1(TD),NULL(units))
MASK AND SPACER (Mark and Spacer(PN),NUll,NUll,NUll)
BL VITAMIN B-6 50 MG  TABS(BL Vitamin(PN),Tabs(DF),50(TD),MG(Units))
4

1 に答える 1

1

私はあなたのデータについていくつかの仮定を立てました。1 は、最初の開き括弧が定義を開始することです。名前の定義の前に括弧はありません。また、製品定義構造は変更されないと想定しています。

したがって、あなたの答えを得るために、変更された分割文字列関数を使用しました。これをベースとして使用しました：T-SQL分割文字列

ここでの違いは、関数が 2 列のテーブルを返すため、定義部分を識別できることです。

CREATE FUNCTION dbo.splitstring_custom
  (
   @stringToSplit VARCHAR(MAX)
  )
RETURNS @returnList TABLE
  (
   [Type] [nvarchar](20)
  ,[Name] [nvarchar](500)
  )
AS 
BEGIN

    DECLARE @name NVARCHAR(255)
    DECLARE @pos INT
    DECLARE @colidx INT = 1

    WHILE CHARINDEX(',', @stringToSplit) > 0 
          BEGIN
                SELECT  @pos = CHARINDEX(',', @stringToSplit)  
                SELECT  @name = SUBSTRING(@stringToSplit, 1, @pos - 1)

                INSERT  INTO @returnList
                        SELECT  CASE WHEN @colidx = 1 THEN 'Product Name'
                                     WHEN @colidx = 2 THEN 'Dose Form'
                                     WHEN @colidx = 3 THEN 'Total Dose'
                                     WHEN @colidx = 4 THEN 'Units'
                                END
                               ,@name

                SELECT  @stringToSplit = SUBSTRING(@stringToSplit, @pos + 1, LEN(@stringToSplit) - @pos)
                SET @colidx += 1
          END

    INSERT  INTO @returnList
            SELECT  CASE WHEN @colidx = 1 THEN 'Product Name'
                         WHEN @colidx = 2 THEN 'Dose Form'
                         WHEN @colidx = 3 THEN 'Total Dose'
                         WHEN @colidx = 4 THEN 'Units'
                    END
                   ,@stringToSplit

    RETURN
END

次に、文字列操作を使用して定義の関連部分を取得します。

SUBSTRING(medication, CHARINDEX('(', medication) + 1, LEN(medication) - (CHARINDEX('(', medication) + 1))

次に、結果をPIVOTして平坦化します。

DECLARE @t TABLE (id varchar(20), medication varchar(100))

INSERT INTO @t VALUES ('BENADRYL', 'BENADRYL: MYLANTA 1:1 SOLUTION(Benadryl mylanta(PN),Sol(DF),1:1(TD),NULL(units))')
INSERT INTO @t VALUES ('MASK', 'MASK AND SPACER (Mark and Spacer(PN),NULL,NULL,NULL)')
INSERT INTO @t VALUES ('BL VITAMIN', 'BL VITAMIN B-6 50 MG  TABS(BL Vitamin(PN),Tabs(DF),50(TD),MG(Units))')

SELECT  id, [Product Name], [Dose Form], [Total Dose], [Units]
FROM    (SELECT id, Type, Name
         FROM   @t t
         CROSS APPLY dbo.splitstring_custom(SUBSTRING(medication, CHARINDEX('(', medication) + 1, LEN(medication) - (CHARINDEX('(', medication) + 1)))
        ) X PIVOT ( MAX(Name) FOR TYPE IN ([Product Name], [Dose Form], [Total Dose], [Units]) ) pvt
于 2013-08-21T23:52:22.430 に答える