4

管理している oracle 10gR2 10.2.05 データベースから BLOB を抽出するときに、パフォーマンスの問題が発生しています。ファイル システムに書き出す必要がある BLOB として保存されている約 400 個のファイルがあります。以下は私のコードです。この手順を実行すると、最初の 8 個程度のファイルが数秒以内に書き込まれ、そこから速度が指数関数的に低下し、最初の 8 個のファイル以降は 40 秒ごとに 1 ファイル程度になります。最初の 8 ファイルは高速ですが、その後はすべてが遅くなります。これをストアド プロシージャとして実行し、UTL_FILE.fopen を "wb" (バイナリ書き込み) に変更し、データベースのパフォーマンスを妨げないように NFS マウント ファイル システムを使用してみました。これのどれも影響を与えていません。このレートでは、平均してそれぞれ約 1.5 MB の 400 個のファイルを抽出するのに 6 時間かかります。誰かが私のコードに問題があるか、これを行うためのより良い方法を知っていますか? ちなみに、ここにあるこのサンプルコードを使用しましたhttp://www.oracle-base.com/articles/9i/ExportBlob9i.phpを開始点として使用します。

助けてくれてありがとう！

DECLARE
  TYPE comment_text IS TABLE OF documents.comment_text%TYPE;
  TYPE localdata IS TABLE OF documents.localdata%TYPE;
  l_file UTL_FILE.FILE_TYPE;
  l_buffer RAW(32767);
  l_amount BINARY_INTEGER := 32767;
  l_pos INTEGER := 1;
  l_blob localdata;
  l_fname comment_text;
  l_blob_len INTEGER;
  l_x NUMBER := 1;
BEGIN
  SELECT comment_text, localdata
  BULK COLLECT INTO l_fname, l_blob
  FROM documents
  WHERE user_id='BILLYBOB';
  IF SQL%ROWCOUNT =0 THEN
    DBMS_OUTPUT.PUT_LINE('No records found!');
  ELSE
    FOR i IN l_fname.FIRST .. l_fname.LAST
    LOOP
      l_blob_len := DBMS_LOB.getlength(l_blob(i));
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS',l_x || '_' || l_fname(i),'w', 32767);
      l_pos := 1;
      l_x := l_x + 1;
      WHILE l_pos < l_blob_len
      LOOP
        DBMS_LOB.read(l_blob(i), l_amount, l_pos, l_buffer);
        UTL_FILE.put_raw(l_file, l_buffer, TRUE);
        l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
    END LOOP;
  END IF;
END;
4

1 に答える 1

1

手順の開始時にすべての BLOB を配列にフェッチするべきではないと確信しています。BLOB データを読み取り、実際にロブ ロケータを閉じることはないため、Oracle はこのすべての情報をメモリに保持する必要があります。これはメモリオーバーフィルの場合だと思います。

代わりにこれを試してください：

CURSOR cc IS (SELECT ...)
BEGIN
   OPEN cc;
   LOOP
      FETCH cc
         INTO l_fname, l_blob;
      EXIT WHEN cc%NOTFOUND;
      l_blob_len := DBMS_LOB.getlength(l_blob);
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS', l_x || '_' || l_fname, 'w', 32767);
      l_pos  := 1;
      l_x    := l_x + 1;
      WHILE l_pos < l_blob_len LOOP
         DBMS_LOB.READ(l_blob, l_amount, l_pos, l_buffer);
         UTL_FILE.put_raw(l_file, l_buffer, TRUE);
         l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
   END LOOP;
   CLOSE cc;
END;
于 2010-12-08T22:34:41.227 に答える