0

リストボックス (uf1_listbox3) を持つ Excel VBA プロジェクトにユーザーフォーム (uf1_assess_sched) があります。

ユーザーがこのリストボックスで 1 つの項目を選択すると、2 番目のユーザーフォーム (group_1) が開き、ユーザーは最初のユーザーフォームで行った選択に固有の情報を入力できます。ユーザーが group_1 へのそれ以上のエントリを放棄したい場合は、[Exit] というコマンド ボタンをクリックして終了できます。

終了すると、group_1 がアンロードされ、uf1_assess_sched が先頭に立ちます。アイデアは、ユーザーが uf1)listbox3 から別の項目を選択できるようにすることです。ただし、最初に行った選択はまだ選択されています。

以前に選択したこの選択を解除するにはどうすればよいですか。

私が試してみました：

With uf1_assess_sched
    .uf1_listbox3.listindex = -1
End With

これは、私の検索で見つけた最も関連性の高いものです。

Patrick の提案に従い、Excel VBA の理解が限られているため、彼の指示を次のように解釈しました。

With uf1_assess_sched
    For i = 0 To .uf1_listbox3.ListCount - 1
        If .uf1_listbox3.Selected(i) = True Then
            .uf1_listbox3.Selected(i) = False
        End If
    Next i
End With

これは残念ながらうまくいきませんでした。コードは正しい選択を見つけましたが、エントリはリストボックスで選択されたままになり、uf1_listbox3_Click イベントもトリガーされました。

元の投稿を編集するだけで、適切な方法でフィードバックを提供できれば幸いです。コメントにコードを追加する方法がわかりません。StackOverflow は私にとって新しい形式なので、最善を尽くしています。

パトリックから親切に提供された最新のコードを使用して、エラーが発生する前にここまでたどり着くことができました。ユーザーフォームとリストボックスの名前を反映するために、いくつかの調整を行いました。2 番目のユーザーフォーム group_1 のコードで「メソッドまたはデータ メンバーが見つかりません」というエラーが表示されます。

Private Sub exit1_Click()

Dim ui2 As VbMsgBoxResult
Dim lastrow As Long
Dim i As Long

If ws_vh.Range("E2") > 0 Then 'unsaved info
    Me.Label34.Caption = "    Saving unsaved rental data."
    Me.Label34.BorderColor = RGB(50, 205, 50)
    lastrow = ws_rd.Cells(ws_rd.Rows.Count, "A").End(xlUp).Row
    ws_rd.Range("A3:FZ" & lastrow).Sort key1:=ws_rd.Range("A3"), order1:=xlAscending, Header:=xlNo
    Application.DisplayAlerts = False
    ThisWorkbook.Save
    Application.DisplayAlerts = True

    Debug.Print Me.Name, "exit1_Click() called"
    uf1_assess_sched.ListBox3_DeSelect    '<--- Error with ".Listbox3_DeSelect"
    Unload Me

    'Unload group_1
    'End
    Exit Sub
End If

If ws_vh.Range("B2") > 0 Then   'Outstanding rentals?
    ui2 = MsgBox("You still have " & ws_vh.Range("C2") & " rentals with critical missing rental information." & Chr(13) & Chr(13) _
        & "Active (Sports) rentals: " & ws_vh.Range("B3") & Chr(13) & "Passive (Picnics) rentals: " & ws_vh.Range("B4") & Chr(13) & Chr(13) _
        & "Are you sure you wish to exit?", vbInformation + vbYesNo, "OUTSTANDING RENTAL INFORMATION")
    If ui2 = vbYes Then
        If ws_vh.Range("N4") > 0 Then
            Me.Label34.Caption = "    Saving unsaved rental data."
            Me.Label34.BorderColor = RGB(50, 205, 50)
            lastrow = ws_rd.Cells(ws_rd.Rows.Count, "A").End(xlUp).Row
            ws_rd.Range("A3:FZ" & lastrow).Sort key1:=ws_rd.Range("A3"), order1:=xlAscending, Header:=xlNo
            Application.DisplayAlerts = False
            ThisWorkbook.Save
            Application.DisplayAlerts = True
            Workbooks("Sports15c.xlsm").Activate
            mbEvents = False

            Debug.Print Me.Name, "exit1_Click() called"
            uf1_assess_sched.ListBox3_DeSelect    '<--- Error with ".Listbox3_DeSelect"
            Unload Me
            Exit Sub
        Else
            Unload Me
            End
        End If
    Else
        Exit Sub
    End If
 End If

Unload group_1
End
End Sub

Subs ListBox1_DeSelect() と ListBoxDeSelect(oListBox As Object) を別のモジュールに入れました (おそらくそれが問題です)。

これがそのコードです...

Sub ListBox3_DeSelect()
ListBoxDeSelect Me.uf1_listbox3
End Sub

Private Sub ListBoxDeSelect(oListBox As Object)
Dim i As Long
If TypeName(oListBox) <> "ListBox" Then Exit Sub
bSkipEvent = True
With oListBox
    For i = 0 To .ListCount - 1
        If .Selected(i) Then
            .Selected(i) = False
        End If
    Next
