3

完全に空のMXMLアプリケーションから開始します。

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" 
    layout="absolute" >

</mx:Application>

次のようなスクリプトは何ですか。

  • ビットマップを作成します（これはBitmapDataオブジェクトである必要がありますか？）
  • プログラムでデータを入力します（たとえば、円を描きます）（繰り返し呼び出すよりも効率的な方法はありますBitmapData.SetPixelか？）
  • アプリケーション内でレンダリングします（たとえば、中央に配置します）（ビットマップを画面に表示するにはどうすればよいですか？オンラインFlashサンプルでは、​​呼び出しmyBitmap=new Bitmap(myBitmapData)とその後myBitmap.AddChildの呼び出しが表示されますが、これによりFlexでエラーが発生します）。

??

注：目標は、画面上に円を表示することだけではなく、SetPixel（または???）を使用してビットマップ（またはBitmapData？または???）オブジェクトにデータを入力し、そのコンテンツを画面に表示することです。画像処理または視覚効果アプリケーションで行う必要があります。

4

2 に答える 2

3

いくつかのオプションがあります。1つ目は、非常に優れた描画ツールを備えたDegrafaフレームワークを調べることです。そうでない場合は、スクリプトブロックを追加し、関数でAS3描画APIを使用する必要があります（この場合、おそらくcreationCompleteで呼び出されます。

private function handleCreationComplete():void
{
    var component:UIComponent = new UIComponent(); //needed to add to the flex display list
    var myCircle:Sprite = new Sprite();
    myCircle.graphics.beginFill(0xFFFFFF,1)
    myCircle.graphics.drawCircle(100,100,50);
    component.addChild(myCircle);
    this.addChild(component);
}

これは円の中心にはなりませんが、それを理解することはできます。

この関数を使用して、上記のUIComponentから実際にビットマップを取得できます。

private function getBitmapData( target : UIComponent ) : BitmapData
   {
    var bd : BitmapData = new BitmapData( target.width, target.height );
    var m : Matrix = new Matrix();
    bd.draw( target, m );
    return bd;
   }

ここから。

于 2009-04-23T03:36:06.427 に答える
2

Joel Hooksの提案に基づいて作成できた、完全で実用的な例を次に示します。

MXML ファイル (ards.mxml):

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
       creationComplete="onCreationComplete()">

<mx:Script source="ards_script.as" />

</mx:Application>

スクリプト ファイル (ards_script.as):

import mx.core.UIComponent;

private function onCreationComplete():void
{
    // create a UIComponent and add it to the Flex display list
    var component:UIComponent = new UIComponent();
    component.width = this.width;
    component.height = this.height;
    component.x = 0;
    component.y = 0;
    this.addChild(component);

    // create a BitmapData object (basically an array of pixels) the same size as the screen    
    var bd : BitmapData = new BitmapData( component.width, component.height );

    // draw a green circle in the bitmap data
    var xCenter:int = component.width/2;
    var yCenter:int = component.height/2;
    var r:int = Math.min(xCenter,yCenter);
    var rSquare:int = r*r;
    var color:Number = 0x00ff00;
    for( var i:int=0; i<component.width; i++ )
    {
        for( var j:int=0; j<component.width; j++ )
        {
            var dX:int = i - xCenter;
            var dY:int = j - yCenter;
            var q:int = dX*dX + dY*dY;
            if( q < rSquare )
            {
                    bd.setPixel( i, j, color );
            }       
        }
    }

    // create a bitmap based on the data, and add it as a child to the UIComponent to be displayed
    // (if you try to add it directly to the Application, you get a runtime error)
    var bt:Bitmap = new Bitmap(bd);
    component.addChild(bt);    
}
于 2009-04-23T16:05:57.550 に答える