1

私はpdp-11にこのコードを持っています

tks = 177560
tkb = 177562
tps = 177564
tpb = 177566
lcs = 177546
. = torg + 2000

main:   mov #main, sp
        mov #kb_int, @#60
        mov #200, @#62
        mov #101, @#tks
        mov #clock, @#100
        mov #300, @#102
        mov #100, @#lcs

loop:   mov @#tks,r2
        aslb r2
        bmi loop
        halt

clock:  tst bufferg
        beq clk_end
        mov #msg,-(sp)
        jsr pc, print_str
        tst (sp)+
        clr bufferg
        bic #100,@#tks
        clr @#lcs
clk_end:rti

kb_int: mov r1,-(sp)
        jsr pc, read_char
        movb r1,@buff_ptr
        inc buff_ptr
        bis #1,@#tks
        cmpb r1,#'q
        bne next_if
        mov #0, @#tks
next_if:cmpb r1,#32.
        bne end_kb_int
        clrb @buff_ptr
        mov #buffer,-(sp)
        jsr pc, print_str 
        tst (sp)+
        mov #buffer,buff_ptr
end_kb_int:
        mov (sp)+,r1
rti


;#############################
read_char:
        tstb @#tks
        bpl read_char
        movb @#tkb, r1
        rts pc
;#############################
print_char:
        tstb @#tps
        bpl print_char
        movb r1, @#tpb
        rts pc
;#############################
print_str:
        mov r1,-(sp)
        mov r2,-(sp)
        mov 6(sp),r2
str_loop:
        movb (r2)+,r1
        beq pr_str_end
        jsr pc, print_char
        br str_loop
pr_str_end:
        mov (sp)+,r2
        mov (sp)+,r1
        rts pc

. = torg + 3000
msg:.ascii<Something is wrong!>
    .byte 0
    .even
buff_ptr: .word buffer
buffer: .blkw 3
bufferg: .word 0

bufferg(最後の行)を変更できるコードの部分を誰か説明してもらえますか? 前もって感謝します

4

1 に答える 1

2

このプログラムで 3 つの基本的な機能ブロックを見つけました。

  1. キーボードからバッファへの文字の読み取り (kb_int:, read_char:など)
  2. 文字の印刷 ( print_char:, print_str:)
  3. 上記の読み取り/書き込み操作の正確性の監視 ( clock:)。

キーボードからデータが読み取られるセグメントに続くので、これはガード ワードだと思いますbufferg(bufferg は、バッファの 3 ワードの後のワード - 最後の 2 行です)。そのため、何か問題が発生した場合 (入力文字が多すぎるか、印刷が遅すぎる) は、buffergゼロ以外の値で埋められます。これはクロックでキャッチされます: (これは明らかにタイマー割り込みハンドラーです) -tst buffergゼロ値をテストし、それがゼロ (デフォルト値) に等しくない場合、メッセージ (msg:) 「何かが間違っています!」が印刷されbufferg、ゼロにリセットされますclr bufferg。

したがって、質問に対する短い答えは次のようになります: bufferg は in movb r1,@buff_ptrまたは in のいずれかで変更できますclr bufferg。

于 2010-06-13T21:18:23.613 に答える