4

考えてください ：

intense = Reverse[Round[Rationalize /@ N[10^Range[0, 3, 1/3]]]];
values = Range[0, 9/10, 1/10];

intensityLegend = Column[Prepend[MapThread[
                         Function[{intensity, values},
                         Row[{Graphics[{(Lighter[Blue, values]),
                         Rectangle[{0, 0}, {4, 1}], Black, 
                         Text[Style[ToString[intensity], 16, Bold], {2, .5}]}]}]],
                        {intense, values}], Text[Style["Photons Number", Bold, 15]]]];

IntersectionDp1={{1., 588.377}, {2.15443, 580.306}, {4.64159, 573.466}, {10.,560.664}, 
                 {21.5443, 552.031}, {46.4159, 547.57}, {100.,545.051}, 
                 {215.443, 543.578}, {464.159, 542.281}, {1000., 541.346}}


FindD1=ListLogLinearPlot[Map[List, IntersectionDp1], 
                  Frame -> True, 
                  AxesOrigin -> {-1, 0}, 
                  PlotMarkers -> 
                  With[{markerSize = 0.04}, {Graphics[{Lighter[Blue, #], Disk[]}], 
                       markerSize} & /@Range[9/10, 0, -1/10]], Filling -> Axis, 
                  FillingStyle -> Opacity[0.8], 
                  PlotRange -> {{.5, 1100}, {540, 600}},
                  ImageSize->400];

Grid[{{intensityLegend, FindD1}, {intensityLegend, FindD1}}, 
      ItemSize -> {50, 20}, Frame -> True]

ここに画像の説明を入力してください

凡例の列サイズをプロット領域の高さに合わせるにはどうすればよいですか？

行がサイズを調整している間、グリッドを使用する必要があります。これが私がグリッドで複製した理由です。

4

2 に答える 2

9

画像サイズの操作。（* <-*）はコードへの重要な変更を示し、残りは主にフォントサイズのものです。

intense = Reverse[Round[Rationalize /@ N[10^Range[0, 3, 1/3]]]];
values = Range[0, 9/10, 1/10];
imgSize = 400;                                                          (* <- *) 
Off[Ticks::ticks]

IntersectionDp1 =  {{1., 588.377},     {2.15443, 580.306}, {4.64159, 573.466}, 
   {10., 560.664}, {21.5443, 552.031}, {46.4159, 547.57},  {100., 545.051},
   {215.443, 543.578}, {464.159, 542.281}, {1000., 541.346}}

FindD1 = ListLogLinearPlot[Map[List, IntersectionDp1], Frame -> True, 
   AxesOrigin -> {-1, 0}, 
   PlotMarkers -> 
    With[{markerSize = 0.04}, 
     {Graphics[{Lighter[Blue, #], Disk[]}], markerSize} & 
       /@ Range[9/10, 0, -1/10]], Filling -> Axis, FillingStyle -> Opacity[0.8], 
       PlotRange -> {{.5, 1100}, {540, 600}}, ImageSize -> imgSize];    (* <- *) 

intensityLegend =
  Rasterize[Column[
    Prepend[
     Reverse@MapThread[                                                 (* <- *) 
      Function[{intensity, values}, 
       Row[{Graphics[{(Lighter[Blue, values]), 
           Rectangle[{0, 0}, {4, 1}], Black, 
           Text[Style[ToString[intensity], 30, Bold], {2, .5}]}]}]],
      {intense, values}],
     Text[Style["Photons Number", Bold, 25]]]], 
   ImageSize -> {Automatic,                                             (* <- *) 
     IntegerPart@                            
      First[imgSize Cases[AbsoluteOptions[FindD1], 
         HoldPattern[AspectRatio -> x_] -> x]]}];

Grid[{{intensityLegend, FindD1}, {intensityLegend, FindD1}}, Frame -> True]

ここに画像の説明を入力してください

美的目的で強度の列を逆にしたところ。

編集

AbsoluteOptions[Plot, "ImageSize"]プロットにImageSizeオプションを明示的に指定しないと、残念ながらそれが返されることに気付くでしょう"Automatic"。

以下の@500のコメントに答えて編集

表現： 

   ImageSize -> {Automatic,                                             (* <- *) 
     IntegerPart@                            
      First[imgSize Cases[AbsoluteOptions[FindD1], 
         HoldPattern[AspectRatio -> x_] -> x]]}];

は実際には機能するはずなのに、プロットの画像サイズを取得できないものの代わりに機能します。

   ImageSize -> {Automatic, Last@AbsoluteOptions[FindD1,"ImageSize"]}

つまり、何をしているのかとIntegerPart[...]いうと、プロット画像の垂直サイズを取得し、プロットのを掛けるimgSizeことAspectRatioです。
それがどのように機能するかを理解するには、コードを実行してから次のように入力します。

AbsoluteOptions[FindD1]

そこにプロットオプションが表示されます。次に、Cases[]関数はAspectRatioオプションを抽出しているだけです。

実際、Cases[]が行うことを行うためのよりクリーンな方法があります。それは：

AbsoluteOptions[FindD1,"AspectRatio"]

ただし、AbsoluteOptions関数には、この方法で使用できない別のバグがあります。

于 2011-10-17T01:24:16.397 に答える
4

伝説をもう少し小さくしてみませんか？

intensityLegend = 
  Column[Prepend[
    MapThread[
     Function[{intensity, values}, 
      Row[{Graphics[{(Lighter[Blue, values]), 
          Rectangle[{0, 0}, {4, 1}], Black, 
          Text[Style[ToString[intensity], 12, Bold], {2, .5}]}, 
         ImageSize -> 50]}]], {intense, values}], 
    Text[Style["Photons Number", Bold, 15]]]];

ここに画像の説明を入力してください

于 2011-10-16T19:46:24.857 に答える