591

更新: 2016 年になった今、私はこれに PowerShell を使用しますが、特にdate. @npocmaka のhttps://stackoverflow.com/a/19799236/8479を参照してください。

ファイル名に入れることができる形式で現在の日時を取得するために使用できる Windows コマンド ライン ステートメントは何ですか?

名前の一部として現在の日付と時刻を含むアーカイブにディレクトリを圧縮する .bat ファイルが必要です。たとえば、.bat ファイルが必要ですCode_2008-10-14_2257.zip。マシンの地域設定に関係なく、これを行う簡単な方法はありますか?

日付の形式は特に気にしません。理想は yyyy-mm-dd ですが、単純なものであれば何でもかまいません。

これまでのところ、私はこれを持っています。これは私のマシンで私に与えますTue_10_14_2008_230050_91:

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

私はこれで我慢できますが、少しぎこちないようです。理想的には、より簡潔で、前述の形式になります。

Windows Server 2003 と Windows XP Professional を使用しています。これを実現するために追加のユーティリティをインストールしたくありません (ただし、適切な日付の書式設定を行うものがあることは認識しています)。

4

30 に答える 30

711

現在の日付をMMDDYYYY形式で取得するには、Windowsバッチファイル（.bat）を参照してください。

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime%

24時間制/軍用形式の時間を希望する場合は、2番目のFOR行を次のように置き換えることができます。

For /f "tokens=1-2 delims=/:" %%a in ("%TIME%") do (set mytime=%%a%%b)

C：>。\ date.bat
2008-10-14_0642

地域の日/月の順序に関係なく日付が必要な場合は、ISOの順序であるため、ソースとして「WMICosGETLocalDateTime」を使用できます。

@echo off
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set ldt=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2% %ldt:~8,2%:%ldt:~10,2%:%ldt:~12,6%
echo Local date is [%ldt%]

C：>test.cmd
ローカル日付は[2012-06-1910：23：47.048]です

于 2008-10-14T22:36:53.733 に答える
121

時間設定に依存しない 2 つの方法があります (どちらも:How get data/time independent from localization: から取得)。また、どちらも曜日を取得し、どちらも管理者権限を必要としません!:

  1. MAKECAB - すべての Windows システムで動作します (高速ですが、小さな一時ファイルが作成されます) (foxidrive スクリプト):

    @echo off
pushd "%temp%"
makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul
for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do (
   set "current-date=%%e-%%b-%%c"
   set "current-time=%%d"
   set "weekday=%%a"
)
del ~.*
popd
echo %weekday% %current-date% %current-time%
pause

    get-date 関数の詳細については、こちらをご覧ください。

  2. ROBOCOPY - Windows XP および Windows Server 2003 のネイティブ コマンドではありませんが、Microsoft サイト からダウンロードできます。ただし、Windows Vista 以降のすべてに組み込まれています。

    @echo off
setlocal
for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
 set "dow=%%D"
 set "month=%%E"
 set "day=%%F"
 set "HH=%%G"
 set "MM=%%H"
 set "SS=%%I"
 set "year=%%J"
)

echo Day of the week: %dow%
echo Day of the month : %day%
echo Month : %month%
echo hour : %HH%
echo minutes : %MM%
echo seconds : %SS%
echo year : %year%
endlocal

    さらに、他の Windows スクリプト言語を使用する方法が 3 つあります。それらはより柔軟性を提供します。たとえば、年間通算週、時間 (ミリ秒) などを取得できます。

  3. JScript/バッチハイブリッド (名前を付けて保存する必要があります.bat)。JScript は、 Windows Script Hostの一部として、NT 以降のすべてのシステムで利用できます(ただし、まれにレジストリを介して無効にすることができます)。

    @if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment

@echo off
cscript //E:JScript //nologo "%~f0"
exit /b 0
*------------------------------------------------------------------------------*/

function GetCurrentDate() {
        // Today date time which will used to set as default date.
        var todayDate = new Date();
        todayDate = todayDate.getFullYear() + "-" +
                       ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" +
                       ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" +
                       ("0" + todayDate.getMinutes()).slice(-2);

        return todayDate;
    }

WScript.Echo(GetCurrentDate());

  4. VSCRIPT/BATCHハイブリッド (一時ファイルを使用せずにバッチ ファイル内に VBScript を埋め込んで実行することは可能ですか? ) JScript と同じケースですが、ハイブリッド化はそれほど完璧ではありません。

    :sub echo(str) :end sub
echo off
'>nul 2>&1|| copy /Y %windir%\System32\doskey.exe %windir%\System32\'.exe >nul
'& echo current date:
'& cscript /nologo /E:vbscript "%~f0"
'& exit /b

