0

siteId とステータスで分割されたアイテムのテーブルがあります。

CREATE TABLE ItemDetail (
    ItemNumber    long,
    SiteId        int,
    Status        int,
    Created       datetime
)

そして、ユーザーのテーブルもあります

CREATE TABLE UserDetail (
    UserId        int,
    Suspended     int
)

ステータスには、異なるキューを表す 7 つの可能な値 (0 ～ 6) があります。この変数を x としましょう。サスペンド。0 (アクティブ) または 1 (サスペンド) のみが必要です。(なぜ int なのか聞かないでください。私は作成していません)。データは、構成可能な時間枠でサイトごとに表示されます。デフォルトは 5 日前です。この変数を a としましょう。1回の呼び出しで、次のようなデータセットを返したい:

ActiveUserCount        int
SuspendedUserCount     int,
Queue0Count            int,
Queue0TodayCount       int,
Queue1Count            int,
Queue1TodayCount       int,
...

QueueXCount は、ステータスとサイト ID ごとの過去 1 日間のすべてです。QueueXTodayCount は、今日発生したステータス x のすべてです。これまでのところ、このようなsprocを開始しました

CREATE PROCEDURE GetSiteStatistics
    @SiteId       int,
    @Window       int
AS
BEGIN
DECLARE @Today datetime
DECLARE @Tomorrow datetime
DECLARE @CutOff datetime

SET @Today = (CAST(YEAR(getdate()) as varchar) + 
    RIGHT('00' + CAST(MONTH(getdate()) as varchar), 2) + 
    RIGHT('00' + CAST(DAY(getdate()) as varchar), 2))

SET @Tomorrow  = DATEADD(dd, 1, @Today)

SET @CutOff = DATEADD(dd, @Window + 1, @Today) 

DECLARE
    @SuspendedUserCount         int,
    @ActiveUserCount            int,
    @Queue0Count                int,
    @Queue0TodayCount           int,
    ...

SELECT @SuspendedUserCount = count(UserId) FROM UserDetail WHERE Suspended = 1 AND SiteId = @SiteId
SELECT @ActiveUserCount = count(UserId) FROM UserDetail WHERE Suspended = 0 AND SiteId = @SiteId
SELECT @Queue0Count = count(ItemNumber) FROM ItemDetail WHERE Status = 0 AND SiteId = @SiteId   AND Created >= @Today AND Created < @CutOff 
SELECT @Queue0TodayCount = count(ItemNumber) FROM ItemDetail WHERE Status = 0 AND SiteId = @SiteId AND Created >= @Today AND Created < @Tomorrow 
...

SELECT @SuspendedUserCount AS SuspendedUsers, @ActiveUserCount AS ActiveUsers, @Queue0Count AS Queue0, @Queue0TodayCount AS @Queue0Today...
END

それほど複雑ではないかのように、私は Fluent Nhibernate を使用しています。必要に応じて sproc を使用することに反対しているわけではありませんが、日ごとのカウントを含むビューを作成し、それを nhibernate とクエリを使用して日付範囲で選択し、コードで適切な金額を合計することを検討しました。

私はこれを必要以上に複雑にしていると感じています。もっと良い方法があるはずです。

4

2 に答える 2

2

おそらくこれを使用できます。

declare @SiteId int = 1
declare @Window int = 5

declare @ToDay datetime = dateadd(d, datediff(d, 0, getdate()), 0)
declare @CutOff datetime = dateadd(d, @Window, @ToDay)
declare @Tomorrow datetime = dateadd(d, 1, @ToDay)

select * from
(
  select
    sum(case when Suspended = 0 then 1 else 0 end) as ActiveUserCount,
    sum(case when Suspended = 1 then 1 else 0 end) as SuspendedUserCount
  from UserDetail
  where
    SiteId = @SiteId
) as q1 cross join
(
  select
    sum(case when Status = 0 then 1 else 0 end) as Queue0Count,
    sum(case when Status = 1 then 1 else 0 end) as Queue1Count,
    sum(case when Status = 2 then 1 else 0 end) as Queue2Count,
    sum(case when Status = 3 then 1 else 0 end) as Queue3Count,
    sum(case when Status = 4 then 1 else 0 end) as Queue4Count,
    sum(case when Status = 5 then 1 else 0 end) as Queue5Count,
    sum(case when Status = 6 then 1 else 0 end) as Queue6Count,
    sum(case when Status = 0 and Created < @Tomorrow then 1 else 0 end) as Queue0TodayCount,
    sum(case when Status = 1 and Created < @Tomorrow then 1 else 0 end) as Queue1TodayCount,
    sum(case when Status = 2 and Created < @Tomorrow then 1 else 0 end) as Queue2TodayCount,
    sum(case when Status = 3 and Created < @Tomorrow then 1 else 0 end) as Queue3TodayCount,
    sum(case when Status = 4 and Created < @Tomorrow then 1 else 0 end) as Queue4TodayCount,
    sum(case when Status = 5 and Created < @Tomorrow then 1 else 0 end) as Queue5TodayCount,
    sum(case when Status = 6 and Created < @Tomorrow then 1 else 0 end) as Queue6TodayCount
  from ItemDetail
  where
    Created >= @ToDay and
    Created < @CutOff
) as q2
于 2011-03-07T19:38:58.517 に答える
0

CTE とピボットを使用してビューを作成しました

CREATE VIEW [dbo].[SiteQueueDailyStatistics]
AS

WITH statCTE AS (
    SELECT
        Count(ItemNumber)as ItemCount,
        SiteId,
        Status,
        DATEADD(dd, 0, DATEDIFF(dd, 0, ScanDate)) AS ScanDay
    FROM
        ItemDetail
    group by  SiteId, Status, DATEADD(dd, 0, DATEDIFF(dd, 0, ScanDate))
)

SELECT 
    SiteId, 
    ScanDay, 
    ISNULL([0], 0) AS Queue0,
    ISNULL([1], 0) AS Queue1,
    ISNULL([2], 0) AS Queue2,
    ISNULL([3], 0) AS Queue3,
    ISNULL([4], 0) AS Queue4,
    ISNULL([5], 0) AS Queue5,
    ISNULL([6], 0) AS Queue6
FROM 
    statCTE
PIVOT
(
    SUM(ItemCount)
    FOR [Status] IN ([0], [1], [2], [3], [4], [5], [6])
)
AS p


GO

次に、すべてのデータを取得し、複数のテーブルにわたる統計を保持するモデルに複合オブジェクトを設定します。

于 2011-04-12T15:42:36.777 に答える