1

リストのリストを持つ関数を作成しようとしています。これは、内側のリストと外側のリストの合計を乗算します。これまでのところ、リストを合計できます。X = (結果) を返す関数 sumlist([1..n],X) を作成しました。しかし、別の関数をその関数で有効に動作させることはできません。 is と = の両方を試しましたが、役に立ちませんでした。

4

3 に答える 3

2

これはあなたが意味するものですか？

prodsumlist([], 1).

prodsumlist([Head | Tail], Result) :-
    sumlist(Head, Sum_Of_Head),
    prodsumlist(Tail, ProdSum_Of_Tail),
    Result is Sum_Of_Head * ProdSum_Of_Tail.

ここsumlist/2で、SWI-Prolog ビルトインです。

使用例:

?- prodsumlist([[1, 2], [3], [-4]], Result).
Result = -36.
于 2008-12-09T17:25:28.020 に答える
1

「内側のリストと外側のリストの合計を乗算する」という部分はあまり明確ではありませんが、[L1,...,Ln]数値のリストのリストが与えられたS1*..*Sn場合Si、Li(ごとにi)。

plus私は と の存在をmultそれらの明白な意味で仮定します (例えば、 が に等しいplus(N,M,R)場合に正確に成立します)。最初に、が の要素の合計である場合にのみ成立するような述語が必要です。が空の場合、明らかに:RN+Msumsum(L,S)SLLS0

sum([],0).

Lが空ではなく の形式である場合、 に の要素の合計を加えたもの[N|L2]でSなければなりません。言い換えると、(S2 を の要素の合計にするために) との両方が必要です。あれは：NS2L2sum(L2,S2)L2plus(N,S2,S)

sum([N|L2],S) :- sum(L2,S2), plus(N,S2,S).

p同じようにして、探している述語を見つけることができます。それが成立するのは、 through where and for allの積であるp(L,R)場合に限られます。が空の場合、次のようにする必要があります:RS1SnL=[L1,...,Ln]sum(Li,Si)iLR1

p([],1).

Lが空ではなく の形式[LL|L2]である場合、 は の要素の和である 'S'と のリストの和の積である 'P' のR積でなければなりません。はすでにあるので、これにより次のことが得られます。LLL2Ssum(LL,S)

p([LL|L2],R) :- sum(LL,S), p(L2,P), mult(S,P,R).

追加したいことの 1 つは、これらの述語を、命令型プログラミングや関数型プログラミングで慣れ親しんだ関数と見なすのは、おそらくあまり良い考えではないということです。sumlist([1,..,n],X)を返すのはそうではありませんX = (result)。真であるような(result)値です。これには、少し異なる考え方が必要です。「p(X) が成立するような X を計算するにはどうすればよいか」と考える代わりに、「P(X) はいつ成立するのか?」と考える必要があります。そして答えを使って (「q(X) か r(X) なら!」) 節 (と) を作ります。Xsumlist([1,...,n],X)p(X) :- q(X)p(X) :- r(X)

于 2008-12-09T01:16:28.333 に答える
0

これはKaarelの答えを書き直したものです（とにかくそれが意図です！）が、末尾再帰です。

prodsumlist(List, Result) :-
    xprodsumlist(List,1,Result).

xprodsumlist([],R,R).

xprodsumlist([Head|Rest],Sofar,Result) :-
    sumlist(Head, Sum_Of_Head),
    NewSofar is Sofar * Sum_Of_Head,
    xprodsumlist(Rest, NewSofar, Result).
于 2009-10-28T06:34:34.290 に答える