0

ですから、私の問題はそれより少し大きいかもしれませんが、確かではありません。ローダーオブジェクトを使用して画像を動的にロードするクライアント用のカスタムフラッシュフォトビューアーを作成しています。サーバー上の指定されたディレクトリにあるフォルダ名を取得し、（URLRequestを使用して）phpページを呼び出して、フォルダの実行可能なコンテンツを取得します。そして、その配列からロードします。

問題は次のとおりです。これは、私のマシンとテストしたすべてのマシンでFINEで動作しますが、クライアントのマシンまたは一部の顧客のマシンでは動作しません。画面の下部にあるローダーバーがいっぱいになり始めない、つまり画像が読み込まれ始めていないことを意味し、ステータスバーは、サーバーを待機し続けているが、待機を終了しないことを示します。これは単一のマシンで一貫していますが、マシンによって異なります。

エラーをキャッチするために診断（特定の変数を追跡してエラーを収集するために作成したカスタムクラス）を追加しましたが、クライアントのマシンには何も報告されません。フラッシュバージョンチェックコードを追加したので、下位バージョンがそれを台無しにする可能性はなくなりました...

私の質問は、リクエストオブジェクトや何かが特定のマシンで動作することを許可しない、見落としていた可能性のあるもの（セキュリティ、環境など）はありますか？私はこれを理解しようとして髪を引き裂いてきました！

私のコード（関連セクション）：

    public static const LOADLIMIT:int = 4;

    public var paramObj:Object;
    private var imageRequests:Vector.<URLRequest>;
    private var loaderObj:Vector.<Loader>;
    private var nextToLoad:int = -1;

    //...

    public function Player(){
        //...
        paramObj = loaderInfo.parameters;
            if (!paramObj.root) paramObj.root = "http://site.com/images/";
            paramObj.imgloc = paramObj.imgloc;
            var res = bootstrapImages(paramObj.imgloc);
            if (res is String){
                loadErrorMsg.text = res;
                loadErrorMsg.visible = true;
                log.log(res);
            }
        //...
    }

    private function bootstrapImages(imgloc:String):*{
        try{
        if (!imgloc) return "No image location specified"; 

        var req:URLRequest = new URLRequest(paramObj.root+"getdirlist.php?name="+imgloc);
        var loader:URLLoader = new URLLoader();
        loader.addEventListener(Event.COMPLETE, directoryLoaded);
        loader.addEventListener(IOErrorEvent.IO_ERROR, function(ex:IOError){
            loadErrorMsg.text = "Error retreiving album data.";
            loadErrorMsg.visible = true;
            log.log(ex);
        });
        loader.load(req);
        } catch (ex:Error){
            log.log(ex); throw ex;
        }
    }

    private function directoryLoaded(e:Event){
        try{
        //directory will come down as a json array
        trace(e.target.data);
        try {
            var items:Array = JSON.decode(e.target.data);
        } catch (ex:Error){
            trace (ex.getStackTrace());
            loadErrorMsg.text = "Error parsing album data.";
            loadErrorMsg.visible = true;
            log.log(ex);
            return;
        } 

        if (items.length == 0){
            loadErrorMsg.text = "Invalid album name";
            loadErrorMsg.visible = true;
            log.log("Items length is 0.");
            return;
        }

        imageRequests = new Vector.<URLRequest>();
        loaderObj = new Vector.<Loader>();
        for each(var item:String in items){
            imageRequests.push(new URLRequest(paramObj.root+"coffeeimages/"+paramObj.imgloc+"/"+item));
            loaderObj.push(null);
        }

        //...show UI...

        for (var i:int = 0; i < LOADLIMIT; i++){
            imageLoaded(null);
        }
        } catch (ex:Error){
            log.log(ex); throw ex;
        }
    }

    private function imageLoaded(e:Event){
        try{
        //if this was called as a result of the load event, start the slideshow! :D
        if (e != null && e.target != null) {
            //stage.addChild((e.target as LoaderInfo).loader);
            trace(loaderObj[0]);
            if (loaderObj[0] != null && //if the first image is loaded
                loaderObj[0].contentLoaderInfo.bytesLoaded >= loaderObj[0].contentLoaderInfo.bytesTotal){ 
                trace(loaderObj[0].contentLoaderInfo.bytesLoaded, loaderObj[0].contentLoaderInfo.bytesTotal);
                loadErrorMsg.visible = false;
                playSlideshow(true);
            }
        }
        trace((e)?e.target:null, loaderObj);
        nextToLoad++;
        if (nextToLoad >= imageRequests.length) return;

        var r:URLRequest = imageRequests[nextToLoad];
        var l:Loader = new Loader();
        l.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
        l.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, function(ex:ErrorEvent){
            loadErrorMsg.text = "Error parsing image data.";
            loadErrorMsg.visible = true;
            log.log(ex);
        });
        l.load(r);
        loaderObj[nextToLoad] = l;
        log.addObjectWatch(l);
        } catch (ex:Error){
            log.log(ex); throw ex;
        }
    }

また、こちらがサイトに住んでいるプレイヤーです。Ctrl + Alt + Homeを押すと、診断パネルが表示されます。それでもうまくいかない場合は教えてください。これについてもっと心配することができます...：/ありがとう。

編集：デバッグ情報を追加しました。それをロードできないコンピューターでは、アルバム情報をブートストラップしようとすると、HTTPステータス0が返されることがわかりました。それが何を意味するのかわかりません...

