0

この問題について、次の点にご協力をお願いいたします。

data: PByteDIB データと DIBHeader を含むバイト配列 ( ) があります。


  TDibHeader = record
    size: Cardinal;
    width: Integer;
    height: Integer;
    planes: Word;
    bits: Word;
    compression: Cardinal;
    image_size: Cardinal;
    x_res: Integer;
    y_res: Integer;
    n_colors: Cardinal;
    important_colors: Cardinal;
  end;

CPU 使用率を低く抑えながら DIB を TBitmap に変換する方法

http://files.codes-sources.com/fichier.aspx?id=43989&f=GdipApi.pasを試しましたが成功しませんでした。

DIB をメモリ ストリームに割り当てました。


  DibMemStream.Clear;
  DibMemStream.SetSize(header.image_size);
  MoveMemory(DibMemStream.Memory,DibBuffer,header.image_size);

Bitmap.LoadFromMemoryStream(DibMemStream) の前にどこかに DIB ヘッダーが書かれているはずだと思います。どこかわからない。

アイデアはありますか？

ありがとうございました ！

4

2 に答える 2

3

次のスキームを使用して、メモリ内の画像を TBitmap に変換しました。

1) TBMPHeader 構造を埋める

  TBMPHeader = packed record
    bmfHeader: TBitmapFileHeader;
    bmiHeader: TBitmapInfoHeader;
    bmiColors: {depends on image format, may be absent};
  end;

2) BMPHeader + 画像データを MemoryStream に書き込む

3) TBitmap.LoadFromStream を使用して、MemoryStream から TBitmap をロードします。

bmiHeader 構造が既に埋められているようです。bmfHeader と (おそらく) bmiColors を追加します。

256 色のグレースケールのメモリ内イメージを TBitmap に変換するために使用したコードを次に示します (何年も前のことなので、詳細はありません)。

procedure TksImage.CopyToBitmap(Bitmap: TBitmap);
var
  Stream: TStream;

begin
  Stream:= TMemoryStream.Create;
  try
    SaveToStream(Stream);
    Stream.Position:= 0;
    Bitmap.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

procedure TksImage.SaveToStream(Stream: TStream);
type
  TBMPHeader = packed record
    bmfHeader: TBitmapFileHeader;
    bmiHeader: TBitmapInfoHeader;
    bmiColors: array[0..255] of TRGBQuad;
  end;

var
  BMPHeader: TBMPHeader;
  N: LongWord;
  I: Integer;

begin
  FillChar(BMPHeader, SizeOf(BMPHeader), 0);
  with BMPHeader.bmfHeader do begin
    bfType:= $4D42; {'BM'}
    bfOffBits:= SizeOf(BMPHeader);
    if FChannels = 4 then Dec(bfOffBits, SizeOf(BMPHeader.bmiColors));
    bfSize:= bfOffBits + LongWord(FImageSize);
  end;
  with BMPHeader.bmiHeader do begin
    biSize:= SizeOf(BMPHeader.bmiHeader);
    biWidth:= FWidth;
    biHeight:= FHeight;
    biPlanes:= 1;
    biBitCount:= 8 * FChannels;
    biCompression:= BI_RGB;
    biSizeImage:= FImageSize;
    {((((biWidth * biBitCount) + 31) and not 31) shr 3) * biHeight;}
  end;
  N:= 0;
  for I:= 0 to 255 do begin
    LongWord(bmpHeader.bmiColors[I]):= N;
    Inc(N, $010101);
  end;
  Stream.Write(BMPHeader, BMPHeader.bmfHeader.bfOffBits);
  Stream.Write(FImageData^, FImageSize);
end;
于 2010-01-29T23:42:55.707 に答える
0

Delphi コーディングを行ってから長い時間が経ちましたが、これをテストすることはできませんでしたが、DIB へのハンドルを提供できる場合は、関数 hDIBToTBitmap1() があり、このリンクでトリックを実行する必要があります。

http://www.efg2.com/Lab/Library/Delphi/Graphics/LeadToolsConversions.TXT

于 2010-01-29T18:01:26.593 に答える