8

mysql dbnamebashプロンプトで入力すると、ファイルに含まれている、、、および情報を使用してデータベースに自動的に接続しdbnameます。usernamepasswordhost.my.cnf

emacsで使用するときM-x sql-mysql、このすべての情報を再度求められます。

ファイル内の情報を使用するためにemacssqlモードを取得する方法はあり.my.cnfますか？

4

4 に答える 4

11

これは可能ではないと思いますが、モード構成自体でそのようなものを設定できます。

(setq sql-connection-alist
'((pool-a
(sql-product 'mysql)
(sql-server "1.2.3.4")
(sql-user "me")
(sql-password "mypassword")
(sql-database "thedb")
(sql-port 3306))
(pool-b
(sql-product 'mysql)
(sql-server "1.2.3.4")
(sql-user "me")
(sql-password "mypassword")
(sql-database "thedb")
(sql-port 3307))))

(defun sql-connect-preset (name)
  "Connect to a predefined SQL connection listed in `sql-connection-alist'"
  (eval `(let ,(cdr (assoc name sql-connection-alist))
    (flet ((sql-get-login (&rest what)))
      (sql-product-interactive sql-product)))))

(defun sql-pool-a ()
  (interactive)
  (sql-connect-preset 'pool-a))

詳細については、この記事をご覧ください。

于 2011-04-20T20:13:04.040 に答える
3

確かにそれは可能です。しかし、それはかなり複雑です。

大まかに言うと、手順は次のとおりです。

  1. ini.elを使用してiniファイルを読み取って解析します。
  2. 後者はグローバルに適用されるため、異なるホスト構成をクライアント構成とマージします。
  3. 各ホストを適切な形式に変換するsql-connection-alist
  4. 人口を増やすsql-connection-alist
  5. 使用M-x sql-connect中（自動完了！）

次のコードには、万が一の場合に備えて、.pgpassパーサーも含まれています。実装がより単純であることに気付くでしょう。

;;; .pgpass parser
(defun read-file (file)
  "Returns file as list of lines."
  (with-temp-buffer
    (insert-file-contents file)
    (split-string (buffer-string) "\n" t)))

(defun pgpass-to-sql-connection (config)
  "Returns a suitable list for sql-connection-alist from a pgpass file."
          (let ((server (lambda (host port db user _pass)
                          (list
                           (concat db ":" user ":" port ":" host)
                           (list 'sql-product ''postgres)
                           (list 'sql-server host)
                           (list 'sql-user user)
                           (list 'sql-port (string-to-number port))
                           (list 'sql-database db))))
                (pgpass-line (lambda (line)
                               (apply server (split-string line ":" t)))))
            (mapcar pgpass-line config)))

;;; .my.cnf parser
;;; Copied verbatim from https://github.com/daniel-ness/ini.el/blob/master/ini.el
(defun ini-decode (ini_text) 
  ;; text -> alist
  (interactive)
  (if (not (stringp ini_text))
      (error "Must be a string"))
  (let ((lines (split-string ini_text "\n"))
    (section)
    (section-list)
    (alist))
    (dolist (l lines)
      ;; skip comments
      (unless (or (string-match "^;" l)
          (string-match "^[ \t]$" l))
    ;; catch sections
    (if (string-match "^\\[\\(.*\\)\\]$" l)
        (progn 
          (if section
          ;; add as sub-list
          (setq alist (cons `(,section . ,section-list) alist))
        (setq alist section-list))
          (setq section (match-string 1 l))
          (setq section-list nil)))
          ;; catch properties
          (if (string-match "^\\([^\s\t]+\\)[\s\t]*=[\s\t]*\\(.+\\)$" l)
          (let ((property (match-string 1 l))
            (value (match-string 2 l)))
            (progn 
              (setq section-list (cons `(,property . ,value) section-list)))))))
    (if section
    ;; add as sub-list
    (setq alist (cons `(,section . ,section-list) alist))
      (setq alist section-list))
    alist))

(defun read-ini (file)
  "Returns ini file as alist."
  (with-temp-buffer
    (insert-file-contents file)
    (ini-decode (buffer-string))))

