10

Oracle ストアド プロシージャから Web サービスへのアクセスに成功した人はいますか? もしそうなら、それは Java ストアード・プロシージャーでしたか? PL/SQL ストアド プロシージャですか。

ストアド プロシージャから WS にアクセスしてはいけない理由はありますか?

ここに私がこれまでに見つけたいくつかの参考文献があります

..明確にするために、これはSOAP呼び出し用です

4

2 に答える 2

13

まず、どのような種類の Web サービスを呼び出していますか? SOAPまたはRESTのいずれかを想定しています。

REST Web サービスの場合、単純な PL/SQL ストアド プロシージャで XPath を少し組み合わせて、UTL_HTTP で十分な場合がよくあります。

SOAP Web サービスの場合は、どれだけ洗練されている必要があるか (または希望するか) によって異なります。確かに、XQuery を使用して Web サービスの仕様を満たす XML ドキュメントを作成し、UTL_HTTP を使用してドキュメントを投稿して応答を取得し、XPath を使用してすべて PL/SQL で応答を解析できます。これは比較的手動で力ずくのソリューションですが、少数の Web サービスについて話している場合は、最小限のインフラストラクチャが必要であり、呼び出しがすぐにノックアウトされる可能性があります。

時間の経過とともに呼び出しが進化することが予想される場合、または多数の Web サービスを呼び出す多数のプロシージャが存在することが予想される場合は、UTL_DBWS のようなものに時間を投資することはおそらく理にかなっています (ただし、これは一般的に得られるものではありません)。数時間で作業します）。

于 2008-11-18T15:28:53.613 に答える
10

便利な関数で UTL_HTTP をラップするのは非常に簡単です。

FUNCTION post
(
    p_url     IN VARCHAR2,
    p_data    IN CLOB,
    p_timeout IN BINARY_INTEGER DEFAULT 60
) 
    RETURN CLOB
IS
    --
    v_request  utl_http.req;
    v_response utl_http.resp;
    v_buffer   CLOB;
    v_chunk    VARCHAR2(4000);
    v_length   NUMBER;
    v_index    NUMBER;
BEGIN

    v_index := 1;
    v_length := nvl(length(p_data), 0);

    -- configure HTTP
    utl_http.set_response_error_check(enable => FALSE);
    utl_http.set_detailed_excp_support(enable => FALSE);
    utl_http.set_transfer_timeout(p_timeout);

    -- send request
    v_request := utl_http.begin_request(p_url, 'POST','HTTP/1.0');
    utl_http.set_header(v_request, 'Content-Type', 'text/xml');
    utl_http.set_header(v_request, 'Content-Length', v_length);
    WHILE v_index <= v_length LOOP
        utl_http.write_text(v_request, substr(p_data, v_index, 4000));
        v_index := v_index + 4000;
    END LOOP;

    -- check HTTP status code for error
    IF v_response.status_code <> utl_http.http_ok THEN   
        raise_application_error(
            cn_http_error,
            v_response.status_code || ' - ' || v_response.reason_phrase
        );
    END IF;

    -- get response
    dbms_lob.createtemporary(v_buffer, FALSE);
    v_response := utl_http.get_response(v_request);
    BEGIN
        LOOP
            utl_http.read_text(v_response, v_chunk, 4000);
            dbms_lob.writeappend(v_buffer, length(v_chunk), v_chunk);
        END LOOP;
    EXCEPTION
        WHEN utl_http.end_of_body THEN NULL;
    END;
    utl_http.end_response(v_response);

    RETURN v_buffer;

END;

次に、SOAP エンベロープを POST するための何かが必要です。

FUNCTION invoke
(
    p_url IN VARCHAR2,
    p_method IN XMLTYPE,
    p_timeout IN NUMBER := 60
)
    RETURN XMLTYPE
IS
    -- calls the given SOAP service
    cn_procedure_name CONSTANT VARCHAR2(30) := 'invoke';
    --
    v_envelope XMLTYPE;
    v_response CLOB;
    v_fault XMLTYPE;
    v_sqlerrm VARCHAR2(2000);
BEGIN

    -- wrap method in SOAP envelope
    SELECT
        XMLElement(
            "soap:Envelope",
            XMLAttributes(
                'http://schemas.xmlsoap.org/soap/envelope/' AS "xmlns:soap"
            ),
            XMLElement(
                "soap:Body",
                p_method
            )
        )
    INTO
        v_envelope
    FROM
        dual;

    -- POST request
    v_response := post(
        p_url,
        '<?xml version="1.0" encoding="ISO-8859-1"?>' || chr(10) || v_envelope.getClobVal(),
        p_timeout
    );
    IF v_response IS NULL THEN
        RAISE null_response;
    END IF;

    -- parse response
    BEGIN
        v_envelope := XMLType(v_response);
    EXCEPTION
        WHEN OTHERS THEN
            v_sqlerrm := SQLERRM;
            RAISE xml_parse_error;
    END;

    -- check for a fault
    v_fault := v_envelope.extract(  
        '/soap:Envelope/soap:Body/soap:Fault', 
        'xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"'
    );
    IF v_fault IS NOT NULL THEN
        v_sqlerrm := v_fault.extract('.//faultstring/text()').getStringVal();
        RAISE soap_fault;
    END IF;

    -- the actual response is the child of the <soap:Body /> element
    RETURN v_envelope.extract(
        '/soap:Envelope/soap:Body/*[position() = 1]', 
        'xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"'
    );

END;

この例とは特に関係がないため、例外処理ブロックを削除したことに注意してください。

これにより、サービスの呼び出しに必要な XML を生成し、invoke を介して渡し、戻り値を解析する他のプロシージャを作成できます。

このソリューションは 9i データベースで開発したため、UTL_DBWS についてはまだ調べていません。しかし、それはうまく機能します。

于 2009-01-09T22:44:43.763 に答える