1

テクスチャ座標を 0 と 1 でハードコーディングし、3x3 テクスチャ変換マトリックスを含む定数バッファを頂点シェーダに送信して、テクスチャをクリップしようとしています。

ただし、テクスチャは期待どおりにレンダリングされません。どこで間違ったのかわかりません。誰か助けてくれませんか？以下のコードを参照してください。

テストのために、私は恒等行列を使用してテクスチャ座標を変更しないようにしようとしていますが、テクスチャは非常に奇妙な方法で変換されて表示されます。

これがテクスチャです: (表示される色は、実際には透明な領域です。ただし、黒い色とハートの柔らかい赤色を除きます)

正常

変換されたテクスチャ:

変換された

HLSL:

cbuffer cbChangesPerFrame : register( b0 )
{
    matrix g_Mvp;
};

cbuffer cbTexTransform : register( b2 )
{
    float3x3 g_TexTransform;
};

Texture2D g_ColorMap : register(t0);
SamplerState g_ColorSampler : register(s0);

struct VS_Input
{
    float4 pos : POSITION0;
    float2 tex0 : TEXCOORD0;
};

struct PS_Input
{
    float4 pos : SV_POSITION0;
    float2 tex0 : TEXCOORD0;
};

PS_Input VS_Main(VS_Input vertex)
{
    PS_Input vsOut = (PS_Input)0;
    vsOut.pos = mul(vertex.pos,g_Mvp);

    //vsOut.tex0 = vertex.tex0;
    float3 coord = float3(vertex.tex0, 1.0);
    coord = mul(coord, g_TexTransform);
    vsOut.tex0 = coord.xy ;

    return vsOut;
}

float4 PS_Main( PS_Input frag ) : SV_TARGET
{
    return g_ColorMap.Sample( g_ColorSampler, frag.tex0 );
}

ハードコードされた VBuffer:

Vertex::PosTex vertices[]=
{
    {XMFLOAT3( 0.5f, 0.5f, 1.0f ),  XMFLOAT2( 1.0f, 0.0f )},
    {XMFLOAT3( 0.5f, -0.5f, 1.0f ), XMFLOAT2( 1.0f, 1.0f )},
    {XMFLOAT3( -0.5f, -0.5f, 1.0f ), XMFLOAT2( 0.0f, 1.0f )},

    {XMFLOAT3( -0.5f, -0.5f, 1.0f ), XMFLOAT2( 0.0f, 1.0f )},
    {XMFLOAT3( -0.5f, 0.5f, 1.0f ), XMFLOAT2( 0.0f, 0.0f )},
    {XMFLOAT3( 0.5f, 0.5f, 1.0f ),  XMFLOAT2( 1.0f, 0.0f )}
};

行列の定義:

XMFLOAT3X3 f3x3;
f3x3.m[0][0] = 1.0f;    f3x3.m[0][1] = 0.0f;    f3x3.m[0][2] = 0.0f;
f3x3.m[1][0] = 0.0f;    f3x3.m[1][1] = 1.0f;    f3x3.m[1][2] = 0.0f;
f3x3.m[2][0] = 0.0f;    f3x3.m[2][1] = 0.0f;    f3x3.m[2][2] = 1.0f;
GAME_MANAGER->GMSetTexTransformMatrix(f3x3);

Game_Manager GMSetTransformMatrix() の定義:

void GameManager::GMSetTexTransformMatrix( const XMFLOAT3X3& rkTexTransform )
{
    m_pContext->UpdateSubresource(m_pTexTransformCB,0,0,&rkTexTransform,0,0);
    m_pContext->VSSetConstantBuffers(2,1,&m_pTexTransformCB);
}

バッファの初期化:

ZeroMemory(&constDesc, sizeof(constDesc));
constDesc.BindFlags = D3D11_BIND_CONSTANT_BUFFER;
constDesc.ByteWidth = 48;
constDesc.Usage = D3D11_USAGE_DEFAULT;

result = m_pDevice->CreateBuffer(&constDesc,0,&m_pTexTransformCB);
4

1 に答える 1

3

問題は 16 バイトのアラインメントです。XMFLOAT3X3 は、連続する 9 個の float です。これがレジスタに格納されると、最初の 4 つの float を取得して c0 に配置し、次の 4 つを c1 に配置し、残りの float を c2.x に配置します。これは、次の方法で自分で確認できます。

cbuffer cbChangesEveryFrame : register( b1 )
{

    float a1 : packoffset(c0.x);
    float a2 : packoffset(c0.y);
    float a3 : packoffset(c0.z);

    float b1 : packoffset(c0.w);
    float b2 : packoffset(c1.x);
    float b3 : packoffset(c1.y);

    float c1 : packoffset(c1.z);
    float c2 : packoffset(c1.w);
    float c3 : packoffset(c2.x);

};

PS_INPUT VS( VS_INPUT input )
{
    PS_INPUT output = (PS_INPUT)0;
    output.Pos = mul( input.Pos, World );
    output.Pos = mul( output.Pos, View );
    output.Pos = mul( output.Pos, Projection );

    float3 coord = float3(input.Tex, 1.0);

    float3x3 g_TexTransform = {a1, a2, a3, b1, b2, b3, c1, c2, c3};

    coord = mul(coord, g_TexTransform);

    output.Tex = coord.xy;

    return output;
}

XMFLOAT3X3 を渡すと、テクスチャが正常に表示されます。問題は、レジスタの割り当てが原因で、テクスチャ変換マトリックスが台無しになったことです。レジスタを見ると、次のようにデータが入ってきます。

c0: 1 0 0 0
c1: 1 0 0 0
c2: 1

float3x3 はおそらく float3 の配列であるため、各レジスタの最初の 3 つのコンポーネントを取得すると、次のようになります。

1, 0, 0
1, 0, 0
1, 0, 0

Y を 0 にスケーリングします。これにより、奇妙な伸縮性のある外観が得られます。これを解決するには、変換を 4x4 マトリックスに格納するか、レジスタの各部分を手動で割り当てる必要があります。3 つの float3 に切り替えても、16 バイトの境界を越えることができないため、機能しません。

于 2011-09-25T19:36:08.393 に答える