End With
bSkipEvent = False
End Sub

これが私の最新のコードです（7月19日）...

USERFORM 1 - uf1_assess_sched (ユーザーが選択するリストボックスを保持)

Private Sub uf1_listbox3_Click()
    If mbEvents Then Exit Sub
    Debug.Print Me.Name, "uf1_listBox3_Click() called"
    If bSkipEvent Then Exit Sub
    With uf1_listbox3
        Debug.Print Me.Name, "uf1_listBox3_Click() ListIndex: " & .ListIndex & " (" & .List(.ListIndex) & ")"
        group_1.Show
        'UserForm2.TextBox1.Value = .List(.ListIndex) ' This won't have effect if UserForm2 is True on ShowModal
    End With
End Sub

USERFORM 2 - group_1 (ユーザーは、userform1 で選択した値に基づいて追加のデータを入力できます。ユーザーは、EXIT ボタン (exit1) を押して放棄することを選択します)

Private Sub exit1_Click()

    Dim ui2 As VbMsgBoxResult
    Dim lastrow As Long
    Dim i As Long

    If ws_vh.Range("E2") > 0 Then 'unsaved info
        Me.Label34.Caption = "    Saving unsaved rental data."
        Me.Label34.BorderColor = RGB(50, 205, 50)
        lastrow = ws_rd.Cells(ws_rd.Rows.Count, "A").End(xlUp).Row
        ws_rd.Range("A3:FZ" & lastrow).Sort key1:=ws_rd.Range("A3"), order1:=xlAscending, Header:=xlNo
        Application.DisplayAlerts = False
        ThisWorkbook.Save
        Application.DisplayAlerts = True
        Unload group_1
        'End
        Exit Sub
    End If

    If ws_vh.Range("B2") > 0 Then   'Outstanding rentals?
        ui2 = MsgBox("You still have " & ws_vh.Range("C2") & " rentals with critical missing rental information." & Chr(13) & Chr(13) _
            & "Active (Sports) rentals: " & ws_vh.Range("B3") & Chr(13) & "Passive (Picnics) rentals: " & ws_vh.Range("B4") & Chr(13) & Chr(13) _
            & "Are you sure you wish to exit?", vbInformation + vbYesNo, "OUTSTANDING RENTAL INFORMATION")
        If ui2 = vbYes Then
            If ws_vh.Range("N4") > 0 Then
                Me.Label34.Caption = "    Saving unsaved rental data."
                Me.Label34.BorderColor = RGB(50, 205, 50)
                lastrow = ws_rd.Cells(ws_rd.Rows.Count, "A").End(xlUp).Row
                ws_rd.Range("A3:FZ" & lastrow).Sort key1:=ws_rd.Range("A3"), order1:=xlAscending, Header:=xlNo
                Application.DisplayAlerts = False
                ThisWorkbook.Save
                Application.DisplayAlerts = True
                Workbooks("Sports15c.xlsm").Activate

                Debug.Print Me.Name, "EXIT1_Click() called"
                    'UserForm1.ListBox1_DeSelect ' No longer used.
                Set oListBoxToDeselect = uf1_assess_sched.uf1_listbox3 ' [M2] This is required for the DelayedListBoxDeSelect(), if top right [X] is clicked, it won't do DeSelect
                Unload Me
            Else
                Unload Me
                End
            End If
        Else
            Exit Sub
        End If
     End If
            'If ws_vh.Range("N4") > 0 Then
            '    MsgBox "Unsaved rental data. Saving."
            '    lastrow = ws_rd.Cells(ws_rd.Rows.Count, "A").End(xlUp).row
            '    ws_rd.Range("A3:FZ" & lastrow).Sort key1:=ws_rd.Range("A3"), order1:=xlAscending, Header:=xlNo
            '    Application.DisplayAlerts = False
            '    ThisWorkbook.Save
            '    Application.DisplayAlerts = True
            '    Unload Me
            'Else
            '    Worksheets("DYNAMIC").Activate
            '    Unload Me
            'End If
        'End If
    Unload group_1
    'Worksheets("DYNAMIC").Activate
    End

End Sub

テストの目的で、ws_vh.Range("B2") > 0 と仮定します。

そして、独立したヘルパーモジュール...

Option Explicit

' Generic ListBox Deselector
Sub ListBoxDeSelect(oListBox As Object)
    Dim i As Long
    If TypeName(oListBox) <> "ListBox" Then Exit Sub
    bSkipEvent = True
    With oListBox
        For i = 0 To .ListCount - 1
            If .Selected(i) Then
                .Selected(i) = False
            End If
        Next
    End With
    bSkipEvent = False
End Sub

' METHOD 2 [M2] - When UserForm's ShowModal = True
Sub DelayedListBoxDeSelect()
    Dim i As Long
    If TypeName(oListBoxToDeselect) <> "ListBox" Then Exit Sub
    bSkipEvent = True
    With oListBoxToDeselect
        For i = 0 To .ListCount - 1
            If .Selected(i) Then
                .Selected(i) = False
            End If
        Next
    End With
    bSkipEvent = False
    Set oListBoxToDeselect = Nothing
