4

ユーザーがグラフをクリックした場合、指定された点と交差する放物線の方程式があります。

 // this would typically be mouse coords on the graph
 var _target:Point = new Point(100, 50);

 public static function plot(x:Number, target:Point):Number{
  return (x * x) / target.x * (target.y / target.x);
 }

これにより、次のようなグラフが得られます。

放物線

また、開始座標と終了座標で定義された一連の線分があります。

startX:Number, startY:Number, endX:Number, endY:Number

この曲線がこれらのセグメントと交差するかどうか、どこで交差するかを見つける必要があります（A）：

代替テキスト

それが助けになるなら、startXいつもです< endX

これを行うにはかなり簡単な方法があるように感じますが、何を検索すればよいかわからないし、「適切な」数学にも精通していないので、実際のコード例をいただければ幸いです。

アップデート：

交差点は機能していますが、私のソリューションでは、y軸の反対側の座標が得られます。

ターゲット座標をそれぞれAとBに置き換えると、プロットの次の方程式が得られます。

(x * x) / A * (B/A)

// this simplifies down to:
(B * x * x) / (A * A)

// which i am the equating to the line's equation
(B * x * x) / (A * A) =  m * x + b

// i run this through wolfram alpha (because i have no idea what i'm doing) and get:
(A * A * m - A * Math.sqrt(A * A * m * m + 4 * b * B)) / (2 * B)

これは正解ですが、2番目の可能なバリエーションが必要です。計算の前にmに-1を掛けて、最後の計算で返されたx値で同じことを行うことで、これを修正することができましたが、それはハックのように感じます。

解決：

 public static function intersectsSegment(targetX:Number, targetY:Number, startX:Number, startY:Number, endX:Number, endY:Number):Point {
  // slope of the line
  var m:Number = (endY - startY) / (endX - startX);

  // where the line intersects the y-axis
  var b:Number = startY - startX * m;

  // solve the two variatons of the equation, we may need both
  var ix1:Number = solve(targetX, targetY, m, b);
  var ix2:Number = solveInverse(targetX, targetY, m, b);

  var intersection1:Point;
  var intersection2:Point;

  // if the intersection is outside the line segment startX/endX it's discarded
  if (ix1 > startX && ix1 < endX) intersection1 = new Point(ix1, plot(ix1, targetX, targetY));
  if (ix2 > startX && ix2 < endX) intersection2 = new Point(ix2, plot(ix2, targetX, targetY));

  // somewhat fiddly code to return the smallest set intersection
  if (intersection1 && intersection2) {
   // return the intersection with the smaller x value
   return intersection1.x < intersection2.x ? intersection1 : intersection2;
  } else if (intersection1) {
   return intersection1;
  }

  // this effectively means that we return intersection2 or if that's unset, null
  return intersection2;
 }

 private static function solve(A:Number, B:Number, m:Number, b:Number):Number {
  return (m + Math.sqrt(4 * (B / (A * A)) * b + m * m)) / (2 * (B / (A * A)));
 }

 private static function solveInverse(A:Number, B:Number, m:Number, b:Number):Number {
  return (m - Math.sqrt(4 * (B / (A * A)) * b + m * m)) / (2 * (B / (A * A)));
 }

 public static function plot(x:Number, targetX:Number, targetY:Number):Number{
  return (targetY * x * x) / (targetX * targetX);
 }
4

4 に答える 4

6

または、まだもっと明確です。

放物線が y(x)= A x2+ B x + C (Eq 1)

そしてあなたのラインは y(x) = m x + b (Eq 2)

xの2つの可能な解決策（+と-）は次のとおりです。

x = ((-B + m +- Sqrt[4 A b + B^2 - 4 A C - 2 B m + m^2])/(2 A))   (Eq 3)

セグメントの端点（x）にこれらの2つのポイントのいずれかが含まれているかどうかを確認する必要があります。含まれている場合は、y = mx + b方程式の対応するxを置き換えて、交差点のy座標を取得します。

編集>

最後の方程式を取得するには、式1の「y」が式2の「y」と等しいと言うだけです（交差点を探しているためです）。それはあなたに与えます：

A x2+ B x + C = m x + b

と再グループ化

A x2+ (B-m) x + (C-b) = 0

これは二次方程式です。

式3は、この2次方程式の2つの可能な解です。

編集2>

コードを読み直すと、放物線は次のように定義されているようです。 y(x) = A x2

どこ
A = (target.y / (target.x)2)

したがって、あなたの場合、式3は単純になります。

 x = ((m +- Sqrt[4 A b + m^2])/(2 A))   (Eq 3b)

HTH！

于 2010-08-31T12:52:56.233 に答える
3

実際に交点を計算する前に、交点が存在するかどうかを確認するための別のテストを希望するほど頻繁にこれを行っていますか？もしそうなら、あなたの放物線が関数f（x、y）= y-（B * x * x）/（A * A）-、具体的にはf（x、 y）=0。2つの端点をf（x、y）に接続します。同じ符号の場合は放物線の同じ側にあり、異なる符号の場合はの異なる側にあります。放物線。

これで、放物線と2回交差するセグメントがまだある可能性がありますが、このテストではそれを検出できません。しかし、あなたが問題を定義している方法についての何かが、多分それがあなたのアプリケーションにとって大丈夫だと私に感じさせます。

于 2010-08-31T18:53:58.843 に答える
3

曲線の方程式を取り、直線をy = mx+bの形式にします。xを解いてから、Xが線分の始点と終点の間にあるかどうかを判断します。

チェックアウト： http： //mathcentral.uregina.ca/QQ/database/QQ.09.03/senthil1.html

于 2010-08-31T12:35:53.000 に答える
0

つまり、各線分の方程式を計算しy = Ax + Bて曲線方程式と比較し、との値の間に解があるかどうかを確認する必要がy = Cx^2 + Dx + Eあります。Ax + B - Cx^2 - Dx - E = 0startXendX

于 2010-08-31T12:33:14.587 に答える