0

アニメーションを毎回 120 ピクセル進めたい。代わりに、アニメーションは新しい位置から進むのではなく、一番下に戻ります。新しい位置を占めますが、常に最初に下に戻ります。アニメーションを毎回現在の位置から進めるにはどうすればよいですか?

GOAL
アニメーションを現在の新しい位置から 120 ピクセル進め、10 ピクセル後に繰り返すようにします。

問題
アニメーションは、進む前に毎回一番下にリセットされます。それが Tweener の問題なのか、ループの設定方法なのか、それとも関係のないものなのかはわかりません。このコードを変更する方法の例を教えていただければ幸いです。

代替テキスト http://www.ashcraftband.com/myspace/videodnd/tweener.jpg

NumbersView.as 'コードは機能しますが、説明したようにめちゃくちゃです'

package   
{ 
    import flash.display.DisplayObject; 
    import flash.display.MovieClip; 
    import flash.utils.Dictionary; 
    import flash.events.Event; 
    import caurina.transitions.Tweener; 

    public class NumbersView extends MovieClip 
    { 
        private var _listItems:Array; 
        private var previousNums:Array; 
        private const numHeight:int = 120; 

        public function NumbersView()  
        { 
            _listItems = new Array(); 
            previousNums = new Array(); 
            //Tweener.init();

            var item:NumberImage; 
            for (var i:Number = 0; i < 9; i++) { 
                item = new NumberImage(); 
                addChild(item); 
                item.x = i * item.width; 
                _listItems.push(item); 
            } 
        } 

        public function setTime($number:String):void { 
            var nums:Array = $number.split(""); 
            //trace("$number = " + $number);
            for (var i:Number = 0; i < nums.length; i++) { 
                if (nums[i] == previousNums[i]) continue; 
                Tweener.removeTweens(_listItems[i]);    

                //newY:int = -numHeight;
                var newY:int = int(nums[i]) * -numHeight;
                trace("newY = " + newY);
                trace("currY = " + _listItems[i].y);                
                if (_listItems[i].y < 0) _listItems[i].y = numHeight; 
                Tweener.addTween(_listItems[i], { y:newY, time:3 } ); 
            } 
            previousNums = nums; 
        } 
    } 
}

代替テキスト http://www.ashcraftband.com/myspace/videodnd/tweener_.jpg

Tweener http://hosted.zeh.com.br/tweener/docs/en-us/

4

1 に答える 1

0

あなたのコードでアイテムをアニメーション化することができました。アニメーション化されたアイテムがその位置で再起動するたびに、現在の位置から上に移動するように変更したのは次のとおりです。

オリジナル：

if (_listItems[i].y < 0) _listItems[i].y = numHeight;
Tweener.addTween(_listItems[i], { y:newY, time:3 } );

に変更:

//if (_listItems[i].y < 0) _listItems[i].y = numHeight; //get rid of this line
Tweener.addTween(_listItems[i], { y:_listItems[i].y+newY, time:3 } );

これのループ部分については、タイマーを使用できます。ここに、例としてまとめたものを示します。おそらく完璧ではありませんが、何をしたいかのアイデアが得られることを願っています。

package   
{ 
    import flash.display.DisplayObject; 
    import flash.display.MovieClip; 
    import flash.utils.Dictionary; 
    import flash.events.Event; 
    import flash.events.TimerEvent;
    import caurina.transitions.Tweener; 
    import flash.utils.Timer;

public class NumbersView extends MovieClip 
{ 
    private var _listItems:Array; 
    private var previousNums:Array; 
    private const numHeight:int = 120; 
    var t:Timer;

    public function NumbersView()  
    { 
        _listItems = new Array(); 
        previousNums = new Array(); 
        //Tweener.init();

        var item:NumberImage; 
        for (var i:Number = 0; i < 9; i++) { 
            item = new NumberImage(); 
            addChild(item); 
            item.x = i * item.width; 
            _listItems.push(item); 
        }

        t = new Timer( 1000 ) //1000ms = 1 second intervals
        t.addEventListener(TimerEvent.TIMER, onTimer);
        t.start();

    } 

    public function onTimer( e:TimerEvent):void {

        //this will run every 10th time firing
        if( t.currentCount % 10 == 0 ) {
            //do something to reset the listItems
            for (var i:Number = 0; i < _listItems.length; i++) { 
                _listItems[i].y = numHeight;
            }
        }

        //do your setTime function, I just randomly called it with random numbers
        setTime(Math.round(Math.random()*234567).toString());
    }

    public function setTime(number:String):void { 
        var nums:Array = number.split(""); 
        trace("$number = " + number);
        for (var i:Number = 0; i < nums.length; i++) { 
            if (nums[i] == previousNums[i]) continue; 
            Tweener.removeTweens(_listItems[i]);    

            //newY:int = -numHeight;
            var newY:int = int(nums[i]) * -numHeight;
            trace("newY = " + newY);
            trace("currY = " + _listItems[i].y);                

            Tweener.addTween(_listItems[i], { y:_listItems[i].y+newY, time:3 } ); 
        } 
        previousNums = nums; 
    } 
} 
}
于 2010-03-17T16:15:02.520 に答える