list - スキームの 2 要素リストの最後にシンボルを追加する

Question

これまでのところ、

(define insert-3
  (lambda (sym ls)
    (cond
      [(null? ls) '()]
      [else (cons sym (insert-3 (caadr ls)))])))

caadr は 2 つの要素のリストに存在しないため、間違っていることはわかっています。しかし、リストの最後に記号を追加する方法がわかりません。

Answer 1

仮定

sym is 'c
ls  is '(a b)

次に、結果は次のように構築されます

> (cons 'a (cons 'b (list 'c)))
'(a b c)

または同等のもの

> (cons 'a (cons 'b (cons 'c null)))
'(a b c)

したがって、プロシージャは、ls を消費するまで各要素をコンスする必要があり、その時点でコンス (list sym) または (cons sym null) を実行する必要があります。

(define insert-3 
  (lambda (sym ls) 
    (cond 
      [(null? ls) (list sym)] 
      [else       (cons (car ls) (insert-3 sym (cdr ls)))])))

そのような

   (insert-3 'c '(a b))
=> (cons 'a (insert-3 'c '(b)))
=> (cons 'a (cons 'b (insert-3 'c '())))
=> (cons 'a (cons 'b (list 'c)))

これは、任意の長さのリストで機能します。

> (insert-3 'c '(a b))
'(a b c)
> (insert-3 'e '(a b c d))
'(a b c d e)

Answer 2

これは非常に単純な関数です:

(define (insert-3 sym lst)
  (reverse (cons sym (reverse lst))))

ここに別のものがあります

(define (insert-3 sym lst)
  (assert (= 2 (length lst)))
  (let ((frst (car  lst))
        (scnd (cadr lst)))
    (list frst scnd sym)))

少し効率的に再帰について考え始めたい場合は、次のようにします。

(define (insert-at-end! sym lst)
  (if (null? lst)
      (list sym)
      (let looking ((l lst))
        (if (null? (cdr l))
            (begin (set-cdr! l (list sym))  ;; replace last `cdr`
                   lst)                     ;; return modified `lst`
            (looking (cdr l))))))
> (insert-at-end! 1 '(5 4 3 2))
(5 4 3 2 1)
> (insert-at-end! 1 '(2))
(2 1)
> (insert-at-end! 1 '())
(1)