2

広く使用されている GetValues 関数を使用して、閉じたブックから値を取得できます。それはうまくいきます。

しかし、閉じたブックからセルの数式を取得する必要がある場合があります。GetValues を変更してセルの数式を取得しようとしましたが、エラーが発生します。

閉じたExcelファイルからセルの数式(単純な値ではない)を取得する方法は?

With Sheets
  For r = 2 To NewRowQty ' from second row to last row
    For c = 1 To ThisColumnEnd ' out to EndColumn (from import dialogue box)
      ThisCell = Cells(r, c).Address
      ThisValue = GetValue(ThisPath, ThisFile, ThisSheet, ThisCell)
      If ThisValue <> "0" Then
        If c = 3 And r > 2 Then
          Cells(r, c).Formula = GetFormula(ThisPath, ThisFile, ThisSheet, ThisCell)
        Else
          Cells(r, c) = ThisValue
        End If
      End If
    Next c
  Next r
End With

これら 2 つの関数を呼び出すと、GetValue は正常に機能し、GetFormula は数式を取得しません。

Private Function GetValue(p, f, s, c)
  'p: path: The drive and path to the closed file (e.g., "d:\files")
  'f: file: The workbook name (e.g., "budget.xls")
  's: sheet: The worksheet name (e.g., "Sheet1")
  'c: cell: The cell reference (e.g., "C4")

  'Retrieves a value from a closed workbook
  Dim arg As String
  'Make sure the file exists
  If Right(p, 1) <> "\" Then p = p & "\"
  If Dir(p & f) = "" Then
    GetValue = "File Not Found"
    Exit Function
  End If
  'Create the argument
  arg = "'" & p & "[" & f & "]" & s & "'!" & _
  Range(c).Range("A1").Address(, , xlR1C1)
  'Execute an XLM macro
  GetValue = ExecuteExcel4Macro(arg)
End Function

Private Function GetFormula(p, f, s, c)
  'p: path: The drive and path to the closed file (e.g., "d:\files")
  'f: file: The workbook name (e.g., "budget.xls")
  's: sheet: The worksheet name (e.g., "Sheet1")
  'c: cell: The cell reference (e.g., "C4")

  'Retrieves a value from a closed workbook
  Dim arg As String
  'Make sure the file exists
  If Right(p, 1) <> "\" Then p = p & "\"
  If Dir(p & f) = "" Then
    GetFormula = "File Not Found"
    Exit Function
  End If
  'Create the argument
  arg = "'" & p & "[" & f & "]" & s & "'!" & _
  Range(c).Range("A1").Address(, , xlR1C1).Formula
  'Execute an XLM macro
  GetFormula = ExecuteExcel4Macro(arg)
End Function

更新: Joel の最初のコード投稿は、私が最終的に使用したものの基礎となったので、正しいとマークしました。これは、行数式全体のコピーペーストを使用した実際の実装です。C または ZZ である可能性がある値または数式を含む列の数がわからないため、これが最適です。

' silent opening of old file:
Application.EnableEvents = False
Set o = GetObject(FileTextBox.Text)
With Sheets
    For r = 2 To NewRowQty ' from second row to last row
        ThisCell = "A" & r
        o.Worksheets(ThisRate).Range(ThisCell).EntireRow.Copy
        Sheets(ThisRate).Range(ThisCell).PasteSpecial xlFormulas
    Next r
End With
' Close external workbook, don't leave open for extended periods
Set o = Nothing
Application.EnableEvents = True
4

2 に答える 2

3

なぜそのような複雑なコードなのですか? 使用しているコードは、何らかの理由で、Excel 4.0 下位互換モードのマクロ プロセッサを呼び出しています。なぜそんなことをするのか、私には想像できません。

c:\tmp\book.xlsx のセル Sheet1!A1 から数式を取得する簡単な方法を次に示します。

Dim o As Excel.Workbook
Set o = GetObject("c:\tmp\Book.xlsx")
MsgBox o.Worksheets("Sheet1").Cells(1, 1).Formula
Set o = Nothing ' this ensures that the workbook is closed immediately
于 2011-11-01T22:38:46.723 に答える
1

Excel 4- スタイルのマクロ (1994 年に廃止されました!) を実行したい場合は、関数を使用して、XLM次GET.FORMULAのように値の代わりに式を取得する必要があります。

arg = "GET.FORMULA('" & p & "[" & f & "]" & s & "'!" & _
      Range(c).Range("A1").Address(, , xlR1C1) & ")"

R1C1結果には、表記法ではなく表記法を使用した式が含まれることに注意してくださいA1。

表記法への変換A1(本当にそうしたい場合) は、読者の課題として残されています。

于 2011-11-01T23:44:15.270 に答える