0

二次方程式を解くプログラムを書こうとしています。（B ** B-4 * A * C）の値が0または負の場合、すぐに「方程式の根は複雑です」と書く必要がありますが、正の場合、評価する必要があります。A、B、Cにどのような値を付けても、論理に誤りがあるようです。「方程式の根は複雑です」と表示され続けます。以下のコードと結果をご覧ください。ありがとう。

    PROGRAM QUADEQN
      INTEGER A,B,C
      REAL D,X,Y,Q
      D=(B**2-4*A*C)
      Q=SQRT(D)
      READ(*,5)A
      READ(*,6)B
      READ(*,7)C
      IF(B**2-4*A*C)10,15,20
      X=(-B+Q)/(2*A)
      Y=(-B-Q)/(2*A)
  20  WRITE(*,25)X,Y
  5   FORMAT(I2)
  6   FORMAT(I2)
  7   FORMAT(I2)
  10  WRITE(*,*)'THE ROOTS OF THE QUADRATIC EQUATION IS COMPLEX'
  15  WRITE(*,*)'THE ROOTS OF THE QUADRATIC EQUATION IS COMPLEX'
  25  FORMAT(/,'THE ROOTS OF THE EQN ARE',1X,F8.4,'AND',1X,F8.4)
      STOP
      END

結果

D：\ Postgraduate \ Programming \ FORTRAN> gfortran quad.f

D：\ Postgraduate \ Programming \ FORTRAN> a.exe 832二次方程式の根は複雑です二次方程式の根は複雑です

D：\ Postgraduate \ Programming \ FORTRAN>

4

4 に答える 4

3

もう少し現代的な方法で書かれています。文字列を好みに合わせて変更します。

  PROGRAM roots
  !Purpose:
  ! This program solves for the roots of a quadratic equation of the
  ! form a*x**2 + b*x + c = 0. It calculates the answers regardless
  ! of the type of roots that the equation possesses.
  IMPLICIT NONE
  REAL :: a, b, c, discriminant, imag_part, real_part, x1, x2

  WRITE(*,*) 'This program solvenes for the roots of a quadratic'
  WRITE(*,*) 'equation of the form A * X**2 + B * X + C = 0.'
  WRITE(*,*) 'Enter the coefficients A, B and C:'
  READ(*,*)a,b,c
  WRITE(*,*) 'The coefficients A, B and C are: ',a,b,c

  discriminant = b**2 - 4.*a*c

  IF (discriminant>0.) THEN
        !there are two real roots, so ...
        x1 = (-b + sqrt(discriminant)) / (2.*a)
        x2 = (-b - sqrt(discriminant)) / (2.*a)
        WRITE(*,*) 'This equation has two real roots:'
        WRITE(*,*) 'X1 = ',x1
        WRITE(*,*) 'X2 = ',x2
  ELSE IF (discriminant<0.) THEN 
        !there are complex roots, so ...
        real_part = (-b)/(2.*a)
        imag_part = sqrt(abs(discriminant))/(2.*a)
        WRITE(*,*) 'This equation has comples roots:'
        WRITE(*,*) 'X1 = ',real_part,' +i ',imag_part
        WRITE(*,*) 'X2 = ',real_part,' -i ',imag_part
  ELSE 
        !here is one repeated root, so ...
        x1 = (-b)/(2.*a)
        WRITE(*,*) 'This equation has two identical real roots:'
        WRITE(*,*) 'X1 = X2 =',x1
  END IF
  END PROGRAM roots
于 2010-11-29T18:03:03.843 に答える
3

うわー、計算された GOTO を 20 年以上見たことがありません。

彼らは、FORTRAN の書き方をまだ人々に教えているわけにはいきませんよね？

次のような、よりモダンなスタイルを使用します。

    PROGRAM QUADEQN
      INTEGER A,B,C
      REAL D,X,Y,Q
      READ(*,5)A
      READ(*,6)B
      READ(*,7)C
      D=(B**2-4*A*C)
      IF(D .LE. 0.0) THEN
  10  WRITE(*,*)'THE ROOTS OF THE QUADRATIC EQUATION IS COMPLEX'
      ELSE IF (D .EQ. 0.0) THEN
      WRITE(*,*)'WHAT SHOULD YOU SAY ABOUT THE ROOTS HERE?'
      ELSE
  25  FORMAT(/,'THE ROOTS OF THE EQN ARE',1X,F8.4,'AND',1X,F8.4)
      Q=SQRT(D)
      X=(-B+Q)/(2*A)
      Y=(-B-Q)/(2*A)
  20  WRITE(*,25)X,Y
      END IF
  5   FORMAT(I2)
  6   FORMAT(I2)
  7   FORMAT(I2)
      STOP
      END
于 2010-11-29T13:03:15.463 に答える
1

ダフィーモが言ったように、、 、がユーザーから読み取られるD前に評価しています。最後に、FORTRAN にはユーザーの心を読む超能力がないことを確認しました。実際、通常はユーザーの希望を完全に無視します。冗談だ。ABC

D=(B**2-4*A*C)ステートメントの後に to を移動し、FORTAN 90READに従ってスタイルを現代化します。

于 2010-11-29T14:14:49.853 に答える
0

プログラムのもう1つの問題は、20行目を実行すると、次の実行可能ステートメント（この場合は10行目、続いて15行目）を実行することです。そのため、「二次方程式の根は二次方程式のルーツは複雑です」。これは、STOPの直前にCONTINUEステートメントを使用し、GOTOを使用してそこに到達することで修正できますが、上記のアプローチの1つを使用する方がはるかに優れています。

于 2010-12-04T13:18:26.883 に答える