2

エージェントを使用して構造を操作していますが、すべての副作用があるわけではありません。

すべてのメッセージが送信されます (印刷して数えました) が、すべての副作用がない場合があります。私の機能のすべてがエージェントの状態に適用されていないかのように、または最後の送信が前の状態に適用されているかのように..

doall、dorun を試してみましたが、解決策が見つかりませんでした。

;; aux function for adding an element to a hashmap 
(defn extend-regs [reg s o]
  (let [os (get reg s)]
    (if (nil? os)
      (assoc reg s [o])
      (assoc reg s (conj os o)))))

;; the agent's altering function - adding an element to the :regs field(a hashmap)
(defn add-reg! [d s o]
  (send d (fn [a] (assoc a :regs (extend-regs (:regs a) s o)))))



;; Creating the agents, dct/init returns an agent
;; pds: data for fields
(defn pdcts->init-dcts! [pds]
  (doall (map dct/init (map :nam pds) (repeat nil))))

;; Altering one agent's state,  dct/add-reg  sends an assoc message to the agent
;; d: agent,  pd: data for fields
(defn dct->add-regs! [d pd]
  (dorun (map (fn [s r] (dct/add-reg! d s r))
          (:syms pd)
          (:regs pd)))
  d)

;; Going through all agents
;; ds: agents,  pds: datas
(defn dcts->add-regs! [ds pds]
  (dorun (map (fn [d pd] (dct->add-regs! d pd))
          ds
          pds))
  ds)

編集: ============================================== =====

さて、スレッドがタスクを完了するのを十分に待っていないことがわかりました。問題は、エージェントを監視する方法です。キューに未完了のスレッドがあることをどのように知ることができますか? swank.core/ active-threadsおよび同様のものしか見つかりませんでしたが、それらは解決策ではありません。

4

2 に答える 2

2

あなたの問題の解決策はありませんが、最初の 2 つの機能を改善することを提案せずにはいられません。

(defn extend-regs [reg s o]
  (let [os (get reg s)]
    (if (nil? os)
      (assoc reg s [o])
      (assoc reg s (conj os o)))))
;; => place the 'if inside the assoc:
(defn extend-regs [reg s o]
  (let [os (get reg s)]
    (assoc reg s (if (nil? os) [o] (conj os o)))))
;; => this (if (nil? x) ...) is the pattern of function fnil, so ...
(defn extend-regs [reg s o]
  (let [os (get reg s)]
    (assoc reg s ((fnil conj []) os o))))
;; with update-in, this will be even clearer, and we can remove the let altogether:
(defn extend-regs [reg s o]
  (update-in reg [s] (fnil conj []) o))

2番目については：

(defn add-reg! [d s o]
  (send d (fn [a] (assoc a :regs (extend-regs (:regs a) s o)))))
;; => We can, again, use update-in instead of assoc:
(defn add-reg! [d s o]
  (send d (fn [a] (update-in a [:regs] extend-regs s o))))
;; or, if you can get rid of extend-regs:
(defn add-reg! [d s o]
  (send d (fn [a] (update-in a [:regs s] (fnil conj []) o)))

最後に、スタイルの問題として、add-reg を別の関数に配置し、クライアント コードでエージェントに送信するイディオムを直接使用します (または単純化された add-reg! 関数を使用します)。

(defn add-reg [v s o] (update-in v [:regs s] (fnil conj []) o))

(defn add-reg! [d s o] (send d add-reg))

これがあなたの最初の質問に答えていないことはわかっていますが、このステップバイステップのリファクタリングを書くのは楽しかったです

于 2011-07-11T20:08:56.673 に答える
1

awaitまたはawait-forを使用して、エージェントが現在の作業キューを終了するまで待機します。

(await agent1 agent2 agent3)

また

(apply await list-of-agents)

add-reg のマイナーな改善:

(defn extend-regs [reg s o]
  (update-in reg [s] conj o))

これは次の理由で機能します

(conj nil :b)               ; => [:b]

したがって

(update-in {} [:a] conj :b) ; => {:a [:b]}

ついに私たちは持っています。

(defn add-reg! [d s o]
  (send d update-in s [:regs] conj o)
于 2011-07-14T08:48:08.317 に答える