3

ファイルのパスのみを表示するために %~p を実行できるようにしたい。しかし、ループで使用すると正しい構文を取得できません(EnableDelayedExpansionを使用)

これが私のコードです：

@echo off
set "dir1=%TMP%\opt"
set "dir2=c:\opt"
set "empty="

setlocal EnableDelayedExpansion
for /f %%F in ('dir  /a:-d /s /b /r "%dir1%"') do (
  set "file_path=%%F"
  set "file_name=%%~nF"
  set "new_path=!file_path:%dir1%=%dir2%!"
  set "new_path=!new_path:!file_name!=%empty%" //This command is problematic
  echo !new_path!
)
endlocal

これを行う方法はありますか？

4

1 に答える 1

2

ファイルパスだけを取得して置き換える方法は次のとおりです。

@echo off
setlocal EnableDelayedExpansion

set "dir1=%TMP%\opt"
set "dir2=c:\opt"

pushd "%dir1%" && for /f %%F in ('dir /a:-d /b /r /s') do (
    set "file_path=%%~dpF"
    set "new_path=!file_path:%dir1%=%dir2%!"
    echo !new_path!
) & popd

endlocal
exit /b 0

説明

主な変更点は~dp、変数の修飾子の使用です。これにより、ファイル名なしで完全なファイル パスが取得されます。

dir1 置換の使用法は正しかったです。ファイル名の置換が悪かったのです。修飾子を使用する~dpことで、ファイル名の置換部分を完全にスキップできます。

ループが作業ディレクトリの設定を開始する前pushdに、一度だけ呼び出されます。for

チュートリアル:

  • 作業ディレクトリをdir1
  • そのディレクトリとサブディレクトリ内のすべてのファイルをループします。
  • 各ファイルについて、ファイルパスだけを取得するのではC:\Path\opt\subなくC:\path\opt\sub\file.ext
  • C:\path\optをに置き換えますC:\opt
  • 結果を表示します。
  • popdは、作業ディレクトリを の前の状態に復元しpushdます。

以下は、for /?ヘルプ テキストのすべての変数修飾子のリストです。

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

The modifiers can be combined to get compound results:

%~dpI       - expands %I to a drive letter and path only
%~nxI       - expands %I to a file name and extension only
%~fsI       - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
               environment variable for %I and expands to the
               drive letter and path of the first one found.
%~ftzaI     - expands %I to a DIR like output line

In the above examples %I and PATH can be replaced by other valid
values.  The %~ syntax is terminated by a valid FOR variable name.
Picking upper case variable names like %I makes it more readable and
avoids confusion with the modifiers, which are not case sensitive.
于 2013-10-11T16:47:28.090 に答える