'0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
'1 = vbLongDate - Returns date: weekday, monthname, year
'2 = vbShortDate - Returns date: mm/dd/yy
'3 = vbLongTime - Returns time: hh:mm:ss PM/AM
'4 = vbShortTime - Return time: hh:mm

WScript.echo  Replace(FormatDateTime(Date,1),", ","-")

  5. PowerShell - .NET がインストールされているすべてのマシンにインストールできます - Microsoft からダウンロードします ( v1、v2、v3 (Windows 7 以降のみ))。デフォルトでは、Windows 7/Windows Server 2008 以降のすべてにインストールされています。

    C:\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"

    バッチファイルから使用するには:

    for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#

  6. 自己コンパイルされた jscript.net/batch (.NET のない Windows マシンを見たことがないので、これはかなり移植性があると思います):

    @if (@X)==(@Y) @end /****** silent line that start JScript comment ******

@echo off
::::::::::::::::::::::::::::::::::::
:::       Compile the script    ::::
::::::::::::::::::::::::::::::::::::
setlocal
if exist "%~n0.exe" goto :skip_compilation

set "frm=%SystemRoot%\Microsoft.NET\Framework\"

:: Searching the latest installed .NET framework
for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
    if exist "%%v\jsc.exe" (
        rem :: the javascript.net compiler
        set "jsc=%%~dpsnfxv\jsc.exe"
        goto :break_loop
    )
)
echo jsc.exe not found && exit /b 0
:break_loop


call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
::::::::::::::::::::::::::::::::::::
:::       End of compilation    ::::
::::::::::::::::::::::::::::::::::::
:skip_compilation

"%~n0.exe"

exit /b 0


****** End of JScript comment ******/
import System;
import System.IO;

var dt=DateTime.Now;
Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));

  7. Logman年と曜日は取得できません。これは比較的遅く、一時ファイルも作成し、logman がログ ファイルに記録するタイム スタンプに基づいています。Windows XP以降のすべてで動作します。おそらく、私を含む誰もが使用することはありませんが、もう1つの方法です...

    @echo off
setlocal
del /q /f %temp%\timestampfile_*

Logman.exe stop ts-CPU 1>nul 2>&1
Logman.exe delete ts-CPU 1>nul 2>&1

Logman.exe create counter ts-CPU  -sc 2 -v mmddhhmm -max 250 -c "\Processor(_Total)\%% Processor Time" -o %temp%\timestampfile_ >nul
Logman.exe start ts-CPU 1>nul 2>&1

Logman.exe stop ts-CPU >nul 2>&1
Logman.exe delete ts-CPU >nul 2>&1
for /f "tokens=2 delims=_." %%t in  ('dir /b %temp%\timestampfile_*^&del /q/f %temp%\timestampfile_*') do set timestamp=%%t

echo %timestamp%
echo MM: %timestamp:~0,2%
echo dd: %timestamp:~2,2%
echo hh: %timestamp:~4,2%
echo mm: %timestamp:~6,2%

endlocal
exit /b 0

  8. 年の週と曜日も提供するが、ミリ秒ではなくWMICを使用するもう 1 つの方法(ミリ秒については、foxidrive の回答を確認してください):

    for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
echo %day%
echo %DayOfWeek%
echo %hour%
echo %minute%
echo %month%
echo %quarter%
echo %second%
echo %weekinmonth%
echo %year%

  9. さまざまな言語設定と互換性があり、可能な限り高速になるように、いくつかの努力を払ってTYPEPERFを使用します。

    @echo off
setlocal

:: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance
::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=")

for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=")
set "mon="
for /f "skip=2 delims=," %%# in ('typeperf "\UDP%v%\*" -si 0 -sc 1') do (
   if not defined mon (
      for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do (
        set mon=%%a
        set date=%%b
        set year=%%c
        set hour=%%d
        set minute=%%e
        set sec=%%f
        set ms=%%g
      )
   )
)
echo %year%.%mon%.%date%
echo %hour%:%minute%:%sec%.%ms%
endlocal

  10. MSHTAでは、上記の #3 で示した JScript メソッドと同様の JavaScript メソッドを呼び出すことができます。月の値を含む JavaScript の Date オブジェクト プロパティには、1 ～ 12 ではなく、0 ～ 11 の番号が付けられていることに注意してください。したがって、値 9 は 10 月を意味します。

    <!-- : Batch portion

@echo off
setlocal

for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I"

rem Display all variables beginning with "now."
set now.

goto :EOF

end batch / begin HTA -->

<script>
    resizeTo(0,0)
    var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1),
        now = new Date(),
        props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes',
            'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay',
            'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth',
            'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString',
            'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'],
        output = [];

    for (var i in props) {output.push(props[i] + '()=' + now[props[i]]())}
    close(fso.Write(output.join('\n')));
