0

反復マップの不動点を見つける必要がありますx[n] == 1/2 x[n-1]^2 - Mu。
私のアプローチ： 

Subscript[g, n_ ][Mu_, x_] :=  Nest[0.5 * x^2 - Mu, x, n]

fixedPoints[n_] := Solve[Subscript[g, n][Mu, x] == x, x]

Plot[
  Evaluate[{x, 
   Table[Subscript[g, 1][Mu, x], {Mu, 0.5, 4, 0.5}]}
  ], {x, 0, 0.5}, Frame -> True]
4

3 に答える 3

4

表記を少し変更します（ほとんどの場合、私自身が理解できるように）。あなたはこのようなものが欲しいかもしれません。

y[n_, mu_, x_] := Nest[#^2/2 - mu &, x, n]
fixedPoints[n_] := Solve[y[n, mu, x] == x, x]

顕著な特徴は、ネストされている「関数」が実際には正しい形式の関数であるということです。

例：

fixedPoints[2]

Out[18]= {{x -> -1 - Sqrt[-3 + 2*mu]}, 
          {x -> -1 + Sqrt[-3 + 2*mu]}, 
          {x ->  1 - Sqrt[ 1 + 2*mu]}, 
          {x ->  1 + Sqrt[ 1 + 2*mu]}}

ダニエル・リヒトブラウ

于 2011-04-05T04:20:33.697 に答える
3

まず第一に、あなたのアプローチに誤りがあります。Nestは純粋関数を取ります。また、ソルバーは数値ソルバーではなくシンボリックであるため、正確な入力、つまり0.5ではなく1/2を使用します。

Subscript[g, n_Integer][Mu_, x_] := Nest[Function[z, 1/2 z^2 - Mu], x, n]

それで

In[17]:= fixedPoints[1]

Out[17]= {{x -> 1 - Sqrt[1 + 2 Mu]}, {x -> 1 + Sqrt[1 + 2 Mu]}}
于 2011-04-05T04:21:07.843 に答える
0

補足：

不動点に非常に近いところから始めるとどうなるか見てください（奇妙な:)： 

f[z_, Mu_, n_] := Abs[N@Nest[1/2 #^2 - Mu &, z, n] - z]

g[mu_] := f[1 + Sqrt[1 + 2*mu] - mu 10^-8, mu, 10^4]

Plot[g[mu], {mu, 0, 3}, PlotRange -> {0, 7}]

ここに画像の説明を入力してください

編集

実際、そこには自己相似構造があるようです。

ここに画像の説明を入力してください

于 2011-04-06T16:06:22.333 に答える