0

この形式でいくつかの RGB 色を表すセルがあります。

RRR-GGG-BBB

各色が「-」記号で区切られていることがわかります。

必要なのは、「GGG」データを取得することです。たとえば、12-1-256 の場合、出力セルは「1」である必要があります。

色は常に 3 文字ではなく、2 文字または 1 文字の場合もあります。

MID 関数を使用しようとしましたが成功しませんでした。これにより、常に 3 つの文字が得られます (定義したように...)。

=MID(E2,SEARCH("-",E2,1)+1,3)

ありがとうございました

4

3 に答える 3

2

FIND() を使用して - 文字のインデックスを取得し、次に LEFT() および RIGHT() を使用してそれらのインデックス間の文字を抽出する必要があります。

たとえば、文字列がセル A1 にある場合、次のようにすることができます。

Set B1 to =FIND("-",A1)                ' gives you index of first -
set C1 to =LEFT(A1,B1-1)               ' gives you RRR
set D1 to =RIGHT(A1,LEN(A1)-B1)       ' gives you GGG-BBB
set E1 to =FIND("-",D1)                ' gives you index of second -
set F1 to =LEFT(D1,E1-1)               ' gives you GGG
set G1 to =RIGHT(D1,LEN(D1)-E1)        ' gives you BBB

必要に応じて、もちろん、これらを 1 つの式に組み合わせて、上記の式の一部を次のように置き換えることで、GGG だけを取得することもできます。

set B1 to =LEFT(RIGHT(A1,LEN(A1)-FIND("-",A1)),FIND("-",RIGHT(A1,LEN(A1)-FIND("-",A1)))-1)
于 2013-11-04T12:44:10.813 に答える
1

言語設定によっては、これでうまくいくはずです;。,

=LEFT(RIGHT(A1; LEN(A1)-FIND("-"; A1)); FIND("-";RIGHT(A1; LEN(A1)-FIND("-"; A1)))-1)

ソース

于 2013-11-04T12:37:12.457 に答える
0

これを試して：

=TRIM(MID(SUBSTITUTE(A1,"-",REPT(" ",999)),2*999-998,999))

"-"- は区切り文字で、2- は 2 番目の項目です。

説明については、これを参照してください。

于 2013-11-04T16:34:11.853 に答える