End Sub

group_1 ユーザーフォーム終了コード

Private Sub UserForm_Terminate()
    Debug.Print Me.Name, "UserForm_Terminate() called"
    Set oListBoxToDeselect = uf1_assess_sched.uf1_listbox3 ' [M2] This is required for the DelayedListBoxDeSelect(), if top right [X] is clicked, it won't do DeSelect
    Application.OnTime Now + TimeSerial(0, 0, 1), "DelayedListBoxDeSelect" ' [M2] Sechedules the Sub named "DelayedListBoxDeSelect" to execute in 1 second.
End Sub

パート 2 - 選択を解除する必要がある別のシナリオ。

If i = 0 Then
        MsgBox "Nothing to eliminate."
    '--- > Deselect the user selection in uf_assess_sched.uf1_listbox2 < ---
        Exit Sub
End If
4

1 に答える 1

0

意図しないユーザー フォーム コントロール イベントに対処する方法が少なくとも 1 つあります。

UserForms がどのように相互作用するかはわかりませんが、必要に応じてグローバルブール変数を追加して、必要に応じてイベントをスキップできるようにするのが最も簡単だと思います。以下に示します。

編集されたヒント:グローバルブール変数bSkipEventをSub ListBoxDeSelect()取り出し、コード削減として通常のモジュールに取り出し、呼び出しをUserForm1.ListBox1. (その UserForm の ListBox が表示され、有効になっていることを確認してください。そうでない場合は、エラー トラップ コードを追加してください)。

UserForms ShowModal = True(TSM) の場合、別のアプローチが必要です。唯一の方法は、別の TSM を変更するために Sub が呼び出されるようにスケジュールすることです。ここでは、UserForm2 が完全に閉じられる直前にDelayedListBoxDeSelectApplication.OnTimeを 1 秒でスケジュールしていました。UserFormHelperの追加の Public オブジェクトに注意してください。私がここで何をしているのか理解していただければ幸いです。

次の 2 つの単純なユーザー フォームを考えてみましょう。
UserForm1_Design   UserForm2_Design

  1. UserForm1 をロードし、ListBox オプションの 1 つをクリックした後:
    UserForm1_ListBox_Click
  2. UserForm2 のコマンド ボタンをクリックすると、フォーカスが UserForm1 に戻ります
    。
    UserForm2_Cmd_Clicked

コード:
UserForm1

Private Sub UserForm_Initialize()
    bSkipEvent = False
End Sub

Private Sub ListBox1_Click()
    Debug.Print Me.Name, "ListBox1_Click() called"
    If bSkipEvent Then Exit Sub
    With ListBox1
        Debug.Print Me.Name, "ListBox1_Click() ListIndex: " & .ListIndex & " (" & .List(.ListIndex) & ")"
        UserForm2.Show
        UserForm2.TextBox1.Value = .List(.ListIndex) ' This won't have effect if UserForm2 is True on ShowModal
    End With
End Sub

'Sub ListBox1_DeSelect() ' No longer used
'    ListBoxDeSelect Me.ListBox1
'End Sub

UserFormsHelper(ノーマルモジュール)

Public bSkipEvent As Boolean ' This makes accessible to Userforms and other Modules
Public oListBoxToDeselect As Object '[M2] This is for delayed ListBox Deselect method

' Generic ListBox Deselector
Sub ListBoxDeSelect(oListBox As Object)
    Dim i As Long
    If TypeName(oListBox) <> "ListBox" Then Exit Sub
    bSkipEvent = True
    With oListBox
        For i = 0 To .ListCount - 1
            If .Selected(i) Then
                .Selected(i) = False
            End If
        Next
    End With
    bSkipEvent = False
End Sub

' METHOD 2 [M2] - When UserForm's ShowModal = True
Sub DelayedListBoxDeSelect()
    Dim i As Long
    If TypeName(oListBoxToDeselect) <> "ListBox" Then Exit Sub
    bSkipEvent = True
    With oListBoxToDeselect
        For i = 0 To .ListCount - 1
            If .Selected(i) Then
                .Selected(i) = False
            End If
        Next
    End With
    bSkipEvent = False
    Set oListBoxToDeselect = Nothing
End Sub

UserForm2

Private Sub CommandButton1_Click()
    Debug.Print Me.Name, "CommandButton1_Click() called"
    'UserForm1.ListBox1_DeSelect ' No longer used.
    Set oListBoxToDeselect = UserForm1.ListBox1 ' [M2] This is required for the DelayedListBoxDeSelect(), if top right [X] is clicked, it won't do DeSelect
    Unload Me
End Sub

Private Sub UserForm_Terminate()
    Debug.Print Me.Name, "UserForm_Terminate() called"
    Application.OnTime Now + TimeSerial(0, 0, 1), "DelayedListBoxDeSelect" ' [M2] Sechedules the Sub named "DelayedListBoxDeSelect" to execute in 1 second.
End Sub

Debug Output
デバッグ出力

于 2016-07-12T02:39:19.870 に答える