path - バッチ：絶対パスから最後のフォルダー名を取得する

Question

バッチスクリプトを使用してファイルをNASに自動的にバックアップしていますが、「C：\ Things\Folder」から「Folder」などの絶対パスから最後のフォルダー名を取得する必要があります。

Answer 1

ちょっとしたハックですが、次のものを使用できます。

Set NasPath=C:\Things\Folder
Set NasFolder=%NasPath%
:GetFolder
Set GetFolderTemp=%NasFolder:*\=%
If Not %GetFolderTemp%==%NasFolder% (
    Set NasFolder=%GetFolderTemp%
    Goto :GetFolder
)
Echo NasPath  =%NasPath%
Echo NasFolder=%NasFolder%
Exit /B

何をするにしても、Set NasPath=...ステートメントのどの部分も引用符で囲まないでください。このように引用符を使用します。

Set FromPath=C:\Program Files\Blah
Set NasPath=C:\Things\Folder
RoboCopy "%FromPath%" "%NasPath%"

このように引用符を使用しないでください。

Set FromPath="C:\Program Files\Blah"
Set NasPath="C:\Things\Folder"
RoboCopy %FromPath% %NasPath%

Answer 2

スペースに問題がないように、私はこのコードを提案します：

Set NasPath=C:\Things\My Space\Folder
Set GetFolderTemp=%NasPath%
:GetFolder
FOR /F "tokens=1,* delims=\" %%1 IN ("%GetFolderTemp%") do (
set NasFolder=%%1
set GetFolderTemp=%%2
)
if not "a%GetFolderTemp%"=="a" goto :GetFolder

echo %NasFolder%

Answer 3

のようなパス（引用符なし）を想定するとC:\Program Files\Mickey\Mouse、次のコードを使用することもできます。

setlocal EnableDelayedExpansion

set path=C:\Program Files\Microsoft\Mickey\Mouse
:shift
for /f "tokens=1* delims=\/" %%i in ( "!path!" ) do (
    set folder=%%i
    set path=%%j
)
if not [!path!] == [] goto :shift

echo folder: !folder!

endlocal