13

作業中の新しい qt 5.7 アプリケーションにいくつかのスタイルを適用しようとしていますが、以下はまったく機能しません。エラーが発生します: qrc:/SignInView.qml:67 Cannot assign to non-existent property "style" And I can't edit it in design mode for the same reason.

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.1
import QtQuick.Controls.Styles 1.4

Page {
    id: page1
    ColumnLayout {
        id: columnLayout1
        height: 100
        anchors.right: parent.right
        anchors.left: parent.left
        anchors.top: parent.top

        Label {
            text: qsTr("Label")
            font.pointSize: 16
            horizontalAlignment: Text.AlignHCenter
            Layout.fillWidth: true
        }

        Image {
            id: image1
            width: 200
            height: 200
            Layout.alignment: Qt.AlignHCenter | Qt.AlignTop
            fillMode: Image.PreserveAspectCrop
            anchors.horizontalCenter: parent
            source: "qrc:/qtquickplugin/images/template_image.png"

            Button {
                id: button1
                text: qsTr("Button")
                anchors.bottomMargin: 10
                anchors.rightMargin: 10
                anchors.bottom: parent.bottom
                anchors.right: parent.right
            }
        }

        Rectangle {
            id: field1
            width: 200
            height: 40
            color: "#ffffff"
            Layout.fillWidth: true



            Label {
                id: label1
                text: qsTr("Full Name")
                anchors.topMargin: 0
                anchors.left: parent.left
                anchors.leftMargin: 5
                anchors.top: parent.top
            }
            TextField {
                style: TextFieldStyle {
                    textColor: "black"
                    background: Rectangle {
                        radius: 2
                        implicitWidth: 100
                        implicitHeight: 24
                        border.color: "#333"
                        border.width: 1
                    }
                }
            }
        }
    }
}

私はこの例に従おうとしています:

http://doc.qt.io/qt-5/qml-qtquick-controls-styles-textfieldstyle.html

Qt Creator のスタイル属性で失敗し、スタイルが存在しないというエラーが発生します。ライブラリがロードされていないか、セットアップした環境に問題があると思います。ボタンやその他の場所にもスタイルがありません。インポートがあればうまくいくと思いましたが、そうではありません。

SO に関する関連する問題は次のとおりです。QML - TextField のフォント サイズを変更する方法 しかし、ここではうまくいくようです。

4

1 に答える 1

25

Qt Quick Controls 2 には、 のようなプロパティはありませんTextField::style。一般に、Qt クイック コントロール 1 のスタイル オブジェクトを Qt クイック コントロール 2 で使用する方法はありません。Qt クイック コントロールの 2 つのメジャー バージョン間の API には互換性がありません。詳細については、次のドキュメント ページを参照してください。

基本的に Qt Quick Controls 1 の重度のローダー ベースのアーキテクチャを適切に実行する方法がないため、新しい API 非互換のメジャー バージョンが導入されました。Componentそのため、Qt Quick Controls 2 では s の動的読み込みはすべて廃止Componentされました。動的に読み込まれたスタイル オブジェクトによって提供される s から動的にインスタンス化されていたデリゲートは、代わりにコントロールの一部になり、「その場で」インスタンス化されます。本質的に：

TextField {
    style: TextFieldStyle {
        textColor: "white"
        background: Rectangle { color: "black" }
    }
}

対。

TextField {
    color: "white"
    background: Rectangle { color: "black" }
}

歴史の詳細については、こちらをご覧ください。特に、この投稿では、Qt Quick Controls 2 の基本的な構造上の変更を強調しています。

于 2016-08-20T09:08:48.190 に答える