emacs - 現在の行を除くemacs削除末尾の空白

Question

最近、いくつかのプログラミング モード用に Emacs(delete-trailing-whitespace)機能を追加しまし'before-save-hookたが、現在編集中の行から空白が削除されるのはかなりイライラします。この問題を解決する方法について何か提案はありますか?

Answer 1

delete-trailing-whitespaceナローイングに関しては、バッファを現在の行の前の部分にナローして呼び出してから、現在の行の後の部分にナローして再度呼び出すという解決策があります。

(defun delete-trailing-whitespace-except-current-line ()
  (interactive)
  (let ((begin (line-beginning-position))
        (end (line-end-position)))
    (save-excursion
      (when (< (point-min) begin)
        (save-restriction
          (narrow-to-region (point-min) (1- begin))
          (delete-trailing-whitespace)))
      (when (> (point-max) end)
        (save-restriction
          (narrow-to-region (1+ end) (point-max))
          (delete-trailing-whitespace))))))

before-save-hookの代わりにこの機能をあなたに置きますdelete-trailing-whitespace。

Answer 2

このラッパーは、次のdelete-trailing-whitespaceことを行うために使用できます。

(defun delete-trailing-whitespace-except-current-line ()
  "do delete-trailing-whitespace, except preserve whitespace of current line"
  (interactive)
  (let ((current-line (buffer-substring (line-beginning-position) (line-end-position)))
        (backward (- (line-end-position) (point))))
    (delete-trailing-whitespace)
    (when (not (string-equal (buffer-substring (line-beginning-position) (line-end-position))
                             current-line))
      (delete-region (line-beginning-position) (line-end-position))
      (insert current-line)
      (backward-char backward))))

Answer 3

「delete-trailing-whitespace」を 2 回呼び出すためのラッパーを用意しました。

(defun modi/delete-trailing-whitespace-buffer ()
  "Delete trailing whitespace in the whole buffer, except on the current line.
The current line exception is because we do want to remove any whitespace
on the current line on saving the file (`before-save-hook') while we are
in-between typing something.

Do not do anything if `do-not-delete-trailing-whitespace' is non-nil."
  (interactive)
  (when (not (bound-and-true-p do-not-delete-trailing-whitespace))
    (delete-trailing-whitespace (point-min) (line-beginning-position))
    (delete-trailing-whitespace (line-end-position) (point-max))))
(add-hook 'before-save-hook #'modi/delete-trailing-whitespace-buffer)