1

以下に相当するクラスの JVM バイトコードを記述しようとしています。

public class foo {
    static String[] crr;
    public static void printString(String str) {
    System.out.println(str);
    }
    public static void main(String[] args) {
    crr = new String[10];
    crr[0] = "Hello";
    foo.printString(crr[0]);
    }
}

私が書いたバイトコード：

.class public foo
.super java/lang/Object
.field public static crr [Ljava/lang/String;
.method public <init>()V
    aload_0
    invokenonvirtual java/lang/Object/<init>()V
    return
.end method
.method public static printString(Ljava/lang/String;)V
    .limit locals 1
    .limit stack 2
    getstatic java/lang/System/out Ljava/io/PrintStream;
    aload_0
    invokevirtual java/io/PrintStream/println(Ljava/lang/String;)V
    return
.end method
.method public static main([Ljava/lang/String;)V
    .limit stack 20
    .limit locals 10
    bipush 9
    anewarray Ljava/lang/String;
    putstatic foo.crr [Ljava/lang/String;
    getstatic foo.crr [Ljava/lang/String;
    ldc 0
    ldc "Hello"
    aastore
    getstatic foo.crr [Ljava/lang/String;
    ldc 0
    aaload
    invokestatic foo.printString(Ljava/lang/String;)V
    return
.end method

Jasmine を使用してバイトコードを実行し、getfield/putfield の Bad Type Error を取得しましたが、その理由がわかりません。

Exception in thread "main" java.lang.VerifyError: (class: foo, method: main signature: ([Ljava/lang/String;)V) Bad type in putfield/putstatic
    at java.lang.Class.getDeclaredMethods0(Native Method)
    at java.lang.Class.privateGetDeclaredMethods(Class.java:2625)
    at java.lang.Class.getMethod0(Class.java:2866)
    at java.lang.Class.getMethod(Class.java:1676)
    at sun.launcher.LauncherHelper.getMainMethod(LauncherHelper.java:494)
    at sun.launcher.LauncherHelper.checkAndLoadMain(LauncherHelper.java:486)

問題がどこにあり、それを解決する方法を知っている人はいますか?

4

1 に答える 1

1

指示に誤りがありanewarrayます。それ以外の

anewarray Ljava/lang/String;

あなたは書く必要があります

anewarray java/lang/String
于 2016-01-14T20:07:26.200 に答える