4

3 に答える 3

1

だから、問題はそれが要求するURLの問題でした...

私のコードが「site.com」を要求しているときに、クライアントは「www.site.com」と入力していました。アドビにとって、これはクロスサイトリクエストであり、デフォルトでは許可されていません。1つの解決策（そしておそらく最も簡単な解決策）は、「crossdomain.xml」というファイルをWebサイトのルートフォルダーに追加することです。Flashは、リクエストを行うときにこのファイルを探します。私のために働いた1つの例は次のとおりです：

//crossdomain.xml
<?xml version="1.0"?>
<!DOCTYPE cross-domain-policy SYSTEM "http://www.adobe.com/xml/dtds/cross-domain-policy.dtd">

<cross-domain-policy>
    <allow-access-from domain="*.site.com" secure="false"/>
</cross-domain-policy>

他の解決策には、2つのうちの1つにリダイレクトする（「site.com」は「www.site.com」にリダイレクトする）、URLの書き換えを行う、または入力したURLを取得することが含まれます。

于 2010-09-06T23:26:43.263 に答える
0

上記のcrossdomain.xmlソリューションが好きですが、クライアントPCでも同様の問題が発生しました。問題は、adblockerブラウザプラグインがactionscriptのURLRequestをブロックしていたことでした。現在、これに対する解決策を見つけています。

于 2012-09-10T08:03:16.247 に答える
0

私が気付いたいくつかのことは、あなたはEvent.COMPLETEとIOErrorEvent.IO_ERRORだけをリッスンしているということです。HTTPStatusEvent.HTTP_STATUS、Event.OPENもリッスンすることをお勧めします。これらは追加していませんが、まだどこにも到達していない場合は、役立つ情報が提供される可能性があります。

画像をロードするだけでコンテンツにアクセスしない場合は、LoaderContextオブジェクトは必要ありません。そのため、（セキュリティ）は実際には問題になりません。imageLoadedでロジックを確実に分離して、ローダーのイニシエーターと完了ハンドラーの両方にならないようにする必要があります。

とにかく、これがあなたに役立つかどうかの手がかりはありませんが、私はあなたのコードを実質的に読みやすくし、ほとんど意味のないいくつかのことを作り直しました。

public static const LOADLIMIT:int = 4;

private var paramObj:Object;
private var imageRequests:Vector.<URLRequest>;
private var loaderObj:Vector.<Loader>;
private var nextToLoad:int = -1;

public function Player(){
    paramObj = loaderInfo.parameters;

    //what is this all about, your backup URL is useless?
    if (!paramObj.root) {
        paramObj.root = "http://site.com/images/";
    }

    var res = bootstrapImages();
    if (res.length > 0){
        loadErrorMsg.text = res;
        loadErrorMsg.visible = true;
        //log.log kills me
        log.log(res);
    }
}

private function bootstrapImages():String {
    try {
        var req:URLRequest = new URLRequest(paramObj.root + "getdirlist.php?name=" + paramObj.imgloc);
        var loader:URLLoader = new URLLoader();
        loader.addEventListener(Event.COMPLETE, directoryLoaded);
        loader.addEventListener(IOErrorEvent.IO_ERROR, dataIOError);
        loader.load(req);
    } catch (ex:Error) {
        log.log(ex);
    }
    return "";
}

private function directoryLoaded(e:Event):void{
    trace(e.target.data);
    try {
        var items:Array = JSON.decode(e.target.data);
    } catch (ex:Error){
        trace (ex.getStackTrace());
        loadErrorMsg.text = "Error parsing album data.";
        loadErrorMsg.visible = true;
        log.log(ex);
        return;
    } 

    if (items.length == 0){
        loadErrorMsg.text = "Invalid album name";
        loadErrorMsg.visible = true;
        log.log("Items length is 0.");
        return;
    }

    imageRequests = new Vector.<URLRequest>();
    loaderObj = new Vector.<Loader>();
    for each(var item:String in items){
        imageRequests.push(new URLRequest(paramObj.root+"coffeeimages/"+paramObj.imgloc+"/"+item));
        loaderObj.push(new Loader());
    }

    for (var i:int = 0; i < LOADLIMIT; i++){
        loadNextImage();
    }
}

private function loadNextImage():void {
    nextToLoad++;
    if (nextToLoad < imageRequests.length) {
        loaderObj[nextToLoad].contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
        loaderObj[nextToLoad].contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, dataIOError);
        try {
            loaderObj[nextToLoad].load(imageRequests[nextToLoad]);
        }
        catch (e:Error) {
            log.log(ex);
        }
        log.addObjectWatch(loaderObj[nextToLoad]);
    }
}

private function dataIOError(e:IOError):void {
    loadErrorMsg.text = "IOError: " + e.errorID + " - " + e.name + ", " + e.message;
    loadErrorMsg.visible = true;
    log.log(ex);
}

private function imageLoaded(e:Event){
    //Start the slideshow if the first image has loaded
    loadNextImage();
    if (e.target == loaderObj[0]) {
        trace(loaderObj[0].contentLoaderInfo.bytesLoaded, loaderObj[0].contentLoaderInfo.bytesTotal);
        loadErrorMsg.visible = false;
        playSlideshow(true);
    }
}

編集：ロードコードを完全に廃棄し、代わりにバルクローダーを使用することもできます

于 2010-08-24T05:29:42.087 に答える