(defun filter-alist (wanted-members alist)
  "Returns a copy of given alist, with only fields from wanted-members."
  (let ((result nil)
        (add-if-member (lambda (elt)
                         (when (member (car elt) wanted-members)
                           (add-to-list 'result elt t)))))
    (mapc add-if-member alist)
    result))

(defun merge-alist (original override)
  "Returns a union of original and override alist. On key conflict, the latter wins."
  (let ((result (copy-alist override))
        (add (lambda (elt)
               (setq result (add-to-list
                             'result elt t
                             (lambda (left right) (equal (car left) (car right))))))))
    (mapc add original)
    result))
    
(defun parse-mycnf-hosts (file-path)
  "Returns list of hosts with clients' section applied to all hosts."
  (let ((hosts nil)
        (global nil)
        (fields '("user" "host" "database" "password" "port"))
        (section-parse (lambda(section)
                         (if (equal (car section) "client")
                             (setq global (filter-alist fields (cdr section)))
                           (let ((host (car section))
                                 (config (filter-alist fields (cdr section))))
                             (when config (add-to-list 'hosts (cons host config) t))))))
        (merge-host-with-global (lambda (host)
                                  (cons (car host) (merge-alist global (cdr host))))))
    (mapc section-parse (read-ini file-path))
    (mapcar merge-host-with-global hosts)))

(defun mycnf-to-sql-connection (config)
  (let ((add-sql-product
     (lambda (config)
       (let ((head (car config))
             (tail (cdr config)))
         (cons head (append tail (list (list 'sql-product ''mysql)))))))
    (parse-keys-and-values
     (lambda (config)
       (let ((head (car config))
             (tail (cdr config)))
         (cons
          head
          (mapcar
           (lambda (element)
            (let ((key (car element))
                  (value (cdr element)))
              (cond ((equal key "host") (list 'sql-server value))
                    ((equal key "port") (list 'sql-port (string-to-number value)))
                    ((equal key "user") (list 'sql-user value))
                    ((equal key "password") (list 'sql-password value))
                    ((equal key "database") (list 'sql-database value))
                    (t (error (format "Unknown key %s" key))))))
           tail))))))
  (mapcar add-sql-product (mapcar parse-keys-and-values config))))

;;; Actually populating sql-connection-alist
(setq sql-connection-alist
      (append
       (mycnf-to-sql-connection (parse-mycnf-hosts "~/.my.cnf"))
       (pgpass-to-sql-connection (read-file "~/.pgpass"))
       ))

次のように.my.cnf：

[client]
user=me

[host1]
database=db1
host=db.host1.com

[host2]
database=db2
user=notme
host=db.host2.com

式を実行すると、(mycnf-to-sql-connection (parse-mycnf-hosts "~/.my.cnf"))（手作業でかなり印刷されます）：

(("host2" ((sql-server "db.host2.com")
           (sql-user "notme")
           (sql-database "db2")))
 ("host1" ((sql-server "db.host1.com")
           (sql-database "db1")
           (sql-user "me"))))

最後に、を使用する代わりに、をM-x sql-mysql使用するM-x sql-connectと、オートコンプリートを使用してエイリアスを使用して接続できるようになります。

于 2017-09-08T10:59:26.453 に答える
1

これを行うには、sql-modeを「トリック」して実行する必要がありますmysql --login-path=some-connection-name some-db-name （--login-pathsql-modeがデフォルトで渡さないパラメーターです）。

次の方法でSQL側に名前付き接続を作成します（デフォルトではに保存されます.mylogin.cnf）：

mysql_config_editor set --login-path=wow --host=127.0.0.1 --port=3306 --user=root --password

次に、emacs側の接続にそのようにラベルを付けます（あなたのinit.el）：

(setq sql-connection-alist
  '((wow-local
     (sql-product 'mysql)
     (sql-mysql-options '("--login-path=wow")) ; Note: use the login-path specified earlier
     (sql-server "") ; Note: All of these empty string parameters prevent being prompted for these values and are ignored.
     (sql-user "")
     (sql-password "")
     (sql-database "wowza"))
    (wow-local-test
     (sql-product 'mysql)
     (sql-mysql-options '("--login-path=wow")) ; Note: You can have multiple connections using the same login-path just with different parameters
     (sql-server "")
     (sql-user "")
     (sql-password "")
     (sql-database "wowza-test"))
    (production
     (sql-product 'mysql)
     (sql-mysql-options '("--login-path=production"))
     (sql-server "")
     (sql-port 0) ; Note: 0 ignores, anything else overrides your .cnf
     (sql-user "")
     (sql-password "")
     (sql-database "wowza_prod"))))

最後に、SQL接続を作成し、emacs側にラベルを付けた接続を実行するM-x sql-connectと、素敵な接続の1つを選択するように求められます。

ノート：

  • emacs変数を設定するsql-mysql-optionsと、.mylogin.cnfファイル（他の.cnfファイルのYMMV）で定義されている接続を使用できます（これを使用して、必要なmysqlパラメーターを渡すこともできます）
  • 、、などを空の文字列に設定するsql-serverとsql-user、上記の値のプロンプトが表示されなくなります
  • sql-server、sql-userなどを空の文字列以外に設定すると、.cnfに設定されている値が上書きされます
  • 無視されるパラメータに関するロジックの詳細については、、M-x (describe-variable sql-mysql-options)およびファイルを参照M-x (describe-function sql-comint-mysql)してください。sql.el

TLDR：使用sql-mysql-optionsと--login-path=<your-login-path>魔法

于 2020-05-20T18:37:36.157 に答える
-3

Returnキーを押すだけで、デフォルトでピックアップされます。

于 2012-01-07T18:24:51.933 に答える