楽しい小さな問題:)
図を詳しく見ると、シーケンスが明確に示されています。
これらを描くにはおそらく多くの解決策があり、おそらくもっとエレガントですが、ここに私のものがあります：
斜辺は現在のセグメント数+1の平方根であり、三角形の反対側は常に1です。
また、角度のSine（Math.sin）は、反対側を斜辺で割った値に等しいこともわかります。古いmnenonicSOH（Sine、Opposite、Hypotenuse）から-CAH-TOA。
Math.sin(angle) = opp/hyp
角度の正弦の値はわかっています。2つの辺はわかっていますが、角度はまだわかりませんが、そのためにアーク正弦関数（Math.asin）を使用できます。
angle = Math.asin(opp/hyp)
これで、各セグメントの角度がわかり、線ごとに角度が大きくなることがわかります。
角度と半径（斜辺）ができたので、極からデカルトの式に使用して、その角度、半径のペアをx、yのペアに変換できます。
x = Math.cos(angle) * radius;
y = Math.sin(angle) * radius;
アクションスクリプトソリューションを求めたので、Pointクラスはすでにpolar（）メソッドを介してこの関数を提供しています。半径と角度を渡すと、Pointオブジェクトにxとyが返されます。
これがスパイラルをプロットする小さなスニペットです。Y軸上でマウスを動かすと、セグメントの数を制御できます。
var sw:Number = stage.stageWidth,sh:Number = stage.stageHeight;
this.addEventListener(Event.ENTER_FRAME,update);
function update(event:Event):void{
drawTheodorus(144*(mouseY/sh),sw*.5,sh*.5,20);
}
//draw points
function drawTheodorus(segments:int,x:Number,y:Number,scale:Number):void{
graphics.clear();
var points:Array = getTheodorus(segments,scale);
for(var i:int = 0 ; i < segments; i++){
points[i].offset(x,y);
graphics.lineStyle(1,0x990000,1.05-(.05+i/segments));
graphics.moveTo(x,y);//move to centre
graphics.lineTo(points[i].x,points[i].y);//draw hypotenuse
graphics.lineStyle(1+(i*(i/segments)*.05),0,(.05+i/segments));
if(i > 0) graphics.lineTo(points[i-1].x,points[i-1].y);//draw opposite
}
}
//calculate points
function getTheodorus(segments:int = 1,scale:Number = 10):Array{
var result = [];
var radius:Number = 0;
var angle:Number = 0;
for(var i:int = 0 ; i < segments ; i++){
radius = Math.sqrt(i+1);
angle += Math.asin(1/radius);//sin(angle) = opposite/hypothenuse => used asin to get angle
result[i] = Point.polar(radius*scale,angle);//same as new Point(Math.cos(angle)*radius.scale,Math.sin(angle)*radius.scale)
}
return result;
}
これはもっと少ない行で書くこともできましたが、私はこれを2つの関数に分割したいと思いました。1つは数値の計算のみを処理し、もう1つは線の描画を処理します。
ここにいくつかのスクリーンショットがあります：
楽しみのために、ここでProcessingJSを使用してこのバージョンを追加しました。動作が少し遅いので、これにはChromium/Chromeをお勧めします。
これで、実際にこのコードをここで実行できます（マウスを上下に動かします）。
var totalSegments = 850,hw = 320,hh = 240,segments;
var len = 10;
points = [];
function setup(){
createCanvas(640,480);
smooth();
colorMode(HSB,255,100,100);
stroke(0);
noFill();
//println("move cursor vertically");
}
function draw(){
background(0);
translate(hw,hh);
segments = floor(totalSegments*(mouseY/height));
points = getTheodorus(segments,len);
for(var i = 0 ; i < segments ; i++){
strokeWeight(1);
stroke(255-((i/segments) * 255),100,100,260-((i/segments) * 255));
line(0,0,points[i].x,points[i].y);
// strokeWeight(1+(i*(i/segments)*.01));
strokeWeight(2);
stroke(0,0,100,(20+i/segments));
if(i > 0) line(points[i].x,points[i].y,points[i-1].x,points[i-1].y);
}
}
function getTheodorus(segments,len){
var result = [];
var radius = 0;
var angle = 0;
for(var i = 0 ; i < segments ; i++){
radius = sqrt(i+1);
angle += asin(1/radius);
result[i] = new p5.Vector(cos(angle) * radius*len,sin(angle) * radius*len);
}
return result;
}
<script src="https://cdnjs.cloudflare.com/ajax/libs/p5.js/0.4.4/p5.min.js"></script>
