2

累積用の親変数と 2 つの子変数があります。

これらの2つの子変数を使用して、2つの異なる値を選択したいと思います

たとえば、他のすべてのチュートリアルと同じように機能するようにハードコードすることしかできません: $parent[1]/Price および $parent[1]/Quantity

代わりに、次のものが必要です。

$parent[1]/$child1 where $parent[1] = orders[1]/order and $child1 = price
$parent[1]/$child2 where $parent[1] = orders[1]/order and $child2 = quantity

    <xsl:call-template name="total">
    <xsl:with-param name="pList" select="$parent"/>
    <xsl:with-param name="price" select="Price"/>
    <xsl:with-param name="quantity" select="Quantity"/>   
    </xsl:call-template>

<xsl:template name="total">
    <xsl:param name="pListItem"/>
    <xsl:param name="pAccum" select="0"/>
    <xsl:param name="price"/>
    <xsl:param name="quantity"/>

    <xsl:choose>
      <xsl:when test="$pListItem">
        <xsl:call-template name="total">
          <xsl:with-param name="pListItem" select="$pListItem[position() > 1]"/>
          <xsl:with-param name="pAccum"
           select="$pAccum + $vHead/$price * $vHead/$quantity"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$pAccum"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
4

2 に答える 2

2

質問が何であるかは明確ではありませんが、私の推測ではこれです。

この変換:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pPriceName" select="'price2'"/>
 <xsl:param name="pQuantityName" select="'quantity1'"/>


 <xsl:template match="/">
  <xsl:call-template name="totalSales">
   <xsl:with-param name="pSales" select="/*/*"/>
   <xsl:with-param name="pPriceName" select="$pPriceName"/>
   <xsl:with-param name="pQuantityName"
        select="$pQuantityName"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="totalSales">
  <xsl:param name="pAccum" select="0"/>
  <xsl:param name="pSales"/>
  <xsl:param name="pPriceName"/>
  <xsl:param name="pQuantityName"/>

  <xsl:variable name="vthisSale" select="$pSales[1]"/>

  <xsl:choose>
   <xsl:when test="not($vthisSale)">
    <xsl:value-of select="$pAccum"/>
   </xsl:when>
   <xsl:otherwise>
    <xsl:call-template name="totalSales">
     <xsl:with-param name="pAccum" select=
     "$pAccum
     +
       $vthisSale/*[name()=$pPriceName]
      *
       $vthisSale/*[name()=$pQuantityName]
      "/>
      <xsl:with-param name="pSales" select=
       "$pSales[position() >1]"/>
      <xsl:with-param name="pPriceName"
           select="$pPriceName"/>
      <xsl:with-param name="pQuantityName"
           select="$pQuantityName"/>
    </xsl:call-template>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

次の XML ドキュメントに適用した場合(少なくともこれを提供できます!):

<orders>
 <order>
  <price1>10</price1>
  <quantity1>3</quantity1>
  <price2>15</price2>
  <quantity2>1</quantity2>
 </order>
 <order>
  <price1>11</price1>
  <quantity1>2</quantity1>
  <price2>9</price2>
  <quantity2>3</quantity2>
 </order>
</orders>

必要な正しい結果が生成されます。

63

注: 価格と数量として機能する子要素の名前の値は、変換の外部パラメーターとして提供され、実行時にのみ知ることができます。

于 2011-05-31T00:49:49.603 に答える
0

どうもありがとう。
必要なのは ' Price' と$vthisSale/*[name()=$pPriceName]

本当に助かります!! 私は魔法のせいで何年も立ち往生してきました ' '

于 2011-06-02T02:18:17.770 に答える