</script>
于 2013-11-05T21:21:53.570 に答える
118

地域に依存しない日時の解析

%DATE%コマンドとコマンドの出力形式dirは地域に依存するため、堅牢でもスマートでもありません。date.exe ( UnxUtilsの一部) は、考えられる形式で日付と時刻の情報を提供します。を使用して、任意のファイルから日付/時刻情報を抽出することもできますdate.exe。

例: (cmd-script では % の代わりに %% を使用)

date.exe +"%Y-%m-%d"
2009-12-22

date.exe +"%T"
18:55:03

date.exe +"%Y%m%d %H%M%S: Any text"
20091222 185503: 任意のテキスト

date.exe +"Text: %y/%m/%d-any text-%H.%M"
テキスト: 09/12/22-任意のテキスト-18.55

Command: date.exe +"%m-%d """%H %M %S """"
07-22 "18:55:03"`

参照ファイルからの日付/時刻情報:
date.exe -r c:\file.txt +"The timestamp of file.txt is: %Y-%m-%d %H:%M:%S"

CMD スクリプトで使用して、年、月、日、時刻の情報を取得します。

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

CMD スクリプトで使用して、必要な形式でタイムスタンプを取得します。

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

参照ファイルから日付/時刻情報を抽出します。

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

ファイルに日付/時刻情報を追加する:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

date.exe は、インストールを必要としない無料の GNU ツールの一部です。

注: 検索パスにある任意のディレクトリにコピーすると、Windows 組み込みコマンドdate.exeを使用する他のスクリプトが失敗する可能性があります。date

于 2009-12-23T09:40:23.903 に答える
44

これは、ローカルに依存せずに動作する alt.msdos.batch.nt のバリアントです。

これをテキスト ファイルに入れます。たとえば、getDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
    :: Works on any NT/2k machine independent of regional date settings
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
    for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
        set '%%a'=%%i
        set '%%b'=%%j
        set '%%c'=%%k))
    if %'yy'% LSS 100 set 'yy'=20%'yy'%
    set Today=%'yy'%-%'mm'%-%'dd'% 
    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]

    :EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

stderr へのエラー メッセージなしでコードを機能させるには、%%a、%%b、%%c の変数割り当ての前後に一重引用符を追加する必要がありました。私のロケール (PT) は、「set = 20」のようなものが実行されるループ/解析のある段階でエラーを引き起こしていました。引用符は、割り当てステートメントの左側のトークン (空ですが) を生成します。

欠点は、「yy」、「mm​​」、「dd」などの乱雑なロケール変数名です。でもねえ、誰が気にします！

于 2010-07-08T10:50:58.477 に答える
39

私はこれを使用します（これも地域に依存しません（英国））

set bklog=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%%time:~3,2%
于 2009-04-12T13:13:23.517 に答える
35

このコードの最初の 4 行は、信頼できる YY DD MM YYYY HH Min Sec 変数を Windows XP Professional 以降で提供します。

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause
于 2014-09-07T19:47:40.953 に答える
26

残念ながら、これは地域の設定の影響を受けませんが、必要なことを実行します。

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

ウィキペディアで見つけることができるものは素晴らしいです。

于 2008-10-14T22:43:39.523 に答える
21

コマンド ラインで現在の日付を取得するには、次のスクリプトを使用してください。

echo %Date:~0,3%day
于 2011-07-15T13:00:25.487 に答える
15

別の方法（クレジット）：

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

ここでの私の答えは両方とも、地域の設定によって決定される日と月の順序に依然依存していることに注意してください-それを回避する方法がわかりません。

于 2008-10-14T22:36:49.943 に答える
14 
"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip
于 2009-12-04T19:44:01.493 に答える
13

これは実際には簡単ではありませんが、より柔軟な方法である可能性があります（クレジット）：

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%
于 2008-10-14T22:31:53.387 に答える
11

簡潔な答え ：

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result

長い答え

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE
于 2010-05-18T06:03:16.007 に答える
10

1行で日時を取得する方法は次のとおりです。

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

米国では、これは「yyyy-mm-dd hhmm」を出力します。地域の設定が異なると、%date% の出力も異なりますが、トークンの順序は変更できます。

別の形式が必要な場合は、トークンを再配置するか、別の (または使用しない) 区切り記号を使用して、echo ステートメントを変更します。

于 2010-10-04T20:57:03.313 に答える
9

この行を使用してください：

PowerShell -Command "get-date"
于 2014-11-19T08:51:50.313 に答える
9

ワンライナーの日付と時刻を取得するMatthew Johnson のワンライナー ソリューションは雄弁で便利です。

ただし、バッチ ファイル内から作業するには、簡単な変更が必要です。

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e
于 2013-04-28T16:05:38.040 に答える
7

そして、これは時間部分の同様のバッチファイルです。 

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional time settings
::
:: Gets the time in ISO 8601 24-hour format
::
:: Note that %time% gets you fractions of seconds, and time /t doesn't, but gets you AM/PM if your locale supports that.
:: Since ISO 8601 does not care about AM/PM, we use %time%
::
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    for /f "tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
      set 'hh'=%%i
      set 'mm'=%%j
      set 'ss'=%%k
      set 'ff'=%%l)
    ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%

    ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
    set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
    echo %timestring%

    :EOF

--jeroen

于 2011-01-03T13:26:05.157 に答える
7

オランダ語でも機能するように、 vMaxのバッチ ファイルで回答を変更しました。 オランダ語 - 私たちのように永続的 - 、、およびにいくつかの変更があり、元のバッチファイルが壊れています。
%date%date/tdate

他の Windows ロケールに対してもこれをチェックし、結果を報告できる人がいるとよいでしょう。
あなたの場所でバッチ ファイルが失敗した場合は、コマンド プロンプトに次の 2 つのステートメントの出力を含めてください。
echo:^|date
date/t

これは、バッチ ファイルから取得する必要がある出力のサンプルです。

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

理由についてのコメントを含む改訂されたコードは次のとおりです。

:: https://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by jeroen@pluimers.com for Dutch locale
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: In addition, date will display the current date before the input prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%

    :EOF

--jeroen

于 2011-01-03T12:55:17.483 に答える
6

これは私が使用したものです：

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

7-Zipアーカイブへのバックアップを自動化するためのさらなるアイデアが必要な場合は、アイデアを使用またはレビューできる無料/オープンプロジェクトがあります：http ：//wittman.org/ziparcy/

于 2008-10-14T22:29:00.490 に答える
5

私も同様の問題を抱えていました。暗号化されたファイルをFTPサーバーから毎日自動ダウンロードしています。gpgを使用してファイルを復号化し、ファイルの名前を現在の日付（YYYYMMDD形式）に変更し、復号化したファイルを正しい部門のフォルダーにドロップしたいと思いました。

私は日付に従ってファイルの名前を変更するためのいくつかの提案を経験しましたが、この単純な解決策に出くわすまで運がありませんでした。

for /f "tokens=1-5 delims=/ " %%d in ("%date%") do rename "decrypted.txt" %%g-%%e-%%f.txt

完全に機能しました（つまり、ファイル名は「2011-06-14.txt」として出力されます）。

（ソース）

于 2011-06-14T19:02:38.490 に答える
4

http://sourceforge.net/projects/unxutils/files/

ZIP ファイル内で "Date.exe" と呼ばれるものを探し、名前を "DateFormat.exe" に変更します (競合を避けるため)。

これを Windows の system32 フォルダーに入れます。

多くの「日付出力」オプションがあります。

ヘルプが必要な場合は、DateFormat.exe --h

出力を環境変数に入れる方法がわかりません... SETを使用しています。

于 2010-10-31T04:45:36.517 に答える
3

ISO 日付形式を生成する地域に依存しないソリューション:

rem save the existing format definition
for /f "skip=2 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate') do set FORMAT=%%a
rem set ISO specific format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d yyyy-MM-dd 1>nul:
rem query the date in the ISO specific format 
set ISODATE=%DATE%
rem restore previous format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d %FORMAT% 1>nul:

まだ最適化できるもの: 変更中に短期間で日付形式を使用すると、他のプロセスが混乱する可能性があります。したがって、既存のフォーマット文字列に従って出力を解析することは「より安全」になる可能性がありますが、より複雑になります

于 2011-09-06T12:09:39.790 に答える
-1

関数形式での参照用に、既知の場所が与えられます。このECHOTIMESTAMP呼び出しは、タイムスタンプを変数に取得する方法を示しています (DTSこの例では)。

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

ファイルに保存すると、timestamp.bat の出力は次のようになります。

ここに画像の説明を入力

于 2016-08-11T20:07:16.770 に答える
-3

すでに言及されている多くの方法があることを私は知っています。しかし、これがどのように行われるかを理解するために、それを分解する私の方法です。ステップバイステップの方法が好きな人に役立つことを願っています。

:: Check your local date format
echo %date%

    :: Output is Mon 08/15/2016

:: get day (start index, number of characters)
::         (index starts with zero)
set myday=%DATE:~0,4%
echo %myday%
    :: output is Mon 

:: get month
set mymonth=%DATE:~4,2%
echo %mymonth%
    :: output is 08

:: get date 
set mydate=%DATE:~7,2% 
echo %mydate%
    :: output is 15

:: get year
set myyear=%DATE:~10,4%
echo %myyear%
    :: output is 2016
于 2016-08-15T15:57:00.700 に答える