8

私がやりたいのは、Lazy C ++ .lzzファイルだけを記述し、ビルドの前にlzzを実行して、最終的なアプリケーションにビルドされる.cppファイルと.hファイルを生成することです。これは、mocがQtでどのように機能するかのようです。

これを行う方法はありますか？

4

3 に答える 3

9

これを行う方法の例を次に示します...最初にlzzプログラムを見つける必要があります。そのためには、次のfind_programコマンドを使用します。

find_program(LZZ_COMMAND lzz)

これLZZ_COMMANDはコンパイラのパスに設定されます。次に、CMakeカスタムコマンドを使用して、LZZファイルをC++ヘッダー/実装ファイルにコンパイルします。

add_custom_command(
    OUTPUT ${output}
    COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})

これにより、ソース外のビルドを行う場合に備えて、現在のビルドディレクトリにファイルが生成されます。また、出力が生成されたファイルであることを指定する必要があります。

set_source_files_properties(${output} PROPERTIES GENERATED TRUE)

それをすべてまとめると、次のようなCMakeLists.txtファイルが得られます。

cmake_minimum_required(VERSION 2.8)
project(lazy_test)
find_program(LZZ_COMMAND lzz)
function(lazy_compile filename)
    get_filename_component(base ${filename} NAME_WE)
    set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
    set(output ${base_abs}.cpp ${base_abs}.h)
    add_custom_command(
        OUTPUT ${output}
        COMMAND ${LZZ_COMMAND} -o ${CMAKE_CURRENT_BINARY_DIR} ${filename})
    set_source_files_properties(${output} PROPERTIES GENERATED TRUE)
endfunction()
lazy_compile(${CMAKE_CURRENT_SOURCE_DIR}/example.lzz)
add_executable(test example.cpp example.h)

最終的には、インクルードパスやその他のオプションをlzzに追加することもできます。すべてのLazyC++のものをモジュールファイルに配置し、CMakeLists.txtからそれを含めると、少しすっきりします。しかし、これが基本的な考え方です。

于 2010-04-22T11:59:47.270 に答える
6

richqのスクリプトに基づいて構築されたCMakeLists.txtを共有したかっただけです。*.cppファイルと*.hppファイルは、*。lzzファイルに適切に依存するようになりました。* .lzzファイルはプロジェクトに追加されますが（上記のabsenseの質問に答えます）、source_groupコマンドを使用して生成されたファイルとは別に保持されます。

私にとって残っている唯一の問題は、現在のファイルを*.lzzファイル用にコンパイルできないことです。

cmake_minimum_required(VERSION 2.8)

PROJECT(LzzTest)

find_program(LZZ_COMMAND lzz.exe)

# Syntax: 
#   add_lzz_file(<output> <lzz file>)
# Adds a build rule for the specified lzz file. The absolute paths of the generated 
# files are added to the <output> list. The files are generated in the binary dir.
# 
# TODO: Support for generating template files etc.
function(add_lzz_file output filename)
  # Only process *.lzz files
  get_filename_component(ext ${filename} EXT)
  if(NOT ext STREQUAL ".lzz")
    return()
  endif()

  set(header_extension "hpp")
  get_filename_component(base ${filename} NAME_WE)
  set(base_abs ${CMAKE_CURRENT_BINARY_DIR}/${base})
  set(outfiles ${base_abs}.cpp ${base_abs}.${header_extension})
  set(${output} ${${output}} ${outfiles} PARENT_SCOPE)

  #message("outfiles=${outfiles}, DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${filename}")
  add_custom_command(
    OUTPUT ${outfiles}
    COMMAND ${LZZ_COMMAND} 
      -o ${CMAKE_CURRENT_BINARY_DIR} # output dir
      -hx ${header_extension}
      -sl -hl -il -tl -nl -x # insert #line commands w/ absolute paths
      -sd -hd -id -td -nd # don't output files that didn't change
      ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
    DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/${filename}"
  )

  set_source_files_properties(${outfiles} PROPERTIES GENERATED TRUE)
endfunction()

include_directories(${CMAKE_CURRENT_BINARY_DIR})

set(SOURCES
  A.lzz
  B.lzz
  main.cpp
)

foreach(file ${SOURCES})
  add_lzz_file(GENERATED_SOURCES ${file})
endforeach()

source_group("" FILES ${SOURCES})
source_group(generated FILES ${GENERATED_SOURCES})

add_executable(LzzTest ${SOURCES} ${GENERATED_SOURCES})
于 2012-03-12T14:54:27.577 に答える
0

makeの場合：

sourcecode.h sourcecode.cpp: sourcecode.lzz
<TAB>lazy-cpp sourcecode.lzz

sourcecode.h、sourcecode.cpp、およびlazy-cppに正しい値を入力します。私はそれらを知りません。

于 2010-04-21T23:08:09